R_FinTransUnfixedFlow

@AbapCatalog.sqlViewName: 'RFINTRANSUNFFLOW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Financial Transaction Unfixed Flow'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #BASIC
define view R_FinTransUnfixedFlow
  as select from vtbfhapo_unfixed as Flow
    inner join   I_CompanyCode    as CompanyCode on Flow.bukrs = CompanyCode.CompanyCode
{
  key Flow.bukrs                                                                                            as CompanyCode,
  key Flow.rfha                                                                                             as FinancialTransaction,
  key Flow.rfhazu                                                                                           as FinancialInstrumentActivity,
  key Flow.dcrdat                                                                                           as FinTransFlowCreationDate,
  key cast( Flow.tcrtim as ftr_flow_creation_time preserving type )                                         as FinTransFlowCreationTime,
  key Flow.rfhazb                                                                                           as FinTransFlowNumber,

      Flow.rantyp                                                                                           as TreasuryContractType,
      cast( Flow.sbktyp as ftr_flow_category preserving type )                                              as FinTransFlowCategory,
      Flow.sfhazba                                                                                          as FinTransFlowType,

      @Semantics.amount.currencyCode: 'FinTransFlowPaytAmtCrcy'
      cast( Flow.bzbetr as ftr_flow_payment_amount preserving type )                                        as FinTransFlowPaytAmt,
      Flow.wzbetr                                                                                           as FinTransFlowPaytAmtCrcy,
      cast( Flow.ssign as ftr_flow_payment_amt_direction preserving type )                                  as FinTransFlowPaytAmtDirection,
      @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
      cast( case
            when Flow.bnwhr is not initial
              then Flow.bnwhr
            when Flow.bbbetr is not initial
              then Flow.bbbetr
            else Flow.bzbetr
            end as ftr_flow_norminal_amount )                                                               as FinTransFlowNomAmt,
      cast( case
            when Flow.wprice is not initial
              then Flow.wprice
            when Flow.wbbetr is not initial
              then Flow.wbbetr
            else Flow.wzbetr
            end as ftr_flow_norminal_amount_crcy preserving type )                                          as FinTransFlowNomAmtCrcy,
      @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
      cast( Flow.bbbetr as ftr_position_amount preserving type )                                            as FinTransFlowPositionAmount,
      Flow.wbbetr                                                                                           as FinTransFlwPosAmtCrcy,
      @Semantics.amount.currencyCode: 'LocalCurrency'
      Flow.bhwbetr                                                                                          as FinTransFlowInLoclCrcyPaytAmt,
      CompanyCode.Currency                                                                                  as LocalCurrency,

      cast( Flow.khwkurs as ftr_flow_rate_in_locl_crcy preserving type )                                    as FinTransFlowLoclCrcyCnvrsnRate,
      cast( Flow.dzterm as ftr_flow_payment_date preserving type )                                          as FinTransFlowPaymentDate,

      Flow.dfaell                                                                                           as FinTransFlowPaymentDueDate,
      cast( Flow.dbuchung as ftr_flow_posting_date preserving type )                                        as FinTransFlowPostingDate,
      Flow.dzfest                                                                                           as FinTransFlowIntrstRateFixDate,

      Flow.dbervon                                                                                          as CalculationPeriodStartDate,
      Flow.sultvon                                                                                          as CalcPeriodStartDateIsMonthEnd,
      Flow.dberbis                                                                                          as CalculationPeriodEndDate,
      Flow.sultbis                                                                                          as CalcPeriodEndDateIsMonthEnd,
      Flow.atage                                                                                            as NumberOfCalculationDays,
      Flow.szbmeth                                                                                          as InterestCalculationMethod,
      @Semantics.amount.currencyCode: 'FinTransFlowCalcBaseAmountCrcy'
      Flow.bbasis                                                                                           as FinTransFlowCalcBaseAmount,
      Flow.wbasis                                                                                           as FinTransFlowCalcBaseAmountCrcy,

      Flow.pkond                                                                                            as ConditionPercentageRate,

      Flow.present_id                                                                                       as FinTransPresentationItemID,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FinTransFlowFixingStatus'
      Flow.sbewebe                                                                                          as FinTransFlowPostingStatus,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FinTransFlowFixingBlkgReason'
      Flow.ssprgrd                                                                                          as FinTransFlowPostingBlkgReason,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FinTransFlowIsFixingReleased'
      Flow.sbfrei                                                                                           as FinTransFlowPostingRelease,

      Flow.sbewebe                                                                                          as FinTransFlowFixingStatus,
      Flow.ssprgrd                                                                                          as FinTransFlowFixingBlkgReason,
      Flow.sbfrei                                                                                           as FinTransFlowIsFixingReleased,

      Flow.regi_state                                                                                       as FinInterestRateAdjmtStatus,
      cast( Flow.rpcode as farp_repetitive_code )                                                           as RepetitiveCode,
      Flow.rahabki                                                                                          as HouseBank,
      Flow.rahktid                                                                                          as HouseBankAccount,
      Flow.rpzahl                                                                                           as PayerPayee,
      Flow.rpbank                                                                                           as PayerPayeeBankDetail,
      Flow.zlsch                                                                                            as PaymentMethod,
      CompanyCode.Country                                                                                   as Country,
      Flow.zwels                                                                                            as PaymentMethodsList,
      Flow.uzawe                                                                                            as PaymentMethodSupplement,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'TreasuryPaymentIsIndividual'
      Flow.sprsng                                                                                           as TreasuryIndividualPayment,
      Flow.sprsng                                                                                           as TreasuryPaymentIsIndividual,
      Flow.scspay                                                                                           as TrsyPaytGroupingSameDrctnIsRqd,
      Flow.sprgrd                                                                                           as TreasuryPaymentRequestGrouping,
      Flow.paygr                                                                                            as TreasuryIntGrpgForPaytValue,
      Flow.prkey                                                                                            as PaymentRequest,

      Flow.rkondgr                                                                                          as FinancialTransactionDirection,
      cast( Flow.logic_rkond as ftr_instr_cndn_logic_group preserving type )                                as FinInstrConditionLogicGroup,
      Flow.dguel_kp                                                                                         as ConditionItemValidityStartDate,
      Flow.rkond                                                                                            as FinConditionItem,
      Flow.nstufe                                                                                           as FinConditionSubItem,

      Flow.zuonr                                                                                            as AssignmentReference,
      Flow.skhwfix                                                                                          as FinTransFlwLoclCrcyAmtCalcType,
      Flow.dvalut                                                                                           as FinTransFlowCalculationDate,
      cast( case
            when Flow.sincl = '1' then 'X'
            when Flow.sincl = '0' then ''
            end as tb_nomsexcl preserving type )                                                            as FlowCalcDateIsExclusive,
      Flow.svult                                                                                            as FlowCalcDateIsMonthEnd,
      Flow.skalidwt                                                                                         as IntrstCalcMethFactoryCalendar,
      cast ( case
            when Flow.jexpozins      = 'X' then '1'
            when Flow.jexpozins      = 'L' then '5'
            else '0'
            end as tfmsintcalc )                                                                            as InterestCalculationType,
      cast ( case
                  when Flow.sexclvon  = '0' then 'X'
                  when Flow.sexclvon  = '1' then ''
                  end as  tb_sinclv preserving type )                                                       as CalcPeriodStartDateIsInclusive,
      cast ( case
            when Flow.sinclbis = '0' then ''
            when Flow.sinclbis = '1' then 'X'
            end as tb_sinclb)                                                                               as CalcPeriodEndDateIsInclusive,
      Flow.sabverf                                                                                          as FinTransFlwDerivationProcedure,
      Flow.pwkurs                                                                                           as FinTransPaytRateInPercent,
      Flow.payment_reason                                                                                   as PaymentReason,
      cast( Flow.cruser as ftr_flow_cruser)                                                                 as FinTransFlowCreatedByUser,
      cast( Flow.upuser as ftr_flow_upuser)                                                                 as FinTransFlowLastChangedByUser,
      cast( Flow.dupdat as ftr_flow_dupdat)                                                                 as FinTransFlowLastChangeDate,
      cast( Flow.tuptim as ftr_flow_tuptim)                                                                 as FinTransFlowLastChangeTime,
      Flow.sbzvabw                                                                                          as FinTransFlwAltvPaytDetIsStated,
      cast( case
            when Flow.szart = 'X' then ''
            when Flow.szart = '' then 'X' end as ftr_payt_is_posted_to_gl)                                  as TrsyPaytIsPostdToGLAccount,
      Flow.spayrq                                                                                           as TrsyPaytRequestIsGenerated,
      Flow.sstornobwg                                                                                       as FinTransFlowIsReversed,
      Flow.abastage                                                                                         as NrOfBaseDaysPerCalcPeriod,
      Flow.sbwgartref                                                                                       as FinTransFlowReferencedFlowType,
      Flow.index_value                                                                                      as FinTransFlowPriceIndexValue,
      Flow.rp_text                                                                                          as RepetitiveCodeReferenceText,
      Flow.lzbkz                                                                                            as StateCentralBankPaymentReason,
      Flow.landl                                                                                            as TrsyPaymentSupplyingCountry,
      @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
      cast( Flow.bdirty as ftr_payt_accrued_intrst_amount)                                                  as PaymentWithAccruedIntrstAmount,
      Flow.grouping_term                                                                                    as FinTransFlwDerivdFlwGrpgTerm,
      cast( Flow.fx_fixing_date as ftr_fixing_ref_date)                                                     as FXRateAdjustmentFixingDate,
      Flow.fx_regi_state                                                                                    as FXRateAdjustmentStatus,
      Flow.fx_read_date                                                                                     as FinTransFlowFXRateReadDate,
      Flow.priceindex_fix_date_low                                                                          as PrcIdxAdjmtFixingLowDate,
      Flow.priceindex_read_date_low                                                                         as FinTransFlowPrcIdxReadLowDate,
      Flow.priceindex_fix_date_high                                                                         as PrcIdxAdjmtFixingHighDate,
      Flow.priceindex_read_date_high                                                                        as FinTransFlowPrcIdxReadHighDate,
      Flow.priceindex_regi_state                                                                            as PrcIdxAdjustmentStatus,
      @Semantics.amount.currencyCode: 'FinTransFlowPaytAmtCrcy'
      Flow.bbbetr_idxclean                                                                                  as FinTransFlowIndexCleanAmount,
      @Semantics.booleanIndicator: true
      cast( case when Flow.payment_reason_changed = '1' then 'X' else '' end as ftr_payment_reason_is_chgd) as FinTransFlowPaytRsnIsChgd,
      Flow.sum_rkond                                                                                        as FinCndnCrsRefcdAccmlnCndnGrp,
      Flow.sum_id_source                                                                                    as FinTransFlwReltdAccumulatingID,
      Flow.sum_id_sum                                                                                       as FinTransFlowAccumulatingFlowID,

      Flow.saend                                                                                            as FinTransFlowModificationStatus, // GUI ALV field ICON_MODIFIED depends on this


      // connection key for transaction management and position management

      // explicit cast for performance

      cast( case when Flow.rantyp = '2'
            then concat(Flow.bukrs, concat(Flow.rfha, concat(cast( Flow.rfhazu as abap.char(5) ), 'X01'))) // Securities has special external business transaction construction logic

            else concat(Flow.bukrs, concat(Flow.rfha, concat(cast( Flow.rfhazu as abap.char(5) ), concat(cast( Flow.dcrdat as abap.char(8) ), concat(cast( Flow.tcrtim as abap.char(6) ), cast( Flow.rfhazb as abap.char(4) ))))))
      end as ftr_gen_tm_bus_transaction )                                                                   as TrsyTransacMgmtBizTransaction

}