R_BusSolnOrdItmPartnerTP

DDL: R_BUSSOLNORDITMPARTNERTP Type: view_entity TRANSACTIONAL Package: CRMS4_SOLUTION_ORDER_RAP

Business Solution Order Item Partner - TP

R_BusSolnOrdItmPartnerTP is a Transactional CDS View that provides data about "Business Solution Order Item Partner - TP" in SAP S/4HANA. It reads from 1 data source (I_ServiceDocumentItemPartner) and exposes 12 fields with key fields BusinessSolutionOrder, BusinessSolutionOrderItem, CustMgmtPartnerFunction, CustMgmtBusinessPartner. It has 5 associations to related views. Part of development package CRMS4_SOLUTION_ORDER_RAP.

1 data source(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_ServiceDocumentItemPartner ItemPartner from

Associations (5)

CardinalityTargetAliasCondition
[0..1] R_BusinessSolutionOrderTP _BusinessSolutionOrderTP $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder
[0..*] I_CustMgmtPartnerFuncText _CustMgmtPartnerFuncText $projection.CustMgmtPartnerFunction = _CustMgmtPartnerFuncText.PartnerFunction
[0..1] I_BusinessPartner _BusinessPartner $projection.CustMgmtBusinessPartner = _BusinessPartner.BusinessPartner
[0..*] I_SrvcMgmtPartnerFunctionText _PartnerFunctionText $projection.CustMgmtPartnerFunction = _PartnerFunctionText.CustMgmtPartnerFunction
[0..1] R_BusSolnOrdItmPartnerAddrTP _BusSolnOrdItmPartnerAddrTP

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Business Solution Order Item Partner - TP view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder ServiceDocument
KEY BusinessSolutionOrderItem ServiceDocumentItem
KEY CustMgmtPartnerFunction I_ServiceDocumentItemPartner CustMgmtPartnerFunction
KEY CustMgmtBusinessPartner I_ServiceDocumentItemPartner CustMgmtBusinessPartner
CustMgmtPartFunctionCategory I_ServiceDocumentItemPartner CustMgmtPartFunctionCategory
CustMgmtPartnerIsMainPartner I_ServiceDocumentItemPartner CustMgmtPartnerIsMainPartner
_CustMgmtPartnerFuncText _CustMgmtPartnerFuncText
_BusinessPartner _BusinessPartner
_BusinessSolutionOrderItemTP _BusinessSolutionOrderItemTP
_BusinessSolutionOrderTP _BusinessSolutionOrderTP
_BusSolnOrdItmPartnerAddrTP _BusSolnOrdItmPartnerAddrTP
_PartnerFunctionText _PartnerFunctionText 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  semanticKey: ['CustMgmtBusinessPartner','CustMgmtPartnerFunction'],
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order Item Partner - TP'

define view entity R_BusSolnOrdItmPartnerTP
  as select from I_ServiceDocumentItemPartner as ItemPartner

  association [0..1] to R_BusinessSolutionOrderTP            as _BusinessSolutionOrderTP     on  $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder

  association [0..*] to I_CustMgmtPartnerFuncText            as _CustMgmtPartnerFuncText     on  $projection.CustMgmtPartnerFunction = _CustMgmtPartnerFuncText.PartnerFunction

  association [0..1] to I_BusinessPartner                    as _BusinessPartner             on  $projection.CustMgmtBusinessPartner = _BusinessPartner.BusinessPartner

  association        to parent R_BusinessSolutionOrderItemTP as _BusinessSolutionOrderItemTP on  $projection.BusinessSolutionOrder     = _BusinessSolutionOrderItemTP.BusinessSolutionOrder
                                                                                             and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItemTP.BusinessSolutionOrderItem

  association [0..*] to I_SrvcMgmtPartnerFunctionText        as _PartnerFunctionText         on  $projection.CustMgmtPartnerFunction = _PartnerFunctionText.CustMgmtPartnerFunction

  composition [0..1] of R_BusSolnOrdItmPartnerAddrTP         as _BusSolnOrdItmPartnerAddrTP
{
  key  ServiceDocument     as BusinessSolutionOrder,
  key  ServiceDocumentItem as BusinessSolutionOrderItem,
       @ObjectModel.text.association:'_PartnerFunctionText'
  key  ItemPartner.CustMgmtPartnerFunction,
  key  ItemPartner.CustMgmtBusinessPartner,
       ItemPartner.CustMgmtPartFunctionCategory,
       ItemPartner.CustMgmtPartnerIsMainPartner,

       // associations

       _CustMgmtPartnerFuncText,
       _BusinessPartner,
       _BusinessSolutionOrderItemTP,
       _BusinessSolutionOrderTP,
       _BusSolnOrdItmPartnerAddrTP,
       _PartnerFunctionText
}
where
  ItemPartner.ServiceObjectType = 'BUS2000172'

Learn More