R_FinTransCashFlowTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel:{
    usageType : {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }
}
@EndUserText.label: 'Financial Transaction Cash Flow - TP'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view entity R_FinTransCashFlowTP
  as select from I_FinTransFlow
  association to parent R_FinancialTransactionTP as _FinancialTransaction on  $projection.CompanyCode          = _FinancialTransaction.CompanyCode
                                                                          and $projection.FinancialTransaction = _FinancialTransaction.FinancialTransaction
{

  key  CompanyCode,
  key  FinancialTransaction,
  key  FinancialInstrumentActivity,
  key  FinTransFlowCreationDate,
  key  FinTransFlowCreationTime,
  key  FinTransFlowNumber,
       FinTransFlowCreatedByUser,
       FinTransFlowLastChangedByUser,
       FinTransFlowLastChangeDate,
       FinTransFlowLastChangeTime,
       TreasuryContractType,
       FinTransFlowType,
       _FinancialTransaction.FinancialInstrProductCategory,
       FinTransFlowPaytAmtDirection,
       FinTransFlwDerivationProcedure,
       FinancialTransactionDirection,
       FinTransFlwAltvPaytDetIsStated,
       HouseBank,
       HouseBankAccount,
       PayerPayee,
       PayerPayeeBankDetail,
       TrsyPaytIsPostdToGLAccount,
       PaymentMethod,
       PaymentMethodSupplement,
       TrsyPaytRequestIsGenerated,
       TreasuryPaymentIsIndividual,
       TreasuryPaymentRequestGrouping,
       TrsyPaytGroupingSameDrctnIsRqd,
       PaymentMethodsList,
       TreasuryIntGrpgForPaytValue,
       FinTransFlowFixingStatus,
       FinTransFlowFixingBlkgReason,
       FinTransFlowIsFixingReleased,
       FinTransFlowModificationStatus,
       FinTransFlowIsReversed,
       FinTransFlowPaymentDueDate,
       FinTransFlowPaymentDate,
       FinTransFlowPaytAmt,
       FinTransFlowPaytAmtCrcy,
       FinTransFlowPositionAmount,
       FinTransFlwPosAmtCrcy,
       FinTransFlowInLoclCrcyPaytAmt,
       LocalCurrency,
       FinTransFlowLoclCrcyCnvrsnRate,
       FinTransFlowNomAmt,
       FinTransFlowNomAmtCrcy,
       CalculationPeriodStartDate,
       CalculationPeriodEndDate,
       NumberOfCalculationDays,
       NrOfBaseDaysPerCalcPeriod,
       ConditionPercentageRate,
       FinTransFlowIntrstRateFixDate,
       FinTransFlowCalcBaseAmount,
       FinTransFlowCalcBaseAmountCrcy,
       FlowCalcDateIsExclusive,
       CalcPeriodEndDateIsInclusive,
       CalcPeriodEndDateIsMonthEnd,
       CalcPeriodStartDateIsInclusive,
       CalcPeriodStartDateIsMonthEnd,
       FinTransFlowCalculationDate,
       FlowCalcDateIsMonthEnd,
       FinTransFlowReferencedFlowType,
       FinTransFlwLoclCrcyAmtCalcType,
       AssignmentReference,
       FinTransPaytRateInPercent,
       FinTransFlowPriceIndexValue,
       FinInterestRateAdjmtStatus,
       PaymentRepetitiveCode,
       RepetitiveCodeReferenceText,
       StateCentralBankPaymentReason,
       TrsyPaymentSupplyingCountry,
       PaymentWithAccruedIntrstAmount,
       FinInstrConditionLogicGroup,
       FinTransFlwDerivdFlwGrpgTerm,
       FXRateAdjustmentFixingDate,
       FXRateAdjustmentStatus,
       FinTransFlowFXRateReadDate,
       PrcIdxAdjmtFixingLowDate,
       FinTransFlowPrcIdxReadLowDate,
       PrcIdxAdjmtFixingHighDate,
       FinTransFlowPrcIdxReadHighDate,
       PrcIdxAdjustmentStatus,
       FinTransFlowIndexCleanAmount,
       PaymentReason,
       FinTransFlowPaytRsnIsChgd,
       FinCndnCrsRefcdAccmlnCndnGrp,
       FinTransFlwReltdAccumulatingID,
       FinTransFlowAccumulatingFlowID,

       cast ( case when FinTransFlowFixingStatus = '1' and ( TrsyPaytRequestIsGenerated = 'X' or TrsyPaytIsPostdToGLAccount = '') then '1'
       when _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '4' or _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '9' then '5'
       when ( _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '2' or _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '8' ) and _FlowAcctgPaytInfo.TrsyPaytRequestReleaseStatus = '0' then '2'
       when ( _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '2' or _FlowAcctgPaytInfo.TreasuryPaymentRequestStatus = '8' ) and _FlowAcctgPaytInfo.TrsyPaytRequestReleaseStatus <> '0' then '3'
       else '0' end as tb_spayind ) as FinTransFlowPaymentStatus,

       TrsyTransacMgmtBizTransaction,

       _FlowAcctgPaytInfo,
       _FinancialTransaction,
       @Consumption.hidden: true
       _FinTrans
}