R_FinTransConditionTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel:{
    usageType : {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }
}
@EndUserText.label: 'Financial Transaction Condition - TP'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view entity R_FinTransConditionTP
  as select from I_FinTransCondition

  composition [0..*] of R_FinTransCndnSingleDateTP as _ConditionSingleDate

  composition [0..*] of R_FinTransCndnFmlaVarblTP  as _CndnVariableInterestFormula

  composition [0..*] of R_FinTransCndnScaleTP      as _ConditionScale

  association to parent R_FinancialTransactionTP   as _FinancialTransaction on  $projection.CompanyCode          = _FinancialTransaction.CompanyCode
                                                                            and $projection.FinancialTransaction = _FinancialTransaction.FinancialTransaction

{

  key  CompanyCode,
  key  FinancialTransaction,
  key  FinancialInstrumentActivity,
  key  FinancialTransactionDirection,
  key  FinConditionItem,
  key  ConditionItemValidityStartDate,

       // Condition Header

       FinConditionForm,       
       FinInstrConditionLogicGroup,
       TreasuryContractType,
       FinConditionConditionCategory,
       FinConditionConditionType,

       // Fixed Interest 

       InterestCalculationMethod,
       InterestCalculationType,
       FinConditionInterestCategory,
       ConditionPercentageRate,
       FinConditionFormulaReference,
       InterestReference,
       FinConditionFixedAmount,
       FinConditionFixedAmountCrcy,
       
       // Repayment Details

       FinConditionRpaytPercentRate,
       FinConditionRpaytBaseAmount,
       FinConditionRpaytAmount,
       FinConditionRpaytCurrency,

       //FinConditionHasSingleDateEntry,


       // Calculation Date

       CalculationDate,
       FinCndnCalcDteUpdateRule,
       FinCndnCalcDteFrequency,
       FinCndnCalcDteFrqcyUnit,
       CalcDateIsAsEndDateInclusive,
       CalcDateIsAsEndDateMonthEnd,
       FinCndnCalcDteWrkgDayShft,
       FinCndnCalcDteShftDrctn,
       FinCndnCalcDteShftNrOfDays,

       // Due Date

       DueDate,
       FinCndnDueDteUpdateRule,
       FinCndnDueDteFrequency,
       FinCndnDueDteFrqcyUnit,
       DueDateIsAsEndDateInclusive,
       DueDateIsAsEndDateMonthEnd,
       FinCndnDueDteWrkgDayShft,
       FinCndnDueDteShftDrctn,
       FinCndnDueDteShftNrOfDays,

       // Calendars

       FinConditionFactoryCalendar1,
       FinConditionFactoryCalendar2,
       FinConditionFactoryCalendar3,
       FinConditionFactoryCalendar4,
       FinConditionFactoryCalendar5,

       // Exponential Interest Calculation

       ExponentialIntrstSettlmtFrqcy, 
       IntrstCalcMethFactoryCalendar, 
       FinancialConditionPaymentRate,
       InterestMarkupMarkdownValue, 
       InterestFirstPeriodRate,
       
       // Average Interest Calculation

       AverageIntrstRateWeightingCat, 
       AverageIntrstRateRndngCategory,
       AverageIntrstRateRndngDecimals,
       AverageInterestRateSpreadValue, 
       AvgIntrstRateHasUsedUpperLimit,    
       AverageInterestUpperLimitRate, 
       AvgIntrstRateHasUsedLowerLimit, 
       AverageInterestLowerLimitRate, 
       AverageIntrstRateResetCalcEvt, 

       // Rounding Interest Factor

       FinCndnRateFactorRndngCategory,
       FinCndnRateFactorRndngDecimals,
       FinCndnFactorRoundingCategory, // Exponential Interest Cal with Factor

       FinCndnFactorRoundingDecimals,
       FinCndnBaseFactorRndngCategory,
       FinCndnBaseFactorRndngDecimals,
       
       // Rounding Amount

       FinCndnAmountRoundingCategory,
       FinCndnAmountRoundingUnit,
       RndngBaseUntAmtInCndnItmCrcy,

       // Calculation Base

       FinConditionIntrstBaseAmount, 
       FinCndnCalcBaseReference,
       FinCndnProcessingSequenceValue,
       
       // Currency Related Data

       FinCndnAmountTimeUnit,
       FinCndnLimitAmountCurrency,
       FinCndnItmHasUsedLowerLimitAmt,
       FinCndnItemLowerLimitAmount,
       FinCndnItmHasUsedUpperLimitAmt,
       FinCndnItemUpperLimitAmount,
       
       // Referenced condition group

       FinCndnCrsRefcdAccmlnCndnGrp,
       RefcdIntrstRateAdjmtCondition,
       RefcdPrcIdxAdjmtCondition,
       

       InterestCalculationDateRef,
       InterestDueDateReference,
       CalcDteIsRegularWithVarblDte,
       DueDteIsRegularWithVarblDte,
       
       // Other Calculation Data

       FinCndnFirstPeriodCalcMethod,
       FinCndnLastPeriodCalcMethod,
       FinCndnDueDteShiftToTermEnd,
       FinCndnPaytDateWrkgDayShft,
       FinCndnRpaytSettlmt,

       // Interest Rate Adjustment

       InterestRateAdjustmentDateRule,
       InterestRateAdjustmentFrqcy,
       InterestRateAdjmtFrqcyUnit,
       InterestRateAdjustmentDate,
       IntrstRateAdjmtDateIsMonthEnd,
       IntrstRateAdjmtDteIsExclusive,
       IntrstRateAdjmtDateWrkgDayShft,
       IntrstRateAdjmtShftNrOfDays,
       FinCndnAdjmtDteShftDrctn,

       // Interest Rate Fixing Date

       InterestRateFixingDateRule,
       InterestRateFixingFrqcy,
       InterestRateFixingFrqcyUnit,
       InterestRateFixingDate,
       IntrstRateFixingDateIsMonthEnd,
       FinCndnFixingDteShftDrctn,
       InterestRateFixingShftNrOfDays,
       IntrstRateFixDteShftIsModifd,
       InterestRateFixingDateRef,
       FinCndnRateFixingLockoutPeriod,

       //CE2508 -  Price Index Adjustment - general attributes

       TreasuryPriceIndex,
       PriceIndexInterpolationMethod,
       PriceIndexApplicationMethod,
       PrcIdxFctrCalcCompoundingFrqcy,
       FinCndnDayFracRoundingCat,
       FinCndnDayFracRoundingDcmls,

       //CE2508 -  Price Index Adjustment - reference date for index adjustment date

       PrcIdxAdjmtDateReference,
       PrcIdxAdjmtDateWrkgDayShift,
       PrcIdxAdjmtDateShftDrctn,
       PrcIdxAdjmtShftNrOfDays,

       //CE2508 - Price Index Adjustment - index base value

       PriceIndexAdjustmentBaseDate,
       //PrcIdxAdjmtBaseValue,


       //CE2508 - Price Index Adjustment - fixing date

       PrcIdxAdjmtFixingLowDate,
       PrcIdxAdjmtFixingHighDate,
       PrcIdxAdjmtFxngDteWrkgDayShft,
       PrcIdxAdjmtFixingDateShftDrctn,
       PrcIdxAdjmtFxngDteShftNrOfDays,

       //CE2508 - FX Rate Adjustment - FX rate reference

       FinConditionSettlementCrcy,
       ForeignExchangeFixingReference,

       //CE2508 - FX Rate Adjustment - fixing date

       FXRateAdjmtFixingDateRef,
       FXRateAdjmtFixingDateShftDrctn,
       FXRateAdjmtFxngDteShftNrOfDays,
       FXRateAdjmtFxngDteShftIsModifd,


       _FinancialTransaction.FinancialInstrProductCategory as FinancialInstrProductCategory,

       //association

       _ConditionScale,
       _CndnVariableInterestFormula,
       _ConditionSingleDate,
       
       _FinancialTransaction,
       @Consumption.hidden: true
       _FinTrans
}