R_EntProjElementPublicSector

@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
   compositionRoot: false,
   representativeKey: 'TaskUUID',
   alternativeKey: [ { id : 'WBSElementInternalID', uniqueness: #UNIQUE } ],
   usageType: {
     serviceQuality:  #A,
     dataClass:       #MIXED, 
     sizeCategory:    #L
    }
}

@EndUserText.label: 'Basic View for Public Sector on WBS'
define view entity R_EntProjElementPublicSector 
      as select from /s4ppm/task    as task
      inner join   prps             as prps on prps.pspnr = task.pspnr
   
   association [1..1] to R_EnterpriseProjectElement as _Element                  on $projection.TaskUUID     = _Element.ProjectElementUUID
   association [1..1] to R_EnterpriseProject        as _EnterpriseProject        on $projection.ProjectUUID  = _EnterpriseProject.ProjectUUID
{
  key task.guid                       as TaskUUID,
      task.project_guid               as ProjectUUID,
      cast ( task.pspnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      
      prps.rfund                      as Fund,
      prps.fund_fix_assign            as FundIsFixAssigned,
      prps.func_area                  as FunctionalArea,
      prps.func_area_fix_assigned     as FunctionalAreaIsFixAssigned,
      prps.rgrant_nbr                 as GrantID,
      prps.grant_fix_assigned         as GrantIsFixAssigned,
      prps.sponsoredprog              as SponsoredProgram,
      prps.is_avc_check_level         as WBSIsAvailyControlControlObj,
      
      cast ( prps.pkokr as ps_s4_kokrs preserving type ) as ControllingArea,
      prps.prctr                                         as ProfitCenter,
      
      _EnterpriseProject,
      _Element
}