R_REContrObjAssgmtTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'REStatusObjectTarget'
@ObjectModel.semanticKey: ['REStatusObjectSource', 'REObjectAssignmentType', 'REStatusObjectTarget', 'ValidityStartDate'  ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'Real Estate Object Assignment TP'


define view entity R_REContrObjAssgmtTP
  as select from I_REObjectAssgmtHier as _REObjectAssgmt
  association        to parent R_REContractTP as _REContract              on  $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [1..1] to I_REEntryValidity     as _REEntryValidity         on  $projection.REEntryValidity = _REEntryValidity.REEntryValidity
  //  association [0..1] to I_REAccountingObject  as _REAccountingObject     on  $projection.REStatusObjectTarget = _REAccountingObject.REAccountingObject

  //  association [0..*] to I_REMeasurement  as _REMeasurement   on  $projection.InternalRealEstateNumber = _REMeasurement.InternalRealEstateNumber

  association [1..1] to I_REObjectAssgmtAddl  as _REObjectAssgmtAddl      on  $projection.REStatusObjectSource      = _REObjectAssgmtAddl.REStatusObjectSource
                                                                          and $projection.REObjectAssignmentType    = _REObjectAssgmtAddl.REObjectAssignmentType
                                                                          and $projection.REStatusObjectTarget      = _REObjectAssgmtAddl.REStatusObjectTarget
                                                                          and $projection.InternalRealEstateNumber  = _REObjectAssgmtAddl.InternalRealEstateNumber
                                                                          and $projection.ValidityStartEndDateValue = _REObjectAssgmtAddl.ValidityStartEndDateValue

  association [1..1] to I_REObjectType        as _REAccountingObjectType  on  $projection.reaccountingobjecttype = _REAccountingObjectType.RealEstateObjectType

  association [1..*] to I_REObjectTypeText    as _REAccountObjectTypeText on  _REAccountObjectTypeText.Language = $session.system_language

{
  key REStatusObjectSource,
  key REObjectAssignmentType,
  key REStatusObjectTarget,
      //  key ValidityStartDate,

  key cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
  key InternalRealEstateNumber,
      @Semantics.businessDate.from: true
      cast( coalesce(ValidityStartDate, '00000000') as rebdvdmvalidfrom ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(ValidityEndDate, '99991231') as rebdvdmvalidto )     as ValidityEndDate,

      @ObjectModel.foreignKey.association: '_REEntryValidity'
      case
      //           when ValidityStartDate is initial then cast ('0' as recavdmentryvalidity)

          when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
          when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
          else cast ('1' as recavdmentryvalidity)
      end                                                                 as REEntryValidity,

      case
      //           when ValidityStartDate is initial then 0

          when ValidityStartDate is initial and ValidityEndDate is initial then 3
          when ValidityStartDate > $session.system_date then 2
          when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
      else 1
      end                                                                 as REEntryValidityCriticality,

      REObjectTypeTarget,
      // REStatusObjectTarget,

      @ObjectModel.editableFieldFor: 'REStatusObjectTarget'
      REStatusObjectTarget                                                as REStatusObjectTargetForEdit,

      @ObjectModel.virtualElement: true
      cast( '' as recaident )                                             as REIdentification,

      @ObjectModel.virtualElement: true
      cast( '' as recavdmidentkey )                                       as REIdentificationKey,
      REOnlyInfoAssgmt,
      //      REStatusObjectSourceIsArchived,

      //      REGenerationType,

      //      REIsMainAsset,

      //      REAssignmentHasMultiple,

      REObjectPossessionStartDate,
      REObjectPossessionEndDate,
      REGroupNumber,
      REObjectGroupName,

      coalesce(_REContractSubject.InternalRealEstateNumber, _REObjectTypeDetails._REKeyAssgmt.InternalRealEstateNumber )         as InternalRealEstateNumberTarget,

      //Contract subject exposure

      _REContractSubject.REContractSubjectNumber,
      _REContractSubject.REContractSubjectDescription,
      _REContractSubject.REContractSubjectClass,
      _REContractSubject.REContractSubjectType,
      _REContractSubject.REAccountingObject,
      _REContractSubject.REAccountingObjectType,

      @ObjectModel.virtualElement: true
      cast( '' as recavdmaccobjident )                                    as REAccountingObjIdentification,

      @ObjectModel.virtualElement: true
      cast( '' as recavdmidentkey )                                       as REAccountingObjIdentKey,
      _REContractSubject.ExternalId,

      _REContractSubject._REContractSubjectClass,
      _REContractSubject._REContractSubjectType,

      _REObjectAssignmentType,
      _REObjectTypeTarget,
      _REEntryValidity,
      //      _REAccountingObject,

      //      _REMeasurement,

      _REAccountingObjectType,
      //      _REGenerationType,

      _REContractSubject,
      _REContract,
      _REObjectAssgmtAddl,
      _REObjectTypeDetails,
      _CostCenter,
      _WBSElement,
      _InternalOrder,
      _FixedAsset,
      _TechnicalObject,
      _REAccountObjectTypeText

}
where
  _REContract.RealEstateObjectType = 'IS'