R_BusSolnOrdPriceElementTP

DDL: R_BUSSOLNORDPRICEELEMENTTP Type: view_entity TRANSACTIONAL Package: CRMS4_SOLUTION_ORDER_RAP

Solution Order Price Element - TP

R_BusSolnOrdPriceElementTP is a Transactional CDS View that provides data about "Solution Order Price Element - TP" in SAP S/4HANA. It reads from 2 data sources (I_PricingElement, I_ServiceDocumentEnhcd) and exposes 17 fields with key fields BusinessSolutionOrder, PricingProcedureStep, PricingProcedureCounter. It has 2 associations to related views. Part of development package CRMS4_SOLUTION_ORDER_RAP.

2 data source(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_PricingElement _PricingElement from
I_ServiceDocumentEnhcd BusinessSolutionOrder inner

Associations (2)

CardinalityTargetAliasCondition
[1..*] I_UnitOfMeasureText _UnitOfMeasureText $projection.ConditionQuantityUnit = _UnitOfMeasureText.UnitOfMeasure
[1..*] I_CurrencyText _CurrencyText $projection.ConditionCurrency = _CurrencyText.Currency

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Solution Order Price Element - TP view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocumentEnhcd ServiceDocument
KEY PricingProcedureStep I_PricingElement PricingProcedureStep
KEY PricingProcedureCounter I_PricingElement PricingProcedureCounter
ConditionType I_PricingElement ConditionType
ConditionRateValue I_PricingElement ConditionRateValue
ConditionQuantity I_PricingElement ConditionQuantity
ConditionQuantityUnit I_PricingElement ConditionQuantityUnit
ConditionAmount I_PricingElement ConditionAmount
ConditionCurrency I_PricingElement ConditionCurrency
ConditionIsForStatistics I_PricingElement ConditionIsForStatistics
ConditionIsManuallyChanged I_PricingElement ConditionIsManuallyChanged
ConditionCalculationType I_PricingElement ConditionCalculationType
ConditionInactiveReason I_PricingElement ConditionInactiveReason
PricingDocument I_ServiceDocumentEnhcd PricingDocument
_BusinessSolutionOrder _BusinessSolutionOrder
_UnitOfMeasureText _UnitOfMeasureText
_CurrencyText _CurrencyText 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Solution Order Price Element - TP'
define view entity R_BusSolnOrdPriceElementTP
as select from I_PricingElement as _PricingElement
 inner join   I_ServiceDocumentEnhcd as BusinessSolutionOrder    on  BusinessSolutionOrder.PricingDocument   = _PricingElement.PricingDocument
                                                                 and _PricingElement.PricingDocumentItem is initial
                                                                 and BusinessSolutionOrder.ServiceObjectType = 'BUS2000172'

 association to parent R_BusinessSolutionOrderTP      as _BusinessSolutionOrder on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

 association [1..*] to I_UnitOfMeasureText             as _UnitOfMeasureText      on $projection.ConditionQuantityUnit = _UnitOfMeasureText.UnitOfMeasure
 association [1..*] to I_CurrencyText                 as _CurrencyText  on $projection.ConditionCurrency  = _CurrencyText.Currency
{
  key  BusinessSolutionOrder.ServiceDocument as BusinessSolutionOrder,
  key  _PricingElement.PricingProcedureStep,
  key  _PricingElement.PricingProcedureCounter,
       _PricingElement.ConditionType,
       _PricingElement.ConditionRateValue,

       @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
       _PricingElement.ConditionQuantity,
       @ObjectModel.text.association: '_UnitOfMeasureText'
       _PricingElement.ConditionQuantityUnit,

       @Semantics.amount.currencyCode: 'ConditionCurrency'
       _PricingElement.ConditionAmount,
       @ObjectModel.text.association: '_CurrencyText'
       _PricingElement.ConditionCurrency, 
       
       _PricingElement.ConditionIsForStatistics,
       _PricingElement.ConditionIsManuallyChanged,
       _PricingElement.ConditionCalculationType,
       _PricingElement.ConditionInactiveReason,    
       
       //Authorization

       BusinessSolutionOrder.PricingDocument,


       // Associations

       _BusinessSolutionOrder,
       _UnitOfMeasureText,
       _CurrencyText
}

Learn More