R_ProductionOrderTP

@AbapCatalog.dataMaintenance: #RESTRICTED
//@AbapCatalog.extensibility: {

//  extensible: true,

//  dataSources: ['_Extension'],

//  elementSuffix: 'ORD',

//  quota: {

//    maximumFields: 204, // calculated with formula for FINS_ORDER - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

//    maximumBytes: 2040  // calculated with formula for FINS_ORDER - 2* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

//  }

//}

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: [ '_PostingRule' ]
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true  // ====> Ist erben OK ??

@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.sapObjectNodeType.name: 'ProductionOrder'
@ObjectModel.representativeKey: 'ProductionOrder'
@Analytics.technicalName: 'RPRODNORDTP'
@ObjectModel.semanticKey: [ 'ProductionOrder']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL  // Still necessary???

@EndUserText.label: 'Production Order Header - TP'

define root view entity R_ProductionOrderTP
  as select from I_ManufacturingOrder as Header

  // BO relations 

  composition [1..*] of R_ProductionOrderItemTP        as _Item  
  composition [0..*] of R_ProductionOrderSequenceTP    as _Sequence
  composition [0..*] of R_ProductionOrderOpComponentTP as _Component

  association [0..*] to R_ProductionOrderOperationTP   as _Operation              on  _Operation.ProductionOrder         = $projection.ProductionOrder
                                                                                  and _Operation.ProductionOrderSequence = '000000'
  association [0..*] to R_ProdnOrderItemSerialNumberTP as _SerialNumber           on  _SerialNumber.ProductionOrder      = $projection.ProductionOrder
  
  association [0..*] to R_EventBasedOrderPostingRuleTP as _PostingRule            on  _PostingRule.OrderID   = $projection.ProductionOrder
                                                                                  and _PostingRule.OrderItem = '0000'
  association [0..1] to R_VariantConfigurationTP      as _VariantConfiguration    on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
                                                                                  and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey                                                                                  
  association [0..*] to R_ProdnOrdOperationCapacityTP as _OrderCapacity           on _OrderCapacity.CapacityRequirement = $projection.CapacityRequirement
  
  // extension association

  association [1..1] to E_ProductionOrder              as _Extension              on  $projection.ProductionOrder = _Extension.ProductionOrder

{
  key cast(ManufacturingOrder as vdm_manufacturingorder preserving type) as ProductionOrder,

      cast(ManufacturingOrder as manufacturingorder preserving type)     as ManufacturingOrder, // still needed for business event


      // Category and Type

      ManufacturingOrderCategory,
      cast(ManufacturingOrderType as aufart preserving type )            as ProductionOrderType,

      // Text

      @Semantics.text: true
      ManufacturingOrderText                                             as ProductionOrderText,
      ManufacturingOrderHasLongText                                      as OrderHasLongText,
      LongTextLanguageCode,

      // Attributes

      ManufacturingOrderImportance                                       as OrderImportance,
      IsMarkedForDeletion,
      IsCompletelyDelivered,
      @Semantics.booleanIndicator
      MfgOrderHasMultipleItems                                           as OrderHasMultipleItems,
      @Semantics.booleanIndicator
      MfgOrderIsPartOfCollvOrder                                         as OrderIsPartOfCollectiveOrder,
      MfgOrderHierarchyLevel                                             as OrderHierarchyLevelValue,
      @Semantics.booleanIndicator
      OrderIsNotCostedAutomatically,
      @Semantics.booleanIndicator
      OrdIsNotSchedldAutomatically,
      ProdnProcgIsFlexible,
      // OrderIsEventBasedPosting,  Invalid name as this is a code => Replace when new name is available

      CombnOrdCombinationIdentifier,

      // Admin data

      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      LastChangeTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      // ETag

      @Semantics.systemDateTime.lastChangedAt: true
      case when LastChangeDate > '00000000' then
             cast( dats_tims_to_tstmp( LastChangeDate, LastChangeTime, '', $session.client, 'NULL' ) as timestampl )
           when LastChangeDate = '00000000' then
             cast( 0 as timestampl )
           end                                                           as LastChangeDateTime,

      // Header Material data

      Product,
      StorageLocation,
      Batch,
      @Semantics.text: true
      GoodsRecipientName,
      @Semantics.text: true
      UnloadingPointName,
      InventoryUsabilityCode,
      MaterialGoodsReceiptDuration,
      QuantityDistributionKey,
      StockSegment,

      // Assignments

      MfgOrderInternalID                                                 as OrderInternalID,
      ReferenceOrder,
      LeadingOrder,
      SuperiorOrder,
      Currency,
      ProductionPlant,
      PlanningPlant,
      cast(MRPArea as berid preserving type )                            as MRPArea,
      MRPController,
      ProductionSupervisor,
      ProductionSchedulingProfile,
      ResponsiblePlannerGroup,
      ProductionVersion,
      SalesOrder,
      SalesOrderItem,
      cast( WBSElementInternalID as  ps_s4_pspnr preserving type )       as WBSElementInternalID,
      Reservation,
      SettlementReservation,
      MfgOrderConfirmation                                               as OrderConfirmationGroup,
      NumberOfMfgOrderConfirmations                                      as NumberOfOrderConfirmations,
      PlannedOrder,
      CapacityRequirement,
      InspectionLot,
      ChangeNumber,
      BasicSchedulingType,
      ForecastSchedulingType,
      SchedulingIsAllowingForBreaks,
      ObjectInternalID,
      ProductConfiguration,
      EffectivityParameterVariant,
      ConditionApplication,
      CapacityActiveVersion,
      CapacityRqmtHasNotToBeCreated,
      OrderSequenceNumber,
      RequestOrderType,      

      // Variant Configuration

      case when ProductConfiguration is not initial
        then
          cast ('ProductionOrder' as sbo_node_type)
        else
          null
      end                                                                 as VarConfigurationBusObjectType,     
      case when ProductConfiguration is not initial
        then
          cast ( ManufacturingOrder as ibobjkey )
        else
          null          
      end                                                                 as VarConfigurationBusObjectKey,

      // Assignments BOO

      BillOfOperationsMaterial,
      BillOfOperationsType,
      BillOfOperationsGroup,
      BillOfOperationsVariant,
      BOOInternalVersionCounter,
      BillOfOperationsUsage,
      BillOfOperationsVersion,
      BOOExplosionDate,
      BOOValidityStartDate,

      // Assignments BOM

      BillOfMaterialCategory,
      cast(BillOfMaterial as pph_stnum preserving type )                 as BillOfMaterial,
      BillOfMaterialVariant,
      BillOfMaterialVariantUsage,
      BillOfMaterialVersion,
      BOMExplosionDate,
      BOMValidityStartDate,

      // Assignments FI/CO

      BusinessArea,
      cast(CompanyCode as bukrs preserving type )                        as CompanyCode,
      ControllingArea,
      ProfitCenter,
      CostCenter,
      cast(ResponsibleCostCenter as pph_kostl preserving type )          as ResponsibleCostCenter,
      CostElement,
      CostingSheet,
      GLAccount,
      ProductCostCollector,
      ActualCostsCostingVariant,
      PlannedCostsCostingVariant,
      ControllingObjectClass,
      FunctionalArea,
      OverheadCode,
      ResultAnalysisInternalID,
      VarianceKey,      
      EventBasedProcessingKey,
      EventBasedPostingMethod,
      OrderSettlementTriggerType,

      // Scheduling

      SchedulingFloatProfile,
      FloatBeforeProductionInWrkDays,
      FloatAfterProductionInWorkDays,
      ReleasePeriodInWorkDays,

      // Dates and Times

      MfgOrderPlannedStartDate                                           as OrderPlannedStartDate,
      MfgOrderPlannedStartTime                                           as OrderPlannedStartTime,
      MfgOrderPlannedEndDate                                             as OrderPlannedEndDate,
      MfgOrderPlannedEndTime                                             as OrderPlannedEndTime,
      MfgOrderPlannedReleaseDate                                         as PlannedReleaseDate,
      MfgOrderScheduledStartDate                                         as OrderScheduledStartDate,
      MfgOrderScheduledStartTime                                         as OrderScheduledStartTime,
      MfgOrderScheduledEndDate                                           as OrderScheduledEndDate,
      MfgOrderScheduledEndTime                                           as OrderScheduledEndTime,
      MfgOrderScheduledReleaseDate                                       as OrderScheduledReleaseDate,
      MfgOrderActualStartDate                                            as OrderActualStartDate,
      MfgOrderActualStartTime                                            as OrderActualStartTime,
      // as mapped in CO03 (MfgOrderItemActualDeliveryDate is not directly visible there)

      MfgOrderItemActualDeliveryDate                                     as OrderActualEndDate,
      MfgOrderActualReleaseDate                                          as OrderActualReleaseDate,
      MfgOrderConfirmedEndDate                                           as OrderConfirmedEndDate,
      MfgOrderConfirmedEndTime                                           as OrderConfirmedEndTime,
      MfgOrderTotalCommitmentDate                                        as TotalCommitmentDate,
      MfgOrderActualCompletionDate                                       as TechnicalCompletionDate,

      // Quantities and UoM

      ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedTotalQty                                            as OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedScrapQty                                            as OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty                                          as OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedScrapQty                                          as OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedReworkQty                                         as OrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      ActualDeliveredQuantity,

      // Associations

      _Item,
      _SerialNumber,
      _Sequence,
      _Component,
      _Operation,
      _PostingRule,
      _VariantConfiguration,
      _OrderCapacity
}
where
  ManufacturingOrderCategory = '10'