R_BusSolnOrdLongTextTP

DDL: R_BUSSOLNORDLONGTEXTTP Type: view_entity TRANSACTIONAL Package: CRMS4_SOLUTION_ORDER_RAP

Business Solution Order Long Text - TP

R_BusSolnOrdLongTextTP is a Transactional CDS View that provides data about "Business Solution Order Long Text - TP" in SAP S/4HANA. It reads from 2 data sources (I_ServiceDocument, I_ServiceDocumentLongText) and exposes 17 fields with key fields BusinessSolutionOrder, TextObjectType, Language. Part of development package CRMS4_SOLUTION_ORDER_RAP.

2 data source(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_ServiceDocument ServiceOrder inner
I_ServiceDocumentLongText ServiceText from

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Business Solution Order Long Text - TP view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocumentLongText ServiceDocument
KEY TextObjectType I_ServiceDocumentLongText TextObjectType
KEY Language I_ServiceDocumentLongText Language
SrvcDocLogTextIdentifier I_ServiceDocumentLongText SrvcDocLogTextIdentifier
TextObjectCategory I_ServiceDocumentLongText TextObjectCategory
ServiceObjectType I_ServiceDocumentLongText ServiceObjectType
BusinessSolutionOrderUUID I_ServiceDocument ServiceDocumentUUID
SrvcDocLongTextMimeType I_ServiceDocumentLongText SrvcDocLongTextMimeType
BusinessSolutionOrderLongText I_ServiceDocumentLongText ServiceDocumentLongText
ReferenceTextObjectCategory I_ServiceDocumentLongText ReferenceTextObjectCategory
ReferenceTextObjectType I_ServiceDocumentLongText ReferenceTextObjectType
ReferenceLongTextKey I_ServiceDocumentLongText ReferenceLongTextKey
SrvcDocLongTxtCreationDateTime I_ServiceDocumentLongText SrvcDocLongTxtCreationDateTime
SrvcDocLongTextCreatedByUser I_ServiceDocumentLongText SrvcDocLongTextCreatedByUser
SrvcDocLongTextChangedDateTime I_ServiceDocumentLongText SrvcDocLongTextChangedDateTime
SrvcDocLongTextChangedByUser I_ServiceDocumentLongText SrvcDocLongTextChangedByUser
_BusinessSolutionOrderTP _BusinessSolutionOrderTP 
@AccessControl: {
  authorizationCheck:    #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  dataCategory: #TEXT,
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order Long Text - TP'

define view entity R_BusSolnOrdLongTextTP
  as select from I_ServiceDocumentLongText as ServiceText
    inner join   I_ServiceDocument         as ServiceOrder on  ServiceText.ServiceDocument     = ServiceOrder.ServiceDocument
                                                           and ServiceText.ServiceDocumentItem = '000000'
                                                           and ServiceText.TextObjectCategory  = 'CRM_ORDERH'
                                                           and ServiceOrder.ServiceObjectType  = 'BUS2000172'

  association to parent R_BusinessSolutionOrderTP as _BusinessSolutionOrderTP on $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder
{

  key ServiceText.ServiceDocument         as BusinessSolutionOrder,
  key ServiceText.TextObjectType,
      @Semantics.language:true
  key ServiceText.Language,
      ServiceText.SrvcDocLogTextIdentifier,
      ServiceText.TextObjectCategory,

      // ServiceText.ServiceDocumentLongTextUUID,

      ServiceText.ServiceObjectType,

//      _BusinessSolutionOrderTP.BusinessSolutionOrderUUID as BusinessSolutionOrderUUID,

      ServiceOrder.ServiceDocumentUUID as BusinessSolutionOrderUUID,

      ServiceText.SrvcDocLongTextMimeType,
      @Semantics.text:true
      ServiceText.ServiceDocumentLongText as BusinessSolutionOrderLongText,
      ServiceText.ReferenceTextObjectCategory,
      ServiceText.ReferenceTextObjectType,
      ServiceText.ReferenceLongTextKey,

      ServiceText.SrvcDocLongTxtCreationDateTime,
      ServiceText.SrvcDocLongTextCreatedByUser,
      ServiceText.SrvcDocLongTextChangedDateTime,
      ServiceText.SrvcDocLongTextChangedByUser,

      /* Associations */
      _BusinessSolutionOrderTP
}
where
  ServiceText.ServiceObjectType = 'BUS2000172'

Learn More