R_BusVolFldCombnTypeFldAssgmt

@EndUserText.label: 'Bus Vol Field Comb Type Field Assignment'
@AccessControl: {
    authorizationCheck: #NOT_REQUIRED
    }
@ObjectModel: {
    representativeKey: 'BusVolFldCombnFieldName',
    usageType: {
      dataClass:      #ORGANIZATIONAL,
      serviceQuality: #A,
      sizeCategory:   #S
      }
    }
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
@Analytics: {
    technicalName: 'RBUSVOLFLDTASG'
    }
@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

define view entity R_BusVolFldCombnTypeFldAssgmt
  as select from wb2_c_bvb_fcf
  association [0..1] to R_SettlmtMgmtMappedField as _SettlmtMgmtMappedField on  _SettlmtMgmtMappedField.SAPObjectType                =  'ConditionContract'
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingScenario   =  'BO_TP'
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingVersion    =  '0001'
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingCategory   =  '21'
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingType       =  ''
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingCopyMode   <> '3'
                                                                            and _SettlmtMgmtMappedField.SetlMgmtFldMappingRightField =  wb2_c_bvb_fcf.fieldname
  association [0..1] to R_BusVolFieldCombnType   as _BusVolFieldCombnType   on  $projection.BusVolFieldCombnType = _BusVolFieldCombnType.BusVolFieldCombnType

{
      @ObjectModel.foreignKey.association: '_BusVolFieldCombnType'
  key wb2_c_bvb_fcf.fieldcomb                               as BusVolFieldCombnType,
  key wb2_c_bvb_fcf.fieldname                               as BusVolFldCombnFieldName,

      wb2_c_bvb_fcf.initial_allowed                         as BusVolFldCombnFldInitIsAllwd,
      cast(
       case
        when wb2_c_bvb_fcf.ext_fieldname is not initial
          then wb2_c_bvb_fcf.ext_fieldname
        when _SettlmtMgmtMappedField.SetlMgmtFldMappingLeftField is not null and _SettlmtMgmtMappedField.SetlMgmtFldMappingLeftField is not initial
          then _SettlmtMgmtMappedField.SetlMgmtFldMappingLeftField
        else wb2_c_bvb_fcf.fieldname
        end as wlf_map_sideleft_fieldname preserving type ) as BusVolFldCombnExtFieldName,

      /* Associations */
      _BusVolFieldCombnType,
      _SettlmtMgmtMappedField
}