R_CollsPrmsToPayCollsSegmentTP

@AbapCatalog: { sqlViewName: 'RCOLLSP2PSGMT',
                preserveKey: true,
                compiler: { compareFilter: true } }
@EndUserText: { label: 'Promise To Pay in Collections Segment' }
@ObjectModel: { representativeKey: 'PromiseToPayUUID',
                semanticKey:       [ 'CaseID' ],
                usageType:         { dataClass:      #TRANSACTIONAL,
                                     sizeCategory:   #L,
                                     serviceQuality: #C } }
@AccessControl: { authorizationCheck: #CHECK,
                  privilegedAssociations: ['_CreatedByContactCard',
                                           '_ChangedByContactCard',
                                           '_ClosedByContactCard' ],
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }

define root view R_CollsPrmsToPayCollsSegmentTP
  as select distinct from I_CollsSgmtCompanyCodeAssgmt
    inner join            I_CollectionsInvoiceMemory on I_CollsSgmtCompanyCodeAssgmt.CompanyCode = I_CollectionsInvoiceMemory.CompanyCode
    inner join            P_CollsPromiseToPayDraft   on  I_CollsSgmtCompanyCodeAssgmt.CompanyCode = P_CollsPromiseToPayDraft.CompanyCode
                                                     and I_CollectionsInvoiceMemory.Customer      = P_CollsPromiseToPayDraft.Customer

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ChangedByContactCard on $projection.CaseLastChangedBy = _ChangedByContactCard.ContactCardID

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _CreatedByContactCard on $projection.CaseCreatedBy = _CreatedByContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ClosedByContactCard  on $projection.CaseClosedBy = _ClosedByContactCard.ContactCardID

{

      // VDM Fields

  key cast( CollectionSegment as farp_collection_segment preserving type ) as CollectionSegment,
  key PromiseToPayUUID,
  key I_CollectionsInvoiceMemory.BranchAccount,
  
      DraftUUID,
      I_CollsSgmtCompanyCodeAssgmt.CompanyCode,
      I_CollectionsInvoiceMemory.Customer,

      ObjectType,
      LinkedInvoiceKey,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      PromisedAmount,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.PaidAmount,

      @Semantics: { currencyCode: true }
      Currency,

      P_CollsPromiseToPayDraft.DueDate,
      PromiseToPayDate,
      LastPaymentDate,
      PromiseToPayStatus,

      PromiseToPayLevel,
      PromiseToPayGivenByPersonName,

      @Semantics: { eMail: { address: true } }
      ContactPersonEmailAddress,

      @Semantics: { telephone: { type: [ #PREF ] } }
      ContactPersonPhoneNumber,

      @Semantics: { telephone: { type: [ #FAX ] } }
      ContactPersonFaxNumber,

      ContactPersonFaxCountry,
      ContactPerson,
      NumberOfInstallments,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      PaidOnScheduleAmount,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      PaidOffScheduleAmount,

      NextInstallmentDueDate,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      NextInstallmentAmount,

      CaseID,
      CaseExternalReference,
      Prms2PToInvoiceGroupRefUUID,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      CaseCreatedBy,

      CaseCreatedOn,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      CaseLastChangedBy,

      CaseLastChangedOn,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      CaseClosedBy,

      CaseClosedTime,
      IsActiveEntity,
      HasActiveEntity,
      DraftCreationDateTime,
      DraftLastChangedDateTime,
      CaseType, 
      
      IsCleared,

      // Exposed Associations

      _CaseAttribute,
      _ChangedByContactCard,
      _ClosedByContactCard,
      _CollsPromiseToPayStatus,
      I_CollsSgmtCompanyCodeAssgmt._CompanyCode,
      _Country,
      _CreatedByContactCard,
      _Currency,
      _Customer

}