R_EnterpriseProjectElementJVA

DDL: R_ENTERPRISEPROJECTELEMENTJVA Type: view_entity BASIC Package: VDM_PPM_OBJECTS_TP_TASK

Basic view for Joint Vntr Account on WBS

R_EnterpriseProjectElementJVA is a Basic CDS View that provides data about "Basic view for Joint Vntr Account on WBS" in SAP S/4HANA. It reads from 2 data sources (prps, /s4ppm/task) and exposes 14 fields with key field TaskUUID. It has 3 associations to related views. Part of development package VDM_PPM_OBJECTS_TP_TASK.

2 data source(s) 14 fields

Data Sources (2)

SourceAliasJoin Type
prps prps inner
/s4ppm/task task from

Associations (3)

CardinalityTargetAliasCondition
[1..1] R_EnterpriseProjectElement _Element $projection.TaskUUID = _Element.ProjectElementUUID
[1..1] R_EnterpriseProject _EnterpriseProject $projection.ProjectUUID = _EnterpriseProject.ProjectUUID
[1..1] I_JointVentureMasterFld jv $projection.JointVenture = jv.JointVenture and task.companycode = jv.CompanyCode

Annotations (10)

NameValueLevelField
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.compositionRoot false view
ObjectModel.representativeKey TaskUUID view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #L view
EndUserText.label Basic view for Joint Vntr Account on WBS view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY TaskUUID /s4ppm/task guid
ProjectUUID /s4ppm/task project_guid
WBSElementInternalID
JointVenture prps vname
JointVentureCostRecoveryCode prps recid
JointVentureEquityType prps etype
JntVntrProjectType prps otype
JntIntrstBillgClass prps jibcl
JntIntrstBillgSubClass prps jibsa
JointVentureType jv JointVentureType
ControllingArea
ProfitCenter prps prctr
_EnterpriseProject _EnterpriseProject
_Element _Element 
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
   compositionRoot: false,
   representativeKey: 'TaskUUID',
   alternativeKey: [ { id : 'WBSElementInternalID', uniqueness: #UNIQUE } ],
   usageType: {
     serviceQuality:  #B,
     dataClass:       #MIXED, 
     sizeCategory:    #L
    }
}

@EndUserText.label: 'Basic view for Joint Vntr Account on WBS'
define view entity R_EnterpriseProjectElementJVA
    as select from /s4ppm/task    as task
      inner join   prps           as prps on prps.pspnr = task.pspnr
   
   association [1..1] to R_EnterpriseProjectElement as _Element                  on $projection.TaskUUID     = _Element.ProjectElementUUID
   association [1..1] to R_EnterpriseProject        as _EnterpriseProject        on $projection.ProjectUUID  = _EnterpriseProject.ProjectUUID
   association [1..1] to I_JointVentureMasterFld    as jv                        on $projection.JointVenture = jv.JointVenture
                                                                                and task.companycode         = jv.CompanyCode
{
  key task.guid                       as TaskUUID,
      task.project_guid               as ProjectUUID,
      cast ( task.pspnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      
      prps.vname                      as JointVenture,
      prps.recid                      as JointVentureCostRecoveryCode, 
      prps.etype                      as JointVentureEquityType, 
      prps.otype                      as JntVntrProjectType, 
      prps.jibcl                      as JntIntrstBillgClass, 
      prps.jibsa                      as JntIntrstBillgSubClass,
      jv.JointVentureType             as JointVentureType,
      
      cast ( prps.pkokr as ps_s4_kokrs preserving type ) as ControllingArea,
      prps.prctr                                         as ProfitCenter,
      
      _EnterpriseProject,
      _Element  
}

Learn More