R_SVTProcdMaterialDocumentTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Processed Material Document - TP'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel: {
    usageType:{
        dataClass: #MIXED,
        serviceQuality: #C,  // If #B: Prio 2 View ... (serviceQuality '...') has more than 5 underlying tables (...)

        sizeCategory: #L
      }
}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view entity R_SVTProcdMaterialDocumentTP
  as select from I_SVTPreprocessedDocuments as SVTPreprocessedDocuments
  association [0..1] to I_SVTPurgPrprocgDocument   as _PurchasingDocs           on $projection.SVTPreprocessedDocumentUUID = _PurchasingDocs.SVTConfirmedPurchasingDocUUID
  association [0..1] to I_SVTProdnPrprocgDocument  as _ProductionDocs           on $projection.SVTPreprocessedDocumentUUID = _ProductionDocs.SVTConfirmedProductionDocUUID
  association [0..1] to I_SVTSalesPrprocgDocument  as _SalesDocs                on $projection.SVTPreprocessedDocumentUUID = _SalesDocs.SVTConfirmedSalesDocUUID
  association [0..1] to I_SVTPreprocessingStatus   as _PreprocessingStatus      on $projection.SVTPreprocessingStatus = _PreprocessingStatus.SVTPreprocessingStatus
  association [0..1] to I_SVTBizProcessCategory    as _SVTBizProcCategory       on $projection.SVTBusinessProcessCategory = _SVTBizProcCategory.SVTBusinessProcessCategory
  association [1..1] to I_SVTProdCmplncEvent       as _SVTProdCmplncEvent       on $projection.ProdCmplncEventUUID = _SVTProdCmplncEvent.ProdCmplncEventUUID
  association [0..1] to I_Country                  as _DeliveringCountry        on $projection.DeliveringCountry = _DeliveringCountry.Country
  association [1..1] to I_UnitOfMeasure            as _UnitOfMeasure            on $projection.QuantityUnit = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to I_PlantVH                  as _Plant                    on $projection.Plant = _Plant.Plant
  association [0..1] to I_CompanyCodeVH            as _CompanyCode              on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_ProdCmplncEventType      as _ProdCmplncEventType      on $projection.prodcmplnceventtype = _ProdCmplncEventType.ProdCmplncEventType
  association [0..1] to I_GoodsMovementType        as _GoodsMovementType        on $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType
  association [0..1] to I_InventoryTransactionType as _InventoryTransactionType on $projection.InventoryTransactionType = _InventoryTransactionType.InventoryTransactionType
  association [0..1] to I_AccountingDocumentType   as _AccountingDocumentType   on $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType
  association [0..1] to I_DebitCreditCode          as _DebitCreditCode          on $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
{
  key SVTPreprocessedDocumentUUID,
      MaterialDocument,
      MaterialDocumentItem,
      MaterialDocumentYear,
      Material,
      PostingDate,
      CreationTime,
      CreationDateTime,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      Quantity,
      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      QuantityUnit,
      SVTPreprocessingStatus,
      Plant,
      _Plant.PlantName,
      CompanyCode,
      _CompanyCode.CompanyCodeName,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OrderQuantity,
      OrderQuantityUnit,
      IsDeleted,
      GoodsMovementType,
      DebitCreditCode,
      AccountingDocumentType,
      InventoryTransactionType,
      ProdCmplncEventUUID,
      _SVTProdCmplncEvent.ProdCmplncEventType,
      DeliveringCountry,
      SupplierIsImporter,
      IsReturnsItem,
      DeliveringRegion,
      DlvgLocationIsBondedWarehouse,
      RcvgLocationIsBondedWarehouse,
      SVTBusinessProcessCategory,

      _PurchasingDocs,
      _ProductionDocs,
      _SalesDocs,
      _PreprocessingStatus,
      _ProdCmplncEventType,
      _SVTBizProcCategory,
      _DeliveringCountry,
      _GoodsMovementType,
      _InventoryTransactionType,
      _AccountingDocumentType,
      _DebitCreditCode,
      _UnitOfMeasure
}