R_InsurPolicyContrCoverageTP

@EndUserText.label: 'Contr Coverage in Insurance Policy - TP'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsurPlcyContrCvrgSurcharge',
                                                '_InsurPlcyContrCvrgLimit',
                                                '_InsurPlcyContrCvrgClause',
                                                '_InsurPlcyContrCvrgDeductible',
                                                '_InsurPlcyContrCvrgInsrdObj',
                                                '_InsurPlcyContrCvrgSubCvrg',
                                                '_InsurPlcyContrCvrgPlndProcg']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoverageID',
   semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}

define view entity R_InsurPolicyContrCoverageTP
  as select from I_InsurancePolicyContrCoverage as Coverage

  association        to parent R_InsuranceContractTP   as _InsuranceContract on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                             and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  composition [0..*] of R_InsurPlcyContrCvrgLimitTP    as _InsurPlcyContrCvrgLimit
  composition [0..*] of R_InsurPlcyContrCvrgClauseTP   as _InsurPlcyContrCvrgClause
  composition [0..*] of R_InsurPlcyContrCvrgDcblTP     as _InsurPlcyContrCvrgDeductible
  composition [0..*] of R_InsurPlcyContrCvrgInsrdObjTP as _InsurPlcyContrCvrgInsrdObj
  composition [0..*] of R_InsurPlcyContrCvrgSuDscTP    as _InsurPlcyContrCvrgSurcharge
  composition [0..*] of R_InsurPlcyContrCvrgSubCvrgTP  as _InsurPlcyContrCvrgSubCvrg
  composition [0..*] of R_InsurPlcyContrCvrgPlndDateTP as _InsurPlcyContrCvrgPlndProcg

  association [1..1] to E_InsurancePolicyCoverage      as _Extension         on  $projection.InsurPlcyUUID        = _Extension.InsurPlcyUUID
                                                                             and $projection.InsurPlcyInsurContr  = _Extension.InsurPlcyInsurContr
                                                                             and 0                                = _Extension.InsurPlcyCoveragePackageID
                                                                             and $projection.InsurPlcyCoverageID  = _Extension.InsurPlcyCoverageID
                                                                             and $projection.InsurPlcyJrnlNmbr    = _Extension.InsurPlcyJrnlNmbr
                                                                             and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr

  association [1..1] to E_InsurancePolicyPremium       as _Extension_Prem    on  $projection.InsurPlcyUUID                 = _Extension_Prem.InsurPlcyUUID
                                                                             and $projection.InsurPlcyInsurContr           = _Extension_Prem.InsurPlcyInsurContr
                                                                             and 0                                         = _Extension_Prem.InsurPlcyCoveragePackageID
                                                                             and $projection.InsurPlcyCoverageID           = _Extension_Prem.InsurPlcyCoverageID
                                                                             and 0                                         = _Extension_Prem.InsurPlcyCoverageOptionID
                                                                             and 0                                         = _Extension_Prem.InsurPlcyInsuredObjectID
                                                                             //and 0                                         = _Extension_Prem.InsurPlcyPremSubjectID

                                                                             and $projection.InsurancePolicyPremium        = _Extension_Prem.InsurancePolicyPremium
                                                                             and $projection.InsurPlcyPremiumJournalNumber = _Extension_Prem.InsurPlcyJrnlNmbr
                                                                             and $projection.InsurPlcyPremJournalEndNumber = _Extension_Prem.InsurPlcyJrnlEndNmbr

{

  key Coverage.InsurPlcyUUID,
  key Coverage.InsurPlcyInsurContr,
  key Coverage.InsurPlcyCoverageID,
      Coverage.InsurPlcyJrnlNmbr,
      Coverage.InsurPlcyJrnlEndNmbr,
      Coverage.InsurPlcyProductPackageID   as InsurPolicyContractPackageID,
      Coverage.InsurPlcyInsuranceCoverage,
      Coverage.InsurPlcyElementaryProdTmpl as InsurancePolicyCoverageControl,
      Coverage.InsurPlcyCoverageStartDateTime,
      Coverage.InsurPlcyCoverageEndDateTime,
      Coverage.InsurPlcyCvrgPremExmpReason,
      Coverage.InsurPlcyCvrgLifeCycleStatus,
      Coverage.InsurContrCanclnRsn,
      Coverage.InsurPlcyCvrgCanclnDateTime,
      Coverage.InsurPlcyCoverageSuspension,
      Coverage.InsurPlcyCvrgSuspnStrtDateTime,
      Coverage.InsurPlcyCvrgSuspnEndDateTime,
      Coverage.InsurPlcyCvrgInsuredSumAmount,
      Coverage.InsurPlcyCvrgInsrdSumCalcMeth,
      Coverage.InsurPlcyCvrgInsuredSumPercent,
      Coverage.InsurPlcyCoverageCurrency,
      Coverage.LastChangeDateTime,
      Coverage.InsurancePolicyPremium,
      Coverage.InsurPlcyPremiumJournalNumber,
      Coverage.InsurPlcyPremJournalEndNumber,
      Coverage.InsurPerdPremBfrTaxPaytAmt,
      Coverage.InsurPerdPremAftTaxPaytAmt,
      Coverage.InsurPremType,
      Coverage.InsurPlcyCvrgIsPremiumExempt,
      Coverage.InsurPlcyCvrgPremExmpEndDate,
      Coverage.InsurPlcyPremiumCurrency,
      Coverage.InsurPlcyTotAnnPremAmt,
      Coverage.InsurPlcyPerdPremBfrTxPaytAmt,
      Coverage.InsurPlcyPremiumTemplate    as InsurancePolicyPremiumControl,

      /* Associations */
      _InsuranceContract,
      _InsurPlcyContrCvrgSurcharge,
      _InsurPlcyContrCvrgLimit,
      _InsurPlcyContrCvrgClause,
      _InsurPlcyContrCvrgDeductible,
      _InsurPlcyContrCvrgInsrdObj,
      _InsurPlcyContrCvrgSubCvrg,
      _InsurPlcyContrCvrgPlndProcg

}