R_EntProjectElementForUpdate

@VDM.viewType: #COMPOSITE 

@AbapCatalog.sqlViewName: 'RPROJELEM4UPD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel:{
   semanticKey:       [ 'ProjectElement' ],
   representativeKey: 'TaskUUID',
   alternativeKey: [ { id : 'WBSElementInternalID', uniqueness: #UNIQUE, element: [ 'WBSElementInternalID' ] } ],
   usageType: {
     serviceQuality:  #B,
     dataClass:       #MIXED,
     sizeCategory:    #L
   }
}

@EndUserText.label: 'Lists all elements a user is permitted and able to update'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API 
define view R_EntProjectElementForUpdate as select from R_EnterpriseProjectElement as Workpackage
  // associations to authorization views need to be overwritten, as we need to check for write here

    association [0..*] to I_PPM_AuthznByUsrH        as _AuthUser
            on      _AuthUser.ReferencedObjectUUID   = $projection.TaskUUID
             and    _AuthUser.UserID                 = $session.user
             and (  _AuthUser.Activity = 'Admin'     or _AuthUser.Activity = 'Write' )
    association [0..*] to I_PPM_AuthznBySubstitH    as _AuthSubst 
            on      _AuthSubst.ReferencedObjectUUID  = $projection.TaskUUID
             and    _AuthSubst.UserID                = $session.user
             and (  _AuthSubst.Activity = 'Admin'    or _AuthSubst.Activity = 'Write' )
    association [0..*] to I_PPM_AuthznByUserRoleH   as _AuthRole
            on      _AuthRole.ReferencedObjectUUID   = $projection.TaskUUID
             and    _AuthRole.UserID                 = $session.user
             and (  _AuthRole.Activity = 'Admin'     or _AuthRole.Activity = 'Write' )
    association [0..*] to I_PPM_AuthznByUsrGrpH     as _AuthGroup
            on      _AuthGroup.ReferencedObjectUUID  = $projection.TaskUUID
             and    _AuthGroup.UserID                = $session.user
             and (  _AuthGroup.Activity = 'Admin'    or _AuthGroup.Activity = 'Write' )
{
  key Workpackage.ProjectElementUUID                 as TaskUUID,
      Workpackage.ProjectElement                     as ProjectElement,
      Workpackage.WBSElementInternalID,
      Workpackage.ProjectUUID                        as ProjectUUID,
      
      ControllingArea,
      ProfitCenter, 
      CompanyCode, 
      ResponsibleCostCenter, 
      Plant,
      FunctionalArea,
      
      cast( 'X' as boolean preserving type ) as IsEditable,         
      
      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup,
      _EnterpriseProject
  
}