R_ServiceConfirmationItemTP

@EndUserText.label: 'Service Confirmation Item - TP'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   sapObjectNodeType.name: 'ServiceConfirmationItem', 
   representativeKey: 'ServiceConfirmationItem',
   semanticKey: ['ServiceConfirmationItem'],
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity R_ServiceConfirmationItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_ServiceConfirmationTP as _ServiceConfirmationTP on  //$projection.ServiceObjectType   = _ServiceConfirmationTP.ServiceObjectType

                                                                                     $projection.ServiceConfirmation = _ServiceConfirmationTP.ServiceConfirmation

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtExtRef        on  $projection.ServiceConfirmation      = _CustMgmtExtRef.CustMgmtDocument
                                                                                 and $projection.ServiceObjectType        = _CustMgmtExtRef.CustMgmtObjectType
                                                                                 and $projection.ServiceConfirmationItem  = _CustMgmtExtRef.CustMgmtDocumentItem
                                                                                 and _CustMgmtExtRef.CustMgmtExtRefIDType = '0015'

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtHeaderExtRef  on  $projection.ServiceConfirmation            = _CustMgmtHeaderExtRef.CustMgmtDocument
                                                                                 and $projection.ServiceObjectType              = _CustMgmtHeaderExtRef.CustMgmtObjectType
                                                                                 and _CustMgmtHeaderExtRef.CustMgmtExtRefIDType = '0014'


  association [0..1] to R_SrvcDocItemDocumentFlow      as _RefServiceOrder       on  $projection.ServiceConfirmation              = _RefServiceOrder.ServiceDocument
                                                                                 and $projection.ServiceConfirmationItem          = _RefServiceOrder.ServiceDocumentItem
                                                                                 and _RefServiceOrder.PrdcssrSuccssrDocObjectType = 'BUS2000116'
                                                                                 and _RefServiceOrder.ServiceObjectType           = 'BUS2000117'

  association [0..1] to R_SrvcDocItemDocumentFlow      as _RefServiceContract    on  $projection.ServiceConfirmation                 = _RefServiceContract.ServiceDocument
                                                                                 and $projection.ServiceConfirmationItem             = _RefServiceContract.ServiceDocumentItem
                                                                                 and _RefServiceContract.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                                 and _RefServiceContract.ServiceObjectType           = 'BUS2000117'

  association [0..1] to I_CustMgmtPartner              as _ServicePerformer      on  _ServicePerformer.CustMgmtPartnerFunction      = '00000028'
                                                                                 and _ServicePerformer.CustMgmtPartFunctionCategory = '0091'
                                                                                 and $projection.ServiceConfirmation                = _ServicePerformer.CustMgmtDocument
                                                                                 and $projection.ServiceConfirmationItem            = _ServicePerformer.CustMgmtDocumentItem

  //added

  association [0..1] to I_RespyMgmtTeamHeaderDetail    as _ServiceTeamHeader     on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  composition [0..*] of R_SrvcConfItemPriceElementTP   as _SrvcConfItemPriceElementTP
  composition [0..*] of R_SrvcConfItemPartnerTP        as _SrvcConfItemPartnerTP
  composition [0..*] of R_SrvcConfItemRefObjectTP      as _SrvcConfItemRefObjTP
  composition [0..*] of R_SrvcConfItemSerialNumberTP   as _SrvcConfItemSerialNumberTP
  composition [0..*] of R_SrvcConfItmFUPBillgDocTP     as _SrvcConfItmFUPBillgDocTP
  composition [0..1] of R_SrvcConfItmFUPTimeSheetTP    as _SrvcConfItmFUPTimeSheetTP
  //composition [0..*] of R_SrvcConfItmFUPGoodsMvtTP     as _GoodsMovementItmFollowupTP

  composition [0..*] of R_SrvcConfItemAppointmentTP    as _SrvcConfItemAppointmentTP
  composition [0..*] of R_SrvcConfItemDurationTP       as _SrvcConfItemDurationTP
  composition [0..*] of R_SrvcConfItemUserStatusTP     as _SrvcConfItemUserStatusTP
  composition [0..*] of R_SrvcConfItemLongTextTP       as _SrvcConfItemLongTextTP
  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcConfItmStatus     on  $projection.ServiceConfirmationItemUUID = _SrvcConfItmStatus.StatusObjectUUID
                                                                                 and (
                                                                                    _SrvcConfItmStatus.StatusCode            = 'I1002' //IsNew

                                                                                    or _SrvcConfItmStatus.StatusCode         = 'I1003' //InProcess

                                                                                    or _SrvcConfItmStatus.StatusCode         = 'I1005' //Completed

                                                                                  )
                                                                                 and _SrvcConfItmStatus.StatusIsActive       = 'X'

  //! Extensibility support

  association [0..1] to E_ServiceDocumentItem          as _Extension             on  _Extension.ServiceCategory          = 'BUS2000117'
                                                                                 and $projection.ServiceConfirmation     = _Extension.ServiceOrderItem
                                                                                 and $projection.ServiceConfirmationItem = _Extension.ServiceLineExternalID
  association [0..1] to I_WBSElementBasicData          as _WBSElement            on  _WBSElement.WBSElementInternalID = I_ServiceDocumentItemEnhcd.WBSElementInternalID

{
      //Administrative fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                                                as ServiceConfirmation,
  key ServiceDocumentItem                                                            as ServiceConfirmationItem,
      ServiceDocumentItemObjectType,
      ServiceDocItemCategory                                                         as ServiceConfItemCategory,
      ServiceDocumentItemUUID                                                        as ServiceConfirmationItemUUID,
      _ParentServiceDocItem_2.ServiceDocumentItem                                    as ParentServiceConfItem,
      ServiceDocumentItemDescription                                                 as ServiceConfItemDescription,
      Language,
      ServiceDocItemCreationDateTime,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,

      //Item fields

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @Semantics: { quantity : {unitOfMeasure: 'QuantityUnit'} }
      ServiceDocumentItemQuantity                                                    as Quantity,
      ServiceDocItemQuantityUnit                                                     as QuantityUnit,

      //Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                  as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                            as RespEmployeeBusinessPartnerId,
      ServiceEmployee                                                                as ExecutingServiceEmployee,
      _ServicePerformer.CustMgmtPartner                                              as ServicePerformer,

      //Organizational data

      RespyMgmtServiceTeam,
      //_ServiceTeamHeader.TeamName                                                 as RespyMgmtServiceTeamName,

      _ServiceTeamHeader.RespyMgmtGlobalTeamID                                       as RespyMgmtGlobalTeamID,

      PaymentTerms,
      PaymentMethod,
      SEPAMandate,
      SrvcSEPAMandateRelevance,

      //Status

      cast( case _SrvcConfItmStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as SrvcConfItemIsNew,
      //      cast( case _SrvcConfItmStatus.StatusCode

      //      when 'I1003' then 'X'

      //      else ' '

      //      end                  as   xfeld preserving type     )                       as SrvcConfItemIsInProcess,

      cast( case _SrvcConfItmStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceConfItemIsCompleted,


      //      cast(0 as vfprc_element_amount)                     as SrvcConfItmCndnRateAmount,

      //      cast('' as waers)                                   as SrvcConfItmCndnRateCurrency,


      ServiceDocumentItemStatus                                                      as ServiceConfirmationItemStatus,
      SrvcDocItmIsReleasedForBilling                                                 as SrvcConfItmReldForBillgStatus,
      ServiceDocItemBillingStatus                                                    as SrvcConfItemBillingStatus,
      @Semantics.booleanIndicator
      ServiceDocumentItemHasError                                                    as SrvcConfItemHasError,
      SrvcDocItemTransferStatus,

      //Dates and Durations

      ActualServiceStartDateTime,
      ActualServiceEndDateTime,
      //@DefaultAggregation: #SUM

      @Semantics: { quantity : {unitOfMeasure: 'ActualServiceDurationUnit'} }
      ActualServiceDuration,
      @ObjectModel.foreignKey.association: '_ActualServiceDurationUnit'
      ActualServiceDurationUnit,

      //      RequestedDeliveryUTCDateTime                        as ErlstRequestedDeliveryDateTime,

      ServicesRenderedDate,

      //Service specific fields

      @ObjectModel.foreignKey.association: '_ServiceDocOvertimeCat'
      TimeSheetOvertimeCategory,

      //Pricing fields

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,
      @ObjectModel.foreignKey.association: '_BillableControl'
      BillableControl,
      _WBSElement.WBSElementExternalID,

      //Reference documents

      _CustMgmtExtRef.CustMgmtExtRefID                                               as SrvcConfItemExtReference,
      _CustMgmtHeaderExtRef.CustMgmtExtRefID                                         as SrvcConfExtReference,
      cast(_RefServiceOrder.CustMgmtPrdcssrTransactionKey as  crmt_object_id_db )    as ReferenceServiceOrder,
      cast( _RefServiceOrder.BusinessTransactionDocItem as crms4_number_int )        as ReferenceServiceOrderItem,

      cast(_RefServiceContract.CustMgmtPrdcssrTransactionKey as  crmt_object_id_db ) as ReferenceServiceContract,
      cast(_RefServiceContract.BusinessTransactionDocItem as crms4_number_int )      as ReferenceServiceContractItem,

      //RAP : Inheritance of complex set

      SrvcDocItmPartReferenceItem,
      SrvcDocItmApptRefObjectUUID,
      SrvcDocItmApptReferenceItem,

      //Shipping

      ShippingCondition,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      cast('' as crms4_is_unplanned_item preserving type)                            as RefSrvcOrdItemIsUnplanned,


      //Associations


      _ServiceDocument,

      _Product,

      _ContactPerson,
      _RespEmployee,

      _ActualServiceDurationUnit,
      _ServiceDocOvertimeCat,

      _ServiceObjType,

      _ServiceConfirmationTP,
      _SrvcConfItemPriceElementTP,
      _SrvcConfItemPartnerTP,
      _TransactionCurrency,
      _BillableControl,
      _RefServiceOrder,
      _SrvcConfItemRefObjTP,
      _SrvcConfItmStatus,
      _SrvcConfItmFUPBillgDocTP,
      _SrvcConfItmFUPTimeSheetTP,
      _SrvcConfItemAppointmentTP,
      _SrvcConfItemDurationTP,
      _SrvcConfItemUserStatusTP,
      _SrvcConfItemLongTextTP,
      _SrvcConfItemSerialNumberTP

}
where
  ServiceObjectType = 'BUS2000117' //  Service Confirmation