R_GLAccountInOperatingCOATP

@AbapCatalog.sqlViewName: 'RGLACCTOPCOATP'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Trnsctnl View GL Acct in Oper. COA'
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #CUSTOMIZING
}
define view R_GLAccountInOperatingCOATP
  as select from I_GLAccountInChartOfAccounts
  association        to parent R_OperatingChartOfAccountsTP as _root            on  $projection.ChartOfAccounts = _root.ChartOfAccounts
  association [0..1] to I_GLAccountInChartOfAccounts        as _GLAcct          on  $projection.ChartOfAccounts = _GLAcct.ChartOfAccounts
                                                                                and $projection.GLAccount       = _GLAcct.GLAccount
  association [0..1] to I_ChartOfAccounts                   as _ChartOfAccounts on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  composition [0..*] of R_CoCodeGLAcctOpgCOATP              as _CoCodeAssignment
{
  key ChartOfAccounts,
      @UI: { lineItem: [ {
                          position:    20,
                          importance: #HIGH,
                          label:      'G/L Account'//,

                           } ],
             identification: [ { position: 20 } ] }
      //  @Consumption.filter.selectionType: #SINGLE

      //  @Consumption.valueHelpDefinition: [{ entity: { name:    'I_GLAccount',

      //                                                 element: 'GLAccount' } }]

      @Consumption.semanticObject: 'GLAccount'
      @Search.defaultSearchElement:true
      //    @EndUserText.label: 'G/L Account Number'

      //    @EndUserText.quickInfo: 'G/L Account Number'

  key GLAccount,
      @UI: { lineItem: [ { position: 25,
                         importance: #MEDIUM
                          } ],
      identification: [ { position: 25 } ] }

      @EndUserText.label: 'G/L Account Short Text'

      _Text[1: Language = $session.system_language].GLAccountName                                           as GLAccountName,

      @UI: { lineItem: [ { position: 30,
                         importance: #MEDIUM
                          } ],
      identification: [ { position: 30 } ] }

      @EndUserText.label: 'G/L Account Type'
      @EndUserText.quickInfo: 'G/L Account Type'
      @ObjectModel.text.element: ['GLAccountTypeName']
      @UI.textArrangement: #TEXT_LAST
      GLAccountType,
      @Semantics.text: true
      @EndUserText.label: 'G/L Account Type Name'
      @EndUserText.quickInfo: 'G/L Account Type Name'
      _GLAcct._GLAccountType._GLAccountTypeText[1: Language =  $session.system_language].GLAccountTypeName  as GLAccountTypeName,

      @UI: { lineItem: [ { position: 40,
                           importance: #MEDIUM                          } ],
       identification: [ { position: 40 } ] }
      @EndUserText.label: 'G/L Account Group'
      @EndUserText.quickInfo: 'G/L Account Group'
      @ObjectModel.text.element: ['AccountGroupName']
      @UI.textArrangement: #TEXT_LAST
      GLAccountGroup,
      @Semantics.text: true
      @EndUserText.label: 'G/L Account Group Name'
      @EndUserText.quickInfo: 'G/L Account Group Name'
      _GLAcct._GLAccountGroup._GLAccountGroupText[1: Language =  $session.system_language].AccountGroupName as AccountGroupName,

      @UI: { lineItem: [ { position: 50,
                         importance: #MEDIUM  } ],
      identification: [ { position: 50 } ] }
      @ObjectModel.text.element: ['CorporateGroupAccountName']
      @UI.textArrangement: #TEXT_LAST
      CorporateGroupAccount                                                                                 as CorporateGroupAccount,
      _GLAcct._CorporateGroupAccount._Text[1: Language = $session.system_language].GLAccountName            as CorporateGroupAccountName,
      @EndUserText.label: 'G/L Account Long Text'
      @EndUserText.quickInfo: 'G/L Account Long Text'
      _Text[1: Language = $session.system_language].GLAccountLongName                                       as GLAccountLongName,

      //      _root.FinancialStatementHierarchy as FinancialStatementHierarchy,

      //     _GLAcctInChartOfAcctsStatus.GLAcctCOAImplementStatus,


      AccountIsMarkedForDeletion                                                                            as AccountIsMarkedForDeletion,
      GLAccountExternal                                                                                     as GLAccountExternal,
      GLAccountSubtype                                                                                      as GLAccountSubtype,
      BankReconciliationAccount                                                                             as BankReconciliationAccount,
      @EndUserText.label: 'P&L Statement Acct'
      ProfitLossAccountType                                                                                 as ProfitLossAccountType,
      _root,
      _ChartOfAccounts,
      _GLAcct,
      _GLAcctInChartOfAcctsStatus,
      _CoCodeAssignment

}