R_REContrSalesRuleTermTP

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'RETermNumber'
@Analytics.technicalName: 'RRETMSALESRULETP'
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'RETermNumber', 'RETermType', 'ValidityStartDate' ]
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Real Estate Sales Rule Term TP'
define view entity R_REContrSalesRuleTermTP
  as select distinct from I_RESalesRuleTerm as _REContrSalesRuleTerm
  association to parent R_REContractTP as _REContract on $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
{
  key InternalRealEstateNumber,
  key RETermNumber,
  key RETermType,
  key cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
  key RESalesReportingTermNumber,
  key RESalesItemNumberGrading,
      @Semantics.businessDate.from: true
      cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )     as ValidityEndDate,

      RETermName,
      RealEstateObjectType,
      REStatusObject,

      RESalesRule,

      REIsPeakSalesRule,
      RESalesRuleIsUsingPeriodicPost,

      //      Assignment Reporting Rule

      RESalesCurrency,
      RESalesUnit,
      RESalesAmountType,
      RESalesQuantityAmountType,
      REMinSalesAmount,
      REMinSalesRptgIntervalAmount,
      REMinSalesQuantity,
      REMinSalesRptgIntervalQuantity,
      REMaxSalesAmount,
      REMaxSalesQuantity,

      //      Assignment Reporting Rule Grading

      RESalesUnitGrading,
      REMinSalesGradingAmount,
      REMaxSalesGradingAmount,
      REMinSalesGradingQuantity,
      REMaxSalesGradingQuantity,
      REPerUnitGradingPrice,
      RESalesMinRentGradingAmount,
      RESalesRentGradingPercent,

      _Currency,
      _REContract,
      _REKeyAssgmt,
      _REObjectType,
      _RETerm,
      _RETermType,
      _RESalesRule
      //        _RESalesRuleReporting,

      //        _RESalesRuleRptgGrading

}
where
  _REContract.RealEstateObjectType = 'IS'