R_REIntegObjectPartAssgmtTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'REPartnerRelationUUID'
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'REPartnerRelationUUID' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'IntegrationObject Partner Assignment TP'
define view entity R_REIntegObjectPartAssgmtTP
  as select from I_REPartnerAssgmt as _REPartnerAssgmt
  association        to parent R_REIntegrationObjectTP as _REIntegrationObjectTP on  $projection.InternalRealEstateNumber = _REIntegrationObjectTP.InternalRealEstateNumber

  association [1..1] to I_REPartnerAssgmtAddl          as _REPartnerAssgmtAddl   on  $projection.InternalRealEstateNumber  = _REPartnerAssgmtAddl.InternalRealEstateNumber
                                                                                 and $projection.BusinessPartner           = _REPartnerAssgmtAddl.BusinessPartner
                                                                                 and $projection.BusinessPartnerRole       = _REPartnerAssgmtAddl.BusinessPartnerRole
                                                                                 and $projection.ValidityStartEndDateValue = _REPartnerAssgmtAddl.ValidityStartEndDateValue
  association [1..1] to I_REEntryValidity     as _REEntryValidity                on  $projection.REEntryValidity           = _REEntryValidity.REEntryValidity
                                                                                 
{
  key REPartnerRelationUUID,
  key InternalRealEstateNumber,
      BusinessPartner,
      BusinessPartnerRole,
      cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
      @Semantics.businessDate.from: true
      cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )     as ValidityEndDate,

      @ObjectModel.foreignKey.association: '_REEntryValidity'
      case
          when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
          when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
          else cast ('1' as recavdmentryvalidity)
      end                                                                 as REEntryValidity,

      case
          when ValidityStartDate is initial and ValidityEndDate is initial then 3
          when ValidityStartDate > $session.system_date then 2
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
      else 1
      end                                                                 as REEntryValidityCriticality,

      cast ('' as rebpvdmmainpartner)                                     as REIsMainPartner,

      0                                                                   as REMainPartnerCriticality,

      REPartnerRoleType,
      AddressType,
      REFractionalPrptyShrRatio,
      REOwnershipShrRatio,
      RECoOwnershipShrRatio,
      REFractionalShrCnvrsnRatio,
      ContractAccount,

      _REIntegrationObjectTP,
      _REPartnerAssgmtAddl,
      _BusinessPartner,
      _BusinessPartnerRole,
      _REPartnerRoleType,
      _BusinessPartnerAddressType,
      _REEntryValidity 

}
where
     // _REIntegrationObjectTP.RealEstateObjectType                  = 'J5'

      InternalRealEstateNumber like 'J5%'
// DPP Business Partner compliance

// based on decision 2023-03-01, blocking shifted to DCL, in order to consider uthorization to access blocked data

//  and _REPartnerAssgmt._BusinessPartner.IsBusinessPurposeCompleted = ''