R_BusSolnOrdUserStatusTP

DDL: R_BUSSOLNORDUSERSTATUSTP Type: view_entity TRANSACTIONAL Package: CRMS4_SOLUTION_ORDER_RAP

Business Solution Order User Status - TP

R_BusSolnOrdUserStatusTP is a Transactional CDS View that provides data about "Business Solution Order User Status - TP" in SAP S/4HANA. It reads from 3 data sources (I_ServiceDocument, I_SrvcMgmtObjectStatus, P_StatusObjectWithGUID) and exposes 7 fields with key fields BusinessSolutionOrder, UserStatus. It has 3 associations to related views. Part of development package CRMS4_SOLUTION_ORDER_RAP.

3 data source(s) 7 fields

Data Sources (3)

SourceAliasJoin Type
I_ServiceDocument BusinessSolutionOrder inner
I_SrvcMgmtObjectStatus SolutionOrderStatus from
P_StatusObjectWithGUID StatusObject inner

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_StatusCode _StatusCode $projection.UserStatus = _StatusCode.StatusCode and $projection.StatusProfile = _StatusCode.StatusProfile
[0..1] I_StatusProfile _StatusProfile $projection.StatusProfile = _StatusProfile.StatusProfile
[1..*] I_UserStatusText _UserStatusText $projection.UserStatus = _UserStatusText.UserStatus and $projection.StatusProfile = _UserStatusText.StatusProfile

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Business Solution Order User Status - TP view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocument ServiceDocument
KEY UserStatus I_SrvcMgmtObjectStatus SrvcMgmtObjectStatus
StatusProfile P_StatusObjectWithGUID StatusProfile
_StatusCode _StatusCode
_StatusProfile _StatusProfile
_BusinessSolutionOrderTP _BusinessSolutionOrderTP
_UserStatusText _UserStatusText 
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory:   #L,
    dataClass:      #TRANSACTIONAL
    }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order User Status - TP'

define view entity R_BusSolnOrdUserStatusTP
  as select from I_SrvcMgmtObjectStatus as SolutionOrderStatus
    inner join   P_StatusObjectWithGUID as StatusObject          on SolutionOrderStatus.SrvcMgmtObjectUUID = StatusObject.StatusObjectUUID

    inner join   I_ServiceDocument      as BusinessSolutionOrder on  SolutionOrderStatus.SrvcMgmtObjectUUID             =    BusinessSolutionOrder.ServiceDocumentUUID
                                                                 and BusinessSolutionOrder.ServiceObjectType            =    'BUS2000172'
                                                                 and SolutionOrderStatus.SrvcMgmtObjectStatus           like 'E%'
                                                                 and SolutionOrderStatus.SrvcMgmtObjectStatusIsInactive =    ' '

  association        to parent R_BusinessSolutionOrderTP as _BusinessSolutionOrderTP on  $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder

  association [0..1] to I_StatusCode                     as _StatusCode              on  $projection.UserStatus    = _StatusCode.StatusCode
                                                                                     and $projection.StatusProfile = _StatusCode.StatusProfile

  association [0..1] to I_StatusProfile                  as _StatusProfile           on  $projection.StatusProfile = _StatusProfile.StatusProfile
  association [1..*] to I_UserStatusText  as _UserStatusText  on $projection.UserStatus = _UserStatusText.UserStatus
                                                                 and $projection.StatusProfile = _UserStatusText.StatusProfile
{

  key BusinessSolutionOrder.ServiceDocument    as BusinessSolutionOrder,

      @ObjectModel.foreignKey.association: '_StatusCode'
      @ObjectModel.text.association: '_UserStatusText'
  key SolutionOrderStatus.SrvcMgmtObjectStatus as UserStatus,

      @ObjectModel.foreignKey.association: '_StatusProfile'
      StatusObject.StatusProfile,

      // Associations

      _StatusCode,
      _StatusProfile,
      _BusinessSolutionOrderTP,
      _UserStatusText
}

Learn More