R_ClfnClassTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Classification Class - TP'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.sapObjectNodeType.name: 'ClassificationClass'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL }

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_ClfnClassTP
  as select from I_ClfnClass as Class

  composition [1..*] of R_ClfnClassDescriptionTP as _ClassDescription
  composition [0..*] of R_ClfnClassKeywordTP as _ClassKeyword
  composition [0..*] of R_ClfnClassCharcTP as _ClassCharacteristic
  composition [0..*] of R_ClfnHistlClassCharcTP as _HistlClassCharacteristic
  composition [0..*] of R_ClfnClassOrglAreaTP as _ClassOrglArea

  association [0..*] to R_ClfnHistlClCharcOvrwrtnTP as _HistlClassCharcOvrwrtn
    on  $projection.Class     = _HistlClassCharcOvrwrtn.Class
    and $projection.ClassType = _HistlClassCharcOvrwrtn.ClassType
    
  association [0..*] to R_ClfnHistlClCharcValOvrwrtnTP as _HistlClassCharcValOverwritten
    on  $projection.Class     = _HistlClassCharcValOverwritten.Class
    and $projection.ClassType = _HistlClassCharcValOverwritten.ClassType
    
  association [0..*] to R_ClfnHistlClChVlDscOvrwrtnTP as _HistClCharcValDescOverwritten
    on  $projection.Class     = _HistClCharcValDescOverwritten.Class
    and $projection.ClassType = _HistClCharcValDescOverwritten.ClassType

{
  key Class.Class,
  key Class.ClassType,

      Class.ClassInternalID,

      Class.ClassStatus,
      Class.ClassGroup,
      Class.ClassSearchAuthGrp,
      Class.ClassClassfctnAuthGrp,
      Class.ClassMaintAuthGrp,
      Class.SameClassfctnReaction,
      Class.ClassIsLocal,
      Class.DocumentInfoRecordDocNumber,
      Class.DocumentInfoRecordDocType,
      Class.DocumentInfoRecordDocPart,
      Class.DocumentInfoRecordDocVersion,
      Class.ClassStandardOrgName,
      Class.ClassStandardNumber,
      Class.ClassStandardStartDate,
      Class.ClassStandardVersionStartDate,
      Class.ClassStandardVersion,
      Class.ClassStandardCharcTable,
      Class.ClassBaseUnit,
      Class.ClassIsUsableInBOM,
      Class.CreatedByUser,
      Class.LastChangedByUser,
      Class.CreationDate,
      Class.LastChangeDate,
      Class.ClassLastChangedDateTime       as LastChangeDateTime,

      @Semantics.businessDate.from: true
      Class.ValidityStartDate,

      @Semantics.businessDate.to: true
      Class.ValidityEndDate,

      _ClassDescription,
      _ClassKeyword,
      _ClassCharacteristic,
      _HistlClassCharacteristic,
      _ClassOrglArea,
      _HistlClassCharcOvrwrtn,
      _HistlClassCharcValOverwritten,
      _HistClCharcValDescOverwritten
}