R_IN_GSTRetsSlsRegDocumentTP

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Document header view parent root view'
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #XL,
    dataClass: #MIXED
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity R_IN_GSTRetsSlsRegDocumentTP
  as select from               I_IN_GSTRetsSlsRegDocument

  //    left outer one to one join  I_EDCElectronicDocRelation    on I_IN_GSTRetsSlsRegDocument.ElectronicDocUUID = I_EDCElectronicDocRelation.ElectronicDocUUID

    left outer one to one join I_EDCRelation                  on  I_IN_GSTRetsSlsRegDocument.ElectronicDocUUID = I_EDCRelation.EDCRepresentationKey
                                                              and I_EDCRelation.EDCRepresentationType          = 'EDOCUMENT'


    left outer one to one join I_EDCRecords                   on I_EDCRecords.EDCRecordUUID = I_EDCRelation.EDCRecordUUID
    left outer one to one join I_EDCResult                    on  I_EDCResult.EDCRecordUUID          = I_EDCRelation.EDCRecordUUID
                                                              and I_EDCResult.EDCResultProcessStatus = 'CREATED'

    left outer one to one join I_ElectronicDocProcessTextTP   on I_ElectronicDocProcessTextTP.ElectronicDocProcess = I_EDCResult.EDCResultProcess

    left outer one to one join I_IN_GSTRetsSlsRegStateCode    on I_IN_GSTRetsSlsRegStateCode.Region = I_IN_GSTRetsSlsRegDocument.IN_GSTPlaceOfSupply

    left outer one to one join I_ElectronicDocProcStatusText  on  I_ElectronicDocProcStatusText.ElectronicDocProcessStatus = I_IN_GSTRetsSlsRegDocument.ElectronicDocProcessStatus
                                                              and I_ElectronicDocProcStatusText.ElectronicDocProcess       = 'INGSTR1'

    left outer one to one join R_IN_EDCLastConsistencyCheckTP on  I_IN_GSTRetsSlsRegDocument.CompanyCode       = R_IN_EDCLastConsistencyCheckTP.EDCCompany
                                                           

  association [0..*] to R_SalesRegisterSummaryTP      as _SalesRegSummaryTP           on $projection.EDCRecordUUID = I_IN_GSTRetsSlsRegDocument.ElectronicDocUUID

  association [0..1] to I_IN_OutgInvcTxAttrib         as _InvoiceTaxAttribute         on _InvoiceTaxAttribute.BillingDocument = I_IN_GSTRetsSlsRegDocument.BillingDocument

  association [0..1] to R_IN_EDocGSTRetsSalesRegister as _IN_EDocGSTRetsSalesRegister on _IN_EDocGSTRetsSalesRegister.ElectronicDocUUID = I_IN_GSTRetsSlsRegDocument.ElectronicDocUUID

  composition [0..*] of R_IN_GSTRetsSlsRegTaxItemTP   as _TaxItemDetails
  //  composition [0..*] of R_SalesRegisterSummaryTP as _SalesRegSummaryTP

  //  composition [1] of R_IN_EDCLastConsistencyCheckTP as _ConsistencyCheck



{
  key I_IN_GSTRetsSlsRegDocument.ElectronicDocUUID,
  key I_IN_GSTRetsSlsRegDocument.CompanyCode,
      I_IN_GSTRetsSlsRegDocument.BusinessPlace,
      cast( I_IN_GSTRetsSlsRegDocument.IN_EDocEInvcExtNmbr as gl_in_einvno )                                            as IN_EDocEInvcExtNmbr, // Invoice Number

      cast( I_IN_GSTRetsSlsRegDocument.ReportingDate as glo_in_vatdate )                                                as ReportingDate,  // Reporting Date

      cast( I_IN_GSTRetsSlsRegDocument.ReportingDate as glo_in_invoice_date )                                           as IN_InvoiceDate, // Invoice Date

      cast( I_IN_GSTRetsSlsRegDocument.IN_InvoiceType as glo_in_invoice_type)                                           as IN_InvoiceType,
      cast( I_ElectronicDocProcStatusText.ElectronicDocProcStatusText as glo_in_invoice_status )                        as ElectronicDocProcStatusText, // Invoice Status

      cast(case I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode
              when 'B2CL' then 'Not Applicable'
              when 'B2CS' then 'Not Applicable'
              when 'NIL' then 'Not Applicable'
              when 'AT' then 'Not Applicable'
              when 'TXP' then 'Not Applicable'
              when 'CDNUR' then 'Not Applicable'
              else (case I_EDCRecords.EDCMetaStatus
                      when '0001' then 'Content Match'
                      else I_ElectronicDocProcessTextTP.ElectronicDocProcessText end ) end as glo_in_recon_status )     as ElectronicDocProcessText, // Reconcillation Status

      cast( I_IN_GSTRetsSlsRegStateCode.IN_GSTPlaceOfSupplyName as glo_in_placeofsupply )                               as IN_GSTPlaceOfSupplyName, // Place Of Supply

      cast( I_IN_GSTRetsSlsRegDocument.IN_PrtnGSTIdentificationNmbr as glo_in_partnergstin )                            as IN_PrtnGSTIdentificationNmbr,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast( I_IN_GSTRetsSlsRegDocument.GrossAmount as glo_in_totalamount )                                              as InvoiceGrossAmount, // Invoice Amount

      //cast( I_IN_GSTRetsSlsRegDocument.InvoiceGrossAmount as glo_in_totalamount )                                     as InvoiceGrossAmount, // Invoice Amount

      I_IN_GSTRetsSlsRegDocument.FiscalYear, // Fiscal year

      cast( I_IN_GSTRetsSlsRegDocument.IN_GSTIdentificationNumber as glo_in_taxpayergstin )                             as IN_GSTIdentificationNumber, // TaxPayer GSTIN

      cast( I_IN_GSTRetsSlsRegDocument.BusinessPartnerFullName as glo_in_businesspartnername )                          as BusinessPartnerFullName, // CounterParty Name

      cast( I_IN_GSTRetsSlsRegDocument.IN_IsGSTReverseCharged as glo_in_reversecharge )                                 as IN_IsGSTReverseCharged, // RCM Flag

      //      cast( I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode as glo_in_doc_section ) as IN_DocumentSectionCode,         // Invoice Type

      cast ( case
      when _IN_EDocGSTRetsSalesRegister.IN_EDocAmendmentDte is not initial and I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode = 'EXP'
      then  'EXPA'
      else
        I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode
      end      as glo_in_doc_section )                                                                                  as IN_DocumentSectionCode,

      cast( I_IN_GSTRetsSlsRegDocument.ReportingCountry as glo_in_country )                                             as ReportingCountry, //Country / Region

      cast( I_IN_GSTRetsSlsRegDocument.IN_NoteType as glo_in_notetype )                                                 as IN_NoteType, // Note Type

      cast(case
             when I_IN_GSTRetsSlsRegDocument.IN_HasNilType = ' ' and I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode = 'NIL'
             then 'Nil'
             when I_IN_GSTRetsSlsRegDocument.IN_HasNilType = ' ' and I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode <> 'NIL'
             then 'Not Applicable'
             when I_IN_GSTRetsSlsRegDocument.IN_HasNilType = 'X' and I_IN_GSTRetsSlsRegDocument.IN_DocumentSectionCode <> 'NIL'
             then 'Partial Nil' end as glo_in_taxcode_type )                                                            as IN_GSTTaxCodeTypeText, //Nil Indicator

      //      I_IN_GSTRetsSlsRegDocument.CompanyCode,                   // Company Code

      cast( I_IN_GSTRetsSlsRegDocument.AccountingDocument as glo_in_account_doc )                                       as AccountingDocument,
      I_IN_GSTRetsSlsRegDocument.BillingDocument,
      I_IN_GSTRetsSlsRegDocument.CompanyCodeCurrency,
      //      I_EDCElectronicDocRelation.EDCRecordUUID,

      I_EDCRelation.EDCRecordUUID,
      I_EDCResult.EDCResultProcess,
      I_EDCResult.EDCResultSqncNmbr,
      I_EDCResult.EDCResultUUID,
      R_IN_EDCLastConsistencyCheckTP.IN_EDCCheckValue,
      -- I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.ElectronicDocSourceKey,
      cast( I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.IN_ElectronicDocInvcRefNmbr as glo_in_einv_irn )        as IN_ElectronicDocInvcRefNmbr, //IRN Number

      cast( I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.IN_ElectronicDocAcknDate as glo_in_einv_ack_date )      as IN_ElectronicDocAcknDate,
      cast( case I_IN_GSTRetsSlsRegDocument._ElectronicDocEInvc.ElectronicDocProcess
               when 'INEINV' then (case I_IN_GSTRetsSlsRegDocument._ElectronicDocEInvc.ElectronicDocProcessStatus
                                      when 'CANC' then 'Canceled'
                                      else 'Active' end ) end as glo_in_einv_ewb_status )                               as IN_ElectronicInvoiceText,
      cast( I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.IN_EDocEInvcEWbillNmbr as glo_in_einv_ewbno )           as IN_EDocEInvcEWbillNmbr,
      cast( I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.IN_EDocEInvcEWbillCreateDate as glo_in_einv_ewb_date )  as IN_EDocEInvcEWbillCreateDate,
      cast( I_IN_GSTRetsSlsRegDocument._IN_ElectronicDocInvoice.IN_EDocEInvcEWbillValidityDate as glo_in_einv_validto ) as IN_EDocEInvcEWbillValidityDate,

      _IN_EDocGSTRetsSalesRegister.IN_EDocAmendmentDte                                                                  as IN_EDocAmendmentDte,
      _InvoiceTaxAttribute.IN_ShippingBillDate                                                                          as IN_ShippingBillDate,
      _InvoiceTaxAttribute.IN_ShippingBillNumber                                                                        as IN_ShippingBillNumber,
      _InvoiceTaxAttribute.IN_ShippingBillPortNumber                                                                    as IN_ShippingBillPortNumber,
      //Associations

      _TaxItemDetails,
      //      _ConsistencyCheck,

      _SalesRegSummaryTP
}