R_LegalDocumentTP

@AccessControl:{
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
    }
@EndUserText.label: 'Legal Document'
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    }
}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.sapObjectNodeType.name:'LegalDocument'
define root view entity R_LegalDocumentTP
  as select from I_LcmDocument
  //Child Node

  composition [0..*] of R_LegalDocParCategoryTP as _LegalDocParCategory
  composition [0..*] of R_LegalDocStampTP       as _LegalDocStamp
  composition [0..*] of R_LegalDocObligationTP  as _LegalDocObligation
  composition [0..1] of R_LegalDocTmplInfoTP    as _LegalDocTmplInfo
  composition [0..1] of R_LegalDocAgreementTP   as _LegalDocAgreement

  //Template

  association [0..1] to I_LglCntntMTemplate     as _LglCntntMTemplate on $projection.LglCntntMTmplUUID = _LglCntntMTemplate.LglCntntMTmplUUID

  //Extension

  association [1..1] to E_LegalDocument         as _Extenstion        on $projection.LglCntntMDocumentUUID = _Extenstion.LglCntntMDocumentUUID
{
  key LglCntntMDocumentUUID                                      as LglCntntMDocumentUUID,
      LglCntntMDocument                                          as LglCntntMDocument,
      LglCntntMDocumentLinkedObject                              as LglCntntMDocumentLinkedObject,
      LglCntntMDocumentLinkedObjKey                              as LglCntntMDocumentLinkedObjKey,
      LegalTransaction                                           as LegalTransaction,
      LegalTransactionUUID                                       as LegalTransactionUUID,
      LglCntntMDocContentType                                    as LglCntntMDocContentType,
      LglCntntMLanguage                                          as LglCntntMLanguage,
      DocumentDescription                                        as DocumentDescription,
      LglCntntMDocAccessLvl                                      as LglCntntMDocAccessLvl,
      LegalDocumentSource                                        as LegalDocumentSource,
      // For Etag

      @Semantics.systemDateTime.lastChangedAt: true
      LglCntntMChangedUTCDateTime                                as LglCntntMChangedUTCDateTime,
      LglCntntMChangedByUser                                     as LglCntntMChangedByUser,
      LglCntntMCreatedUTCDateTime                                as LglCntntMCreatedUTCDateTime,
      LglCntntMCreatedByUser                                     as LglCntntMCreatedByUser,
      @Semantics.booleanIndicator: true
      IsEndOfPurposeBlocked                                      as IsEndOfPurposeBlocked,
      InternalDocumentStatus                                     as InternalDocumentStatus,
      LglCntntMDocPaperType                                      as LglCntntMDocPaperType,
      LglCntntMProfile                                           as LglCntntMProfile,
      LglCntntMDocType                                           as LglCntntMDocType,
      LglCntntMDocumentIsTopVersion                              as LglCntntMDocumentIsTopVersion,
      LglCntntMVirtualDocVersKey                                 as LglCntntMVirtualDocVersKey,
      LglCntntMDocAssemblyStatus                                 as LglCntntMDocAssemblyStatus,
      LglCntntMTmplUUID                                          as LglCntntMTmplUUID,
      LglCntntMDocLowTouchLevel                                  as LglCntntMDocLowTouchLevel,
      _LglCntntMTemplate.LglCntntMTmplID                         as LglCntntMTmplID,
      LglCntntMParentDocument                                    as LglCntntMParentDocument,
      LglCntntMIsMandatory                                       as LglCntntMIsMandatory,
      @UI.hidden:true
      DocumentVersion                                            as DocumentVersion,      // Don't cast(DocumentVersion as dokvr)

      LegalDocumentVersion                                       as LegalDocumentVersion, //new field for document version number(NUMC4)

      LglCntntMDocReferenceNumber                                as LglCntntMDocReferenceNumber,
      LglCntntMDocumentKind                                      as LglCntntMDocumentKind,
      LglCntntMMainLinkdObjType                                  as LglCntntMMainLinkdObjType,

      @Feature: 'LCM_DOC_AMENDMENT_TYPE_ENH'
      LglCntntMDocAmendmentType                                  as LglCntntMDocAmendmentType,

      @Feature: 'LCM_DOCUMENT_ENH'
      LglCntntMDocEffectiveFromDate                              as LglCntntMDocEffectiveFromDate,

      @Feature: 'LCM_DOCUMENT_ENH'
      LglCntntMDocEffectiveToDate                                as LglCntntMDocEffectiveToDate,

      @Feature: 'LCM_DOCUMENT_SIGNATURE_ENH'
      LglCntntMSgntrPreference,

      @Feature: 'LCM_DOC_ASSIGN_LINKEDOBJECT'
      LglCntntMMainLinkedObject,

      LglCntntMDocLockedReasonCode                               as LglCntntMDocLockedReasonCode,
      _LglCntntMDocLockedReasonText.LglCntntMDocLockedReasonText as LglCntntMDocLockedReasonText,

      _LegalTransaction.LglTransAccessLvl,
      _LegalTransaction.LglCntntMMainOrgCoCode,
      _LegalTransaction.LglCntntMMainOrgPurOrg,
      _LegalTransaction.LglCntntMMainOrgSalesOrg,

      /* Associations */
      _LegalTransaction,
      _LglCntntMDocAssemblyInfo,
      _LglCntntMTemplate,
      _LegalDocParCategory,
      _LegalDocStamp,
      _LegalDocObligation,
      _LegalDocTmplInfo,
      _LegalDocAgreement

}