R_STOSubcontractingComponent

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #BASIC
}

@ObjectModel: {
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #XL
  }

//  representativeKey: 'ScheduleLine'

}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@EndUserText.label: 'Subcontracting Component for STO'

define view entity R_STOSubcontractingComponent
  as select from R_PurgDocSubcontrgComponent
    inner join   R_StockTransportOrderItem as StockTransportOrderItem on  R_PurgDocSubcontrgComponent.PurchasingDocument     = StockTransportOrderItem.StockTransportOrder
                                                                      and R_PurgDocSubcontrgComponent.PurchasingDocumentItem = StockTransportOrderItem.StockTransportOrderItem


  association to exact one R_StockTransportOrder     as _StockTransportOrder     on  _StockTransportOrder.StockTransportOrder = $projection.StockTransportOrder

  association to exact one R_StockTransportOrderItem as _StockTransportOrderItem on  _StockTransportOrderItem.StockTransportOrder     = $projection.StockTransportOrder
                                                                                 and _StockTransportOrderItem.StockTransportOrderItem = $projection.StockTransportOrderItem

  association to exact one R_STOScheduleLine         as _ScheduleLine            on  $projection.StockTransportOrder     = _ScheduleLine.StockTransportOrder
                                                                                 and $projection.StockTransportOrderItem = _ScheduleLine.StockTransportOrderItem
                                                                                 and $projection.ScheduleLine            = _ScheduleLine.ScheduleLine

  // new asociations for CustomUI


  association to many      I_ProductText             as _ProductText             on  $projection.Product   = _ProductText.Product
  
  association to many      I_UnitOfMeasureText       as _BaseUnitText            on  $projection.BaseUnit  = _BaseUnitText.UnitOfMeasure
  
  association to many      I_UnitOfMeasureText       as _EntryUnitText           on  $projection.EntryUnit = _EntryUnitText.UnitOfMeasure
                      
{


      @ObjectModel.foreignKey.association: '_StockTransportOrder'
  key cast(R_PurgDocSubcontrgComponent.PurchasingDocument as vdm_stocktransportorder preserving type)         as StockTransportOrder,
      @ObjectModel.foreignKey.association: '_StockTransportOrderItem'
  key cast(R_PurgDocSubcontrgComponent.PurchasingDocumentItem as vdm_stocktransportorderitem preserving type) as StockTransportOrderItem,
      @ObjectModel.foreignKey.association: '_ScheduleLine'
  key R_PurgDocSubcontrgComponent.ScheduleLine                                                                as ScheduleLine,
  key R_PurgDocSubcontrgComponent.ReservationItem,
  key R_PurgDocSubcontrgComponent.RecordType,

      cast( R_PurgDocSubcontrgComponent.MaterialRevisionLevel as vdm_qm_revlv preserving type )               as MaterialRevisionLevel,
      cast( R_PurgDocSubcontrgComponent.BillOfMaterialItemNumber as vdm_sposn preserving type )               as BillOfMaterialItemNumber,
      R_PurgDocSubcontrgComponent.Reservation,
      R_PurgDocSubcontrgComponent.Material                                                                    as Product,
      R_PurgDocSubcontrgComponent.BaseUnit,
      R_PurgDocSubcontrgComponent.RequiredQuantity,
      R_PurgDocSubcontrgComponent.RequirementDate,
      R_PurgDocSubcontrgComponent.RequirementTime,
      R_PurgDocSubcontrgComponent.Plant,
      R_PurgDocSubcontrgComponent.LatestRequirementDate,
      R_PurgDocSubcontrgComponent.OrderLevelValue,
      R_PurgDocSubcontrgComponent.OrderPathValue,
      //      R_PurgDocSubcontrgComponent.SortField,

      R_PurgDocSubcontrgComponent.MatlCompFreeDefinedAttribute,
      R_PurgDocSubcontrgComponent.BOMItemCategory,
      R_PurgDocSubcontrgComponent.MaterialComponentIsPhantomItem,
      R_PurgDocSubcontrgComponent.IsBulkMaterialComponent,
      R_PurgDocSubcontrgComponent.AccountAssignmentCategory,
      R_PurgDocSubcontrgComponent.InventorySpecialStockType,
      R_PurgDocSubcontrgComponent.ConsumptionPosting,
      R_PurgDocSubcontrgComponent.InventorySpecialStockValnType,
      R_PurgDocSubcontrgComponent.MaterialProvisionType,

      R_PurgDocSubcontrgComponent.DebitCreditCode,
      R_PurgDocSubcontrgComponent.ReservationIsFinallyIssued,
      R_PurgDocSubcontrgComponent.QuantityInEntryUnit,
      R_PurgDocSubcontrgComponent.EntryUnit,
      R_PurgDocSubcontrgComponent.MaterialQtyToBaseQtyNmrtr,
      R_PurgDocSubcontrgComponent.MaterialQtyToBaseQtyDnmntr,
      R_PurgDocSubcontrgComponent.WithdrawnQuantity,
      R_PurgDocSubcontrgComponent.QuantityIsFixed,
      R_PurgDocSubcontrgComponent.ComponentScrapInPercent,
      R_PurgDocSubcontrgComponent.OperationScrapInPercent,
      R_PurgDocSubcontrgComponent.IsNetScrap,
      R_PurgDocSubcontrgComponent.LeadTimeOffset,
      R_PurgDocSubcontrgComponent.QuantityDistributionKey,
      R_PurgDocSubcontrgComponent.MaterialCompIsVariableSized,
      R_PurgDocSubcontrgComponent.VariableSizeItemQuantity,
      R_PurgDocSubcontrgComponent.VariableSizeItemUnit,
      R_PurgDocSubcontrgComponent.VariableSizeComponentUnit,
      R_PurgDocSubcontrgComponent.VariableSizeComponentQuantity,
      R_PurgDocSubcontrgComponent.UnitOfMeasureForSize1To3,
      R_PurgDocSubcontrgComponent.Size1,
      R_PurgDocSubcontrgComponent.Size2,
      R_PurgDocSubcontrgComponent.Size3,
      R_PurgDocSubcontrgComponent.FormulaKey,
      R_PurgDocSubcontrgComponent.StorageLocation,
      R_PurgDocSubcontrgComponent.ProductionSupplyArea,
      R_PurgDocSubcontrgComponent.Batch,
      R_PurgDocSubcontrgComponent.BOMItemDescription,
      R_PurgDocSubcontrgComponent.BOMItemText2,
      R_PurgDocSubcontrgComponent.ChangeNumber,

      R_PurgDocSubcontrgComponent.SalesOrder,
      R_PurgDocSubcontrgComponent.SalesOrderItem,
      cast ( R_PurgDocSubcontrgComponent.WBSElementInternalID as ps_s4_pspnr preserving type )                as WBSElementInternalID,

      _StockTransportOrder,
      _StockTransportOrderItem,
      _ScheduleLine,

      R_PurgDocSubcontrgComponent._Material,
      R_PurgDocSubcontrgComponent._Product,
      R_PurgDocSubcontrgComponent._VariableSize1To3Unit,
      R_PurgDocSubcontrgComponent._VariableSizeCompUnit,
      R_PurgDocSubcontrgComponent._BaseUnit,
      R_PurgDocSubcontrgComponent._EntryUnit,
      
      // Text associations for CustomUI

      _ProductText,
      _BaseUnitText,
      _EntryUnitText
}