R_SalesQuotationItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesQuotation', 'SalesQuotationItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Sales Quotation Item - Text TP'
define view entity R_SalesQuotationItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as SalesQuotationItemText

    inner join   I_SalesDocumentItemBasic                                 as SalesDocumentItemBasic    on  SalesDocumentItemBasic.SalesDocument      = SalesQuotationItemText.SalesDocument
                                                                                                       and SalesDocumentItemBasic.SalesDocumentItem  = SalesQuotationItemText.SalesDocumentItem
                                                                                                       and SalesDocumentItemBasic.SDDocumentCategory = 'B'

    inner join   I_SalesDocumentItemCategory                              as SalesDocumentItemCategory on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association        to parent R_SalesQuotationItemTP as _Item                        on  $projection.SalesQuotation     = _Item.SalesQuotation
                                                                                      and $projection.SalesQuotationItem = _Item.SalesQuotationItem

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_SalesQuotationTP            as _SalesQuotation              on  $projection.SalesQuotation = _SalesQuotation.SalesQuotation

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesQuotationItemText.SalesDocument as sales_quotation preserving type)          as SalesQuotation,

  key cast(SalesQuotationItemText.SalesDocumentItem as sales_quotation_item preserving type) as SalesQuotationItem,

  key SalesQuotationItemText.Language,

  key SalesQuotationItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      SalesQuotationItemText.LongTextID                                                      as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      SalesQuotationItemText.Language                                                        as LanguageForEdit,

      @ObjectModel.virtualElement: true
      SalesQuotationItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                            as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                               as SalesQuotationType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _SalesQuotation,
      _Language,
      _LongTextID
}