R_MaintNotifItemActivityTP

DDL: R_MAINTNOTIFITEMACTIVITYTP SQL: RMNNTFITMACTTP Type: view_entity TRANSACTIONAL Package: RAP_EAM_NTF

Maintenance Notification Item Activity

R_MaintNotifItemActivityTP is a Transactional CDS View that provides data about "Maintenance Notification Item Activity" in SAP S/4HANA. It reads from 1 data source (I_MaintNotifActivityTechObj) and exposes 22 fields with key fields MaintNotificationActivity, MaintenanceNotification, MaintenanceNotificationItem. It has 1 association to related views. Part of development package RAP_EAM_NTF.

1 data source(s) 22 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintNotifActivityTechObj I_MaintNotifActivityTechObj from

Associations (1)

CardinalityTargetAliasCondition
[1..1] R_MaintenanceNotificationTP _Notif $projection.MaintenanceNotification = _Notif.MaintenanceNotification

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Maintenance Notification Item Activity view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY MaintNotificationActivity MaintNotificationActivity
KEY MaintenanceNotification MaintenanceNotification
KEY MaintenanceNotificationItem MaintenanceNotificationItem
MaintNotifActivitySortNumber MaintNotifActivitySortNumber
MaintNotifActyTxt MaintNotifActyTxt
MaintNotifActivityCodeGroup MaintNotifActivityCodeGroup
MaintNotificationActivityCode MaintNotificationActivityCode
PlannedStartDate PlannedStartDate
PlannedStartTime PlannedStartTime
PlannedEndDate PlannedEndDate
PlannedEndTime PlannedEndTime
MaintNotifActivityCodeCatalog MaintNotifActivityCodeCatalog
IsDeleted IsDeleted
MaintNotifItmActyStrtDateTime
MaintNotifItemActyEndDateTime
MaintNotifItemActyCrtnDateTime
MaintNotifItemActyChgdDateTime
_Item _Item
_Notif _Notif
_MaintNotifActivityCodeGroup _MaintNotifActivityCodeGroup
_MaintNotificationActivityCode _MaintNotificationActivityCode
_MaintenanceNotification _MaintenanceNotification 
//@AbapCatalog.sqlViewName: 'RMNNTFITMACTTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Notification Item Activity'

@Metadata.ignorePropagatedAnnotations: true
//@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}
define view entity R_MaintNotifItemActivityTP as select from I_MaintNotifActivityTechObj 

// Root 

   association [1..1] to R_MaintenanceNotificationTP    as _Notif         on  $projection.MaintenanceNotification = _Notif.MaintenanceNotification
//Parent

    association to parent R_MaintNotificationItemTP as _Item on _Item.MaintenanceNotification = $projection.MaintenanceNotification
                                                                    and _Item.MaintenanceNotificationItem = $projection.MaintenanceNotificationItem

{
 key MaintNotificationActivity,
 key MaintenanceNotification,
 key MaintenanceNotificationItem,   //Damages Number (Sort number for Item)

 MaintNotifActivitySortNumber,      //Activity Number (Sort number for Activity)

 MaintNotifActyTxt,                 //Activity Description

 MaintNotifActivityCodeGroup,       //Code Group - Activities

 MaintNotificationActivityCode,     //Activity Code

 PlannedStartDate,                  //Activity Start Date

 PlannedStartTime,                  //Start Time of Activity

 PlannedEndDate,                    //Activity End Date

 PlannedEndTime,                     //End Time of Activity

 MaintNotifActivityCodeCatalog,
 @Semantics.booleanIndicator: true
 IsDeleted,
       cast (dats_tims_to_tstmp( PlannedStartDate, PlannedStartTime, I_MaintNotifActivityTechObj._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItmActyStrtDateTime
,               
       cast (dats_tims_to_tstmp( PlannedEndDate, PlannedEndTime, I_MaintNotifActivityTechObj._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItemActyEndDateTime
,
       cast (dats_tims_to_tstmp( CreationDate, CreationTime, abap_system_timezone( $session.client,'NULL' ) , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItemActyCrtnDateTime

,               
       cast (dats_tims_to_tstmp( LastChangeDate, LastChangeTime, abap_system_timezone( $session.client,'NULL' ) , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItemActyChgdDateTime

,                 
 
 
// Root View 

    _Item,
    _Notif,
    
// Assocociation 

   _MaintNotifActivityCodeGroup,
   _MaintNotificationActivityCode,
   _MaintenanceNotification
   
}
where 
MaintenanceNotificationItem is not initial

Learn More