R_DngrsGdsBasicClassfctnDetTP

@EndUserText.label: 'DG Basic Classification Detail - TP'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:
{
  sapObjectNodeType.name: 'DngrsGdsBscClassfctnDetails',
  representativeKey:  'CmplRqRsltDngrsGdsBscDetsUUID',
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L, // <10.000.000

    serviceQuality: #C // <= 15 msec

  }
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity R_DngrsGdsBasicClassfctnDetTP
  --Select data from basic view 'Chemical Component'
  as select from I_CmplRqRsltDngrsGdsBscDets as DngrsGdsBscClassfctnDetails
  association        to parent R_DngrsGdsBasicClassfctnTP as _DngrsGoodsBasicClassification on  $projection.CmplRqRsltUUID = _DngrsGoodsBasicClassification.CmplRqRsltUUID

  association [0..1] to I_ClassifiedAsDangerousGood       as _ClassifiedAsDangerousGood     on  _ClassifiedAsDangerousGood.ClassifiedAsDangerousGood = $projection.ClassifiedAsDangerousGood
  association [0..1] to I_DangerousGdsClassOrDivision     as _DangerousGdsClassOrDivision   on  _DangerousGdsClassOrDivision.DangerousGoodsClass = $projection.DangerousGoodsClass
  association [0..1] to I_DangerousGoodsPackingGroup      as _DangerousGoodsPackingGroup    on  _DangerousGoodsPackingGroup.DangerousGoodsPackingGroup = $projection.DangerousGoodsPackingGroup
  // Regulatory Data of selected UN Number

  association [0..1] to I_CmplRqVersDngrsGdsPart1Item     as _CmplRqVersDngrsGdsPart1Item   on  $projection.ProdCmplncDngrsGdsIdnNmbr     = _CmplRqVersDngrsGdsPart1Item.DangerousGoodsIdnNumber
                                                                                            and $projection.ProdCmplncDngrsGdsIdnNmbrType = _CmplRqVersDngrsGdsPart1Item.DangerousGoodsIdnNumberType
                                                                                            and $projection.DangerousGoodsPackingGroup    = _CmplRqVersDngrsGdsPart1Item.DangerousGoodsPackingGroup
                                                                                            and $projection.DangerousGoodsListItemVariant = _CmplRqVersDngrsGdsPart1Item.DangerousGoodsListItemVariant
                                                                                            and $projection.CmplRqVersUUID                = _CmplRqVersDngrsGdsPart1Item.CmplRqVersUUID
  association [0..1] to I_Substance                       as _DngrsGdsTechName1Substance    on  $projection.DngrsGdsTechName1SubstUUID = _DngrsGdsTechName1Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsTechName2Substance    on  $projection.DngrsGdsTechName2SubstUUID = _DngrsGdsTechName2Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsTechName3Substance    on  $projection.DngrsGdsTechName3SubstUUID = _DngrsGdsTechName3Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsMarnPlltnt1Substance  on  $projection.DngrsGdsMarnPlltnt1SubstUUID = _DngrsGdsMarnPlltnt1Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsMarnPlltnt2Substance  on  $projection.DngrsGdsMarnPlltnt2SubstUUID = _DngrsGdsMarnPlltnt2Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsRptblQty1Substance  on  $projection.DngrsGdsRptblQty1SubstUUID = _DngrsGdsRptblQty1Substance.SubstanceUUID
  association [0..1] to I_Substance                       as _DngrsGdsRptblQty2Substance  on  $projection.DngrsGdsRptblQty2SubstUUID = _DngrsGdsRptblQty2Substance.SubstanceUUID

{
  key DngrsGdsBscClassfctnDetails.CmplRqRsltDngrsGdsBscDetsUUID,
      DngrsGdsBscClassfctnDetails.CmplRqRsltUUID,
      DngrsGdsBscClassfctnDetails.CmplRqVersUUID,

      @Semantics.systemDateTime.createdAt: true
      DngrsGdsBscClassfctnDetails.CreationDateTime,
      @Semantics.user.createdBy: true
      DngrsGdsBscClassfctnDetails.CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      DngrsGdsBscClassfctnDetails.LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      DngrsGdsBscClassfctnDetails.LastChangedByUser,      

      DngrsGdsBscClassfctnDetails.ClassifiedAsDangerousGood,
      cast( case DngrsGdsBscClassfctnDetails.ClassifiedAsDangerousGood
      when '' then ' '
      when '01' then ' '
      when '02' then ' '
      when '03' then 'X'
      end as productisnodangerousgood preserving type )       as ProductIsNoDangerousGood,
      DngrsGdsBscClassfctnDetails.DangerousGoodsIdnNumberType as ProdCmplncDngrsGdsIdnNmbrType,
      DngrsGdsBscClassfctnDetails.DangerousGoodsIdnNumber     as ProdCmplncDngrsGdsIdnNmbr,
      DngrsGdsBscClassfctnDetails.DangerousGoodsClass,
      DngrsGdsBscClassfctnDetails.DangerousGoodsPackingGroup,
      DngrsGdsBscClassfctnDetails.PackingInstruction          as DngrsGdsPackingInstructionText,
      DngrsGoodDescForDocsTmplText,
      DangerousGoodsListItemVariant,
      DngrsGdsQualifgWordPrefix,
      DngrsGdsQualifgWordSuffix,
      DngrsGdsTechName1SubstUUID,
      DngrsGdsTechName2SubstUUID,
      DngrsGdsTechName3SubstUUID,
      DngrsGdsTechName1PosOnSrce,
      DngrsGdsTechName2PosOnSrce,
      DngrsGdsTechName3PosOnSrce,
      ProdIsEnvironmentalHazardous,
      DngrsGdsMarnPlltnt1SubstUUID,
      DngrsGdsMarnPlltnt2SubstUUID,
      ProductIsMarinePollutant,
      ProductIsToxicByInhalation,
      DngrsGdsRptblQty1SubstUUID,
      DngrsGdsRptblQty2SubstUUID,
      ReportableQtyIsPrintedOnDoc,
      ToxicByInhalationHazardZone,
//      BasicClassfctnIsOverwritten,

//      DngrsGdsDescTmplIsOverwritten,

//      EnclosureVariant,

//      SpecialProvisionOrExemptionTxt,

//      DngrsGdsIsIgnoredLblFrmRgln,

//      AddlPlcdIsIgnoredLblFrmRgln,

      /* Associations */
      _ClassifiedAsDangerousGood,
      _CmplRqVersDngrsGdsPart1Item,
      _DangerousGdsClassOrDivision,
      _DangerousGoodsPackingGroup,
//      _EnclosureVariant,

      _DngrsGdsTechName1Substance,
      _DngrsGdsTechName2Substance,
      _DngrsGdsTechName3Substance,
      _DngrsGdsMarnPlltnt1Substance,
      _DngrsGdsMarnPlltnt2Substance,
      _DngrsGdsRptblQty1Substance,
      _DngrsGdsRptblQty2Substance,
      _DngrsGoodsBasicClassification
} where _DngrsGoodsBasicClassification.CmplRqRsltUUID is not initial