R_EntProjectPublicSector

@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
   compositionRoot: false,
   representativeKey: 'ProjectUUID',
   alternativeKey: [ { id : 'ProjectSummaryTaskUUID', uniqueness: #UNIQUE } ],
   usageType: {
     serviceQuality:  #B,
     dataClass:       #MIXED, 
     sizeCategory:    #L
    }
}

@EndUserText.label: 'Basic view for ent proj public sector'
define view entity R_EntProjectPublicSector 
  as select from /s4ppm/project as project
    inner join   /s4ppm/task    as task on  task.project_guid = project.guid
                                        and task.object_type  = 'DPO'
    inner join   proj           as proj on proj.pspnr = project.pspnr
    inner join   prps           as prps on prps.pspnr = task.pspnr
  
  association [1..1] to R_EnterpriseProject as _Root on $projection.ProjectUUID = _Root.ProjectUUID
  
{
  key project.guid                    as ProjectUUID,
      task.guid                       as ProjectSummaryTaskUUID,
      cast ( project.pspnr as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
      cast ( task.pspnr    as ps_s4_pspnr      preserving type ) as WBSElementInternalID,

      prps.rfund                      as Fund,
      prps.fund_fix_assign            as FundIsFixAssigned,
      prps.func_area                  as FunctionalArea,
      prps.func_area_fix_assigned     as FunctionalAreaIsFixAssigned,
      prps.rgrant_nbr                 as GrantID,
      prps.grant_fix_assigned         as GrantIsFixAssigned,
      prps.sponsoredprog              as SponsoredProgram,
      prps.is_avc_check_level         as WBSIsAvailyControlControlObj,
      
      cast ( prps.pkokr as ps_s4_kokrs preserving type ) as ControllingArea,
      prps.prctr                                         as ProfitCenter,

      _Root
     
}