R_InsurPlcyContrObjClauseTP

@EndUserText.label: 'InsOb Clause of Contr in Insur Plcy - TP'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyClauseID',
   semanticKey: [ 'InsurPlcyClauseID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}

define view entity R_InsurPlcyContrObjClauseTP
  as select from I_InsurPlcyContrInsrdObjClause as Clause

  association        to parent R_InsurPlcyContrInsrdObjectTP as _InsurPlcyContrInsuredObject on  $projection.InsurPlcyUUID            = _InsurPlcyContrInsuredObject.InsurPlcyUUID
                                                                                             and $projection.InsurPlcyInsurContr      = _InsurPlcyContrInsuredObject.InsurPlcyInsurContr
                                                                                             and $projection.InsurPlcyInsuredObjectID = _InsurPlcyContrInsuredObject.InsurPlcyInsuredObjectID

  association [1..1] to E_InsurancePolicyClause              as _Extension                   on  $projection.InsurPlcyUUID            = _Extension.InsurPlcyUUID
                                                                                             and $projection.InsurPlcyInsurContr      = _Extension.InsurPlcyInsurContr
                                                                                             and 0                                    = _Extension.InsurPlcyCoveragePackageID
                                                                                             and 0                                    = _Extension.InsurPlcyCoverageID
                                                                                             and 0                                    = _Extension.InsurPlcySubCvrgID
                                                                                             and $projection.InsurPlcyInsuredObjectID = _Extension.InsurPlcyInsuredObjectID
                                                                                             and $projection.InsurPlcyClauseID        = _Extension.InsurPlcyClauseID
                                                                                             and 0                                    = _Extension.InsurPlcyCoverageOptionID
                                                                                             and 0                                    = _Extension.InsurPlcyUndrwrtgDcsnRiskID
                                                                                             and $projection.InsurPlcyJrnlNmbr        = _Extension.InsurPlcyJrnlNmbr
                                                                                             and $projection.InsurPlcyJrnlEndNmbr     = _Extension.InsurPlcyJrnlEndNmbr

{

  key Clause.InsurPlcyUUID,
  key Clause.InsurPlcyInsurContr,
  key Clause.InsurPlcyInsuredObjectID,
  key Clause.InsurPlcyClauseID,
      Clause.InsurPlcyJrnlNmbr,
      Clause.InsurPlcyJrnlEndNmbr,
      Clause.InsurPlcyProductPackageID as InsurPolicyContractPackageID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'
      Clause.InsurPlcyClauseTemplate   as InsurancePolicyClauseControl,
      Clause.InsurPlcyIndivClauseAgrmtText,
      Clause.InsurPlcyClauseDetailTextUUID,
      Clause.LongText,
      Clause.TextObjectCategory,
      Clause.TextObjectKey,
      Clause.Language,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyClauseType'
      Clause.InsurPlcyClauseType,
      Clause.InsurPlcyClauseStartDate,
      Clause.InsurPlcyClauseEndDate,
      Clause.LastChangeDateTime,

      /* Associations */
      _InsurPlcyContrInsuredObject

}