R_CentralRequestForQuotationTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Central Request for Quotation'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.sapObjectNodeType.name: 'CentralRequestForQuotation'
@ObjectModel.semanticKey:  [ 'CentralRequestForQuotation' ]
@ObjectModel.representativeKey: 'CentralRequestForQuotation'
@ObjectModel: {
    usageType: {
      sizeCategory: #M,
      serviceQuality: #A,
      dataClass: #TRANSACTIONAL
    }
  }

@Metadata.ignorePropagatedAnnotations: true

define root view entity R_CentralRequestForQuotationTP
  as select from R_CentralRequestForQuotation

  composition [1..*] of R_CentralReqForQuotationItemTP as _CentralReqForQuotationItem

  composition [1..*] of R_CntrlReqForQuotationBidderTP as _CntrlReqForQuotationBidder

  ----Extension Association
  association [0..1] to E_PurchasingDocument           as _CentralReqForQuotationExtn on _CentralReqForQuotationExtn.PurchasingDocument = $projection.CentralRequestForQuotation

{

  key CentralRequestForQuotation,

      @ObjectModel: { foreignKey.association: '_CompanyCode'}
      CompanyCode,

      @ObjectModel: {foreignKey.association: '_PurchasingDocumentCategory' }
      PurchasingDocumentCategory,

      @ObjectModel: {foreignKey.association: '_RFQType' }
      PurchasingDocumentType,
      CreatedByUser,
      CreationDate,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      Language,

      @ObjectModel: { foreignKey.association: '_PurchasingOrganization'}
      PurchasingOrganization,

      @ObjectModel: { foreignKey.association: '_PurchasingGroup'}
      PurchasingGroup,

      @ObjectModel: { foreignKey.association: '_DocumentCurrency'}
      DocumentCurrency,

      @ObjectModel: { foreignKey.association: '_IncotermsClassification' }
      IncotermsClassification,
      IncotermsTransferLocation,

      @ObjectModel: {foreignKey.association: '_IncotermsVersion' }
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      CashDiscount1Percent,
      CashDiscount2Percent,
      NetPaymentDays,
      RFQPublishingDate,
      QuotationLatestSubmissionDate,
      BindingPeriodValidityEndDate,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TargetAmount,

      @ObjectModel: {  foreignKey.association: '_RFQLifecycleStatus'}
      RFQLifecycleStatus,
      RequestForQuotationName,
      QuotationEarliestSubmsnDate,
      LatestRegistrationDate,
      CorrespncInternalReference,

      @ObjectModel.foreignKey.association: '_FollowOnDocumentCategory'
      FollowOnDocumentCategory,

      PurgDocFollowOnDocumentType,
      PurchasingDocumentDeletionCode,

      @Semantics.booleanIndicator
      IsEndOfPurposeBlocked,
      PurContrValidityStartDate,
      PurContrValidityEndDate,

      /* Associations */
      _CentralReqForQuotationItem,
      _CntrlReqForQuotationBidder,
      _CompanyCode,
      _DocumentCurrency,
      _FollowOnDocumentCategory,
      _IncotermsClassification,
      _IncotermsVersion,
      _PaymentTerms,
      _PurchasingDocumentCategory,
      _PurchasingGroup,
      _PurchasingOrganization,
      _RFQLifecycleStatus,
      _RFQType
}