R_SalesOrderPricingElementTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
    }
}

@ObjectModel.semanticKey: ['SalesOrder', 'PricingProcedureStep', 'PricingProcedureCounter']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Sales Order Pricing Element - TP'
define view entity R_SalesOrderPricingElementTP
  as select from I_SalesOrderPricingElement as SalesOrderPricingElement

  association to parent R_SalesOrderTP as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
{

  key SalesOrderPricingElement.SalesOrder,

  key SalesOrderPricingElement.PricingProcedureStep,

  key SalesOrderPricingElement.PricingProcedureCounter,

      @ObjectModel.foreignKey.association: '_ConditionApplication'
      SalesOrderPricingElement.ConditionApplication,

      @ObjectModel.foreignKey.association: '_PricingConditionType'
      SalesOrderPricingElement.ConditionType,

      //    needed as condition type name is filled without any condition type key for subtotal lines

      SalesOrderPricingElement._PricingConditionType._Text_2[1: Language=$session.system_language].ConditionTypeName as ConditionTypeName,
      
      cast(SalesOrderPricingElement._PricingConditionType._Text_2[1: Language=$session.system_language].ConditionTypeName as priceelementdescription) as PriceElementDescription,

      @ObjectModel.foreignKey.association: '_ConditionCalculationType'
      SalesOrderPricingElement.ConditionCalculationType,
      
      SalesOrderPricingElement.PriceConditionDeterminationDte,

      @Semantics.amount.currencyCode: 'ConditionCurrency'
      SalesOrderPricingElement.ConditionRateAmount,

      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
      SalesOrderPricingElement.ConditionRateRatio,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderPricingElement.ConditionBaseAmount,

      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      SalesOrderPricingElement.ConditionBaseQuantity,

      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      SalesOrderPricingElement.ConditionQuantity,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderPricingElement.ConditionAmount,

      @ObjectModel.foreignKey.association: '_ConditionCurrency'
      SalesOrderPricingElement.ConditionCurrency,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      SalesOrderPricingElement.TransactionCurrency,

      @ObjectModel.foreignKey.association: '_ConditionQuantityUnit'
      SalesOrderPricingElement.ConditionQuantityUnit,

      @ObjectModel.foreignKey.association: '_ConditionRateRatioUnit'
      SalesOrderPricingElement.ConditionRateRatioUnit,

      SalesOrderPricingElement.ConditionIsForStatistics,

      SalesOrderPricingElement.ConditionIsManuallyChanged,

      @ObjectModel.foreignKey.association: '_ConditionInactiveReason'
      SalesOrderPricingElement.ConditionInactiveReason,
      
      @ObjectModel.foreignKey.association: '_ConditionClass'
      SalesOrderPricingElement.ConditionClass,  
      
      @ObjectModel.foreignKey.association: '_ConditionOrigin'
      SalesOrderPricingElement.ConditionOrigin,
            
      @ObjectModel.foreignKey.association: '_ConditionControl'
      SalesOrderPricingElement.ConditionControl,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrderPricingElement.CndnRoundingOffDiffAmount,
                   
      SalesOrderPricingElement.TaxCode,
      
      SalesOrderPricingElement.VariantCondition,
      
      SalesOrderPricingElement.IsGroupCondition_2 as IsGroupCondition,
      
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionRateRatioUnit = ''
          then 'X'
        else ''
      end as boole_d )                                                                                               as ConditionRateValueIsAmount,

      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionRateRatioUnit = ''
          then ''
        else 'X'
      end as boole_d )                                                                                               as ConditionRateValueIsRatio,

      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionCalculationType = 'A'
            or ConditionCalculationType = 'B'
            or ConditionCalculationType = 'H'
            or ConditionCalculationType = 'I'
            or ConditionCalculationType = 'J'
            or ConditionCalculationType = 'K'
            or ConditionCalculationType = 'W'
          then ''
        else 'X'
      end as boole_d )                                                                                               as ConditionBaseValueIsQuantity,

      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionCalculationType = 'A'
            or ConditionCalculationType = 'B'
            or ConditionCalculationType = 'H'
            or ConditionCalculationType = 'I'
            or ConditionCalculationType = 'J'
            or ConditionCalculationType = 'K'
            or ConditionCalculationType = 'W'
          then 'X'
        else ''
      end as boole_d )                                                                                               as ConditionBaseValueIsAmount,
      
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionRateAmount is initial 
           and ConditionRateRatio  is initial
           then 'X'
          else ''
       end as boole_d )                                                                                              as ConditionRateValueIsNull,
       
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionQuantity is initial
           then 'X'
          else ''
       end as boole_d )                                                                                              as ConditionQuantityIsNull,
       
      @Semantics.booleanIndicator: true
      cast(
        case
          when ConditionAmount is initial
           then 'X'
          else ''
       end as boole_d )                                                                                              as ConditionAmountIsNull,              
      
      //for DCL

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,

      //Associations

      _SalesOrder,
      SalesOrderPricingElement._ConditionApplication,
      SalesOrderPricingElement._PricingConditionType,
      SalesOrderPricingElement._ConditionCalculationType,
      SalesOrderPricingElement._ConditionCurrency,
      SalesOrderPricingElement._Currency                                                                             as _TransactionCurrency,
      SalesOrderPricingElement._ConditionQuantityUnit,
      SalesOrderPricingElement._ConditionInactiveReason,
      SalesOrderPricingElement._ConditionClass,
      SalesOrderPricingElement._ConditionOrigin,
      SalesOrderPricingElement._ConditionControl,
      SalesOrderPricingElement._ConditionRateRatioUnit
}