R_CostCenterTP

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Cost Center'

@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory: #L,
    dataClass: #MASTER
  },
  semanticKey: [ 'ControllingArea','CostCenter', 'ValidityEndDate' ],
  sapObjectNodeType.name: 'CostCenter'
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@Metadata.ignorePropagatedAnnotations: true

define root view entity R_CostCenterTP
  as select from I_CostCenter

  composition [0..*] of R_CostCenterTextTP            as _CostCenterTextTP

  association [1..1] to E_CostCenter                  as _Extension                   on  $projection.ControllingArea = _Extension.ControllingArea
                                                                                      and $projection.CostCenter      = _Extension.CostCenter
                                                                                      and $projection.ValidityEndDate = _Extension.ValidityEndDate

  association [0..1] to I_CostCtrCombinedStdHierarchy as _CostCtrCombinedStdHierarchy on  $projection.ControllingArea            = _CostCtrCombinedStdHierarchy.ControllingArea
                                                                                      and $projection.CostCenterStandardHierArea = _CostCtrCombinedStdHierarchy.CostCenterGroup
                                                                                
{
  key ControllingArea,
  key CostCenter,
      @Semantics.businessDate.to: true
  key ValidityEndDate,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea                                                                       as ControllingAreaForEdit,
      @ObjectModel.editableFieldFor: 'CostCenter'
      CostCenter                                                                            as CostCenterForEdit,
      @ObjectModel.editableFieldFor: 'ValidityEndDate'
      ValidityEndDate                                                                       as ValidityEndDateForEdit,
      _Text[1:Language = $session.system_language].CostCenterName,
      _Text[1:Language = $session.system_language].CostCenterDescription,
      @Semantics.booleanIndicator: true
      cast( IsBlkdForPrimaryCostsPosting as fis_cc_bkzkp preserving type )                  as IsBlkdForPrimaryCostsPosting,
      @Semantics.booleanIndicator: true
      cast( IsBlockedForPlanPrimaryCosts as fis_cc_pkzkp preserving type )                  as IsBlockedForPlanPrimaryCosts,
      CompanyCode,
      BusinessArea,
      CostCenterCategory,
      CostCtrResponsiblePersonName,
      CostCtrResponsibleUser,
      CostCenterCurrency,
      CostingSheet, //possible deletable

      TaxJurisdiction,
      ProfitCenter,
      Plant,
      LogicalSystem,
      cast ( CostCenterCreationDate as fis_cc_erfdt preserving type )                       as CostCenterCreationDate,
      cast ( CostCenterCreatedByUser as fis_cc_erfnm preserving type )                      as CostCenterCreatedByUser,
      @Semantics.booleanIndicator: true
      cast ( IsBlkdForSecondaryCostsPosting as fis_cc_bkzks preserving type )               as IsBlkdForSecondaryCostsPosting,
      @Semantics.booleanIndicator: true
      cast ( IsBlockedForRevenuePosting as fis_cc_bkzer preserving type )                   as IsBlockedForRevenuePosting,
      @Semantics.booleanIndicator: true
      cast ( IsBlockedForCommitmentPosting as fis_cc_bkzob preserving type )                as IsBlockedForCommitmentPosting,
      @Semantics.booleanIndicator: true
      cast ( IsBlockedForPlanSecondaryCosts as fis_cc_pkzks preserving type )               as IsBlockedForPlanSecondaryCosts,
      @Semantics.booleanIndicator: true
      cast ( IsBlockedForPlanRevenues as fis_cc_pkzer preserving type )                     as IsBlockedForPlanRevenues,
      CostCenterAllocationMethod,
      @Semantics.booleanIndicator: true
      ConsumptionQtyIsRecorded,
      Department,
      SubsequentCostCenter,
      ConditionUsage,
      ConditionApplication,
      CostCenterAccountingOverhead,
      cast( Country as fis_land1 preserving type )                                          as Country,
      FormOfAddress,
      cast ( AddressName as fco_cc_addressname preserving type )                            as AddressName,
      AddressAdditionalName,
      CostCenterAddrName3,
      CostCenterAddrName4,
      CityName,
      District,
      StreetAddressName,
      POBox,
      PostalCode,
      POBoxPostalCode,
      Region,
      Language,
      TeleboxNumber,
      cast ( PhoneNumber1 as fco_cc_telf1 preserving type )                                 as PhoneNumber1,
      PhoneNumber2,
      FaxNumber,
      TeletexNumber,
      TelexNumber,
      DataCommunicationPhoneNumber,
      cast( CostCenterPrinterDestination as fis_kdnam preserving type )                     as CostCenterPrinterDestination,
      cast( CostCenterStandardHierArea as fco_cc_khinr preserving type )                    as CostCenterStandardHierArea,
      CostCollector,
      @Semantics.booleanIndicator: true
      CostCenterIsComplete,
      IsStatisticalCostCenter,
      ObjectInternalID,
      CostCenterFunction,
      CostCenterAlternativeFunction,
      FunctionalArea,
      //ControllingAreaName,

      //6 possible deletable ->

      cast ( ActyIndepFormulaPlanningTmpl as fco_cca_templ_cpi preserving type )            as ActyIndepFormulaPlanningTmpl,
      cast ( ActyDepdntFormulaPlanningTmpl as fco_cca_templ_cpd preserving type )           as ActyDepdntFormulaPlanningTmpl,
      cast ( ActyIndependentAllocationTmpl as fco_cca_templ_sci preserving type )           as ActyIndependentAllocationTmpl,
      cast ( ActyDependentAllocationTmpl as fco_cca_templ_scd preserving type )             as ActyDependentAllocationTmpl,
      cast ( ActlIndepStatisticalKeyFigures as fco_cca_templ_ski preserving type )          as ActlIndepStatisticalKeyFigures,
      cast ( ActlDepStatisticalKeyFigures as fco_cca_templ_skd preserving type )            as ActlDepStatisticalKeyFigures,
      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      cast ( BudgetCarryingCostCenter as fco_budgetcarryingcostcenter preserving type )     as BudgetCarryingCostCenter,
      cast ( AvailabilityControlProfile as fco_budgetavailabilityctrlprof preserving type ) as AvailabilityControlProfile,
      cast ( AvailabilityControlIsActive as fco_availabilityctrlprofisact preserving type ) as AvailabilityControlIsActive,
      Fund,
      GrantID,
      FundIsFixAssigned,
      GrantIDIsFixAssigned,
      FunctionalAreaIsFixAssigned,

      case
        when BudgetCarryingCostCenter = CostCenter
          then cast( 'X' as fco_costcenterisbudgetcarrying preserving type )
          else cast( '' as fco_costcenterisbudgetcarrying preserving type )
      end                                                                                   as CostCenterIsBudgetCarrying,

      case( length( ControllingArea ) )
        when 2 then cast( concat_with_space(ControllingArea, CostCenter, 2 ) as cdobjectv )
        when 3 then cast( concat_with_space(ControllingArea, CostCenter, 1 ) as cdobjectv )
        else cast( concat(ControllingArea, CostCenter ) as cdobjectv )
      end                                                                                   as ChangeDocObject,
      
      CostCenterLastChangedByUser,
      CostCenterCreationTime,
      CostCenterLastChangedOnDate,
      CostCenterLastChangedAtTime,
      @Semantics: { dateTime: true,
                    systemDateTime.createdAt: true }
      dats_tims_to_tstmp( CostCenterCreationDate,
                          CostCenterCreationTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                          'NULL' )                                                          as CostCenterCreationDateTime,
      @Semantics: { dateTime: true,
                    systemDateTime.lastChangedAt:true }
      dats_tims_to_tstmp( CostCenterLastChangedOnDate,
                          CostCenterLastChangedAtTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                          'NULL' )                                                          as CostCenterLastChangedDateTime,

      /* Associations */
      _CostCenterTextTP,
      _CostCtrCombinedStdHierarchy,
      _Region,
      _Language,
      _Country,
      _BusinessArea,
      _ControllingArea,
      _CompanyCode,
      _FunctionalArea,
      _CostCenterCategory,
      _Currency,
      _ProfitCenter,
      _JointVenture,
      _JointVentureRecovery,
      _JointVentureEquityType,
      _JointVentureObjectType,
      _JointVentureClass,
      _JointVentureSubClass,
      _Fund,
      _Grant,
      _AvailabilityCtrlProfile,
      _UserRespContactCard,
      _UserCrtedContactCard,
      _LastChangedByUserContactCard,
      _BudgetCarryingCostCenter
}