R_NoteBasic

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Basis-View für die Notizen'
@ObjectModel: {
  representativeKey: 'NoteBasicUUID'
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.allowExtensions:false
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity R_NoteBasic 
  as select from sgbt_nte_cont 
  association [1]    to I_NoteBasicType as _NoteBasicType
                          on $projection.NoteBasicType = _NoteBasicType.NoteBasicType and
                             $projection.NoteBasicObjectNodeTypeUpper = _NoteBasicType.NoteBasicObjectNodeType 
  association [0..1] to I_Language as _Language
                          on $projection.NoteBasicLanguage = _Language.LanguageISOCode 
  association [0..1] to I_User as _LastChangedByUser
                          on $projection.NoteBasicLastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_User as _CreatedByUser
                        on $projection.NoteBasicCreatedByUser = _CreatedByUser.UserID
{
  key noteid      as NoteBasicUUID,
  cast(objectnodetype as sap_object_node_type preserving type ) as NoteBasicObjectNodeType,
  objectid        as NoteBasicObject,
  notetype        as NoteBasicType,
  langu           as NoteBasicLanguage,
  title           as NoteBasicTitle,
  mimetype        as NoteBasicMIMEType,
  length          as NoteBasicLength,
  creator         as NoteBasicCreatedByUser,
  created         as NoteBasicCreationDateTime,
  changer         as NoteBasicLastChangedByUser,
  changed         as NoteBasicLastChangeDateTime,
  content         as NoteBasicContent,
  
  /* helper fields */
  upper(objectnodetype) as NoteBasicObjectNodeTypeUpper,
  
  /* Association Read Only */
  _NoteBasicType,
  
  /* Association foreign key */
  _Language,
  _LastChangedByUser,
  _CreatedByUser
}