R_ProdPlantWorkSchedulingTP_2

@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@Search.searchable: true
@ObjectModel.semanticKey: [ 'Product','Plant' ]
@EndUserText.label: 'Product Plant Work Scheduling - TP'
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view entity R_ProdPlantWorkSchedulingTP_2
  as select from I_ProductWorkScheduling
  association        to parent R_ProductPlantTP_2 as _ProductPlant  on  $projection.Product = _ProductPlant.Product
                                                                    and $projection.Plant   = _ProductPlant.Plant
  association [1..1] to R_ProductTP_2           as _Product         on  $projection.Product = _Product.Product
  association [1]    to E_Productplant          as _ActiveExtension on  $projection.Product = _ActiveExtension.Product
                                                                    and $projection.Plant   = _ActiveExtension.Plant
{
      @Search:{
            defaultSearchElement: true,
            fuzzinessThreshold: 0.8,
            ranking: #HIGH
          }
  key cast (Product as productnumber preserving type ) as Product,
  key Plant,
      MaterialBaseQuantity                             as ProductBaseQuantity,
      UnlimitedOverDelivIsAllowed,
      OverDelivToleranceLimit                          as OverDeliveryTolerancePercent,
      UnderDelivToleranceLimit                         as UnderDeliveryTolerancePercent,
      ProductionInvtryManagedLoc,
      ProdnOrderIsBatchRequired                        as ProductionOrderBatchCode,
      ProdIsWithdrawnFrmProdnBin,
      TransitionMatrixProductsGroup,
      OrderChangeManagementProfile,
      MatlCompIsMarkedForBackflush                     as ProductComponentBackflushCode,
      SetupAndTeardownTime,
      ProductionSchedulingProfile,
      TransitionTime,
      ProcessingTimeInDays,
      ProductionSupervisor,
      ProductProductionQuantityUnit,
      //      HasProductionVersion, //read-only field

      BaseUnit,
      /* Associations */
      _BaseUnitOfMeasure,
      _Plant,
      _Product,
      _ProductionInvtryManagedLoc,
      _ProductionSchedulingProfile,
      _ProductionSupervisor,
      _ProductPlant,
      _ProductProductionQuantityUnit,
      _ProdnOrdBatDetnCodeText,
      _ProdComponentBackflushCodeT,
      _ProductDescription,
      _BaseUnitOfMeasureText,
      _ProdProdnQuantityUnitText
}