R_BusSolnOrdItemLongTextTP

DDL: R_BUSSOLNORDITEMLONGTEXTTP Type: view_entity TRANSACTIONAL Package: CRMS4_SOLUTION_ORDER_RAP

Business Solution Order Item Long Text - TP

R_BusSolnOrdItemLongTextTP is a Transactional CDS View that provides data about "Business Solution Order Item Long Text - TP" in SAP S/4HANA. It reads from 2 data sources (I_ServiceDocumentItem, I_ServiceDocumentLongText) and exposes 20 fields with key fields BusinessSolutionOrder, BusinessSolutionOrderItem, TextObjectType, Language. It has 1 association to related views. Part of development package CRMS4_SOLUTION_ORDER_RAP.

2 data source(s) 20 fields

Data Sources (2)

SourceAliasJoin Type
I_ServiceDocumentItem BusinessSolutionOrderItem inner
I_ServiceDocumentLongText ServiceItemText from

Associations (1)

CardinalityTargetAliasCondition
[1..1] R_BusinessSolutionOrderTP _BusinessSolutionOrderTP $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Business Solution Order Item Long Text - TP view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocumentItem ServiceDocument
KEY BusinessSolutionOrderItem I_ServiceDocumentItem ServiceDocumentItem
KEY TextObjectType I_ServiceDocumentLongText TextObjectType
KEY Language I_ServiceDocumentLongText Language
SrvcDocLogTextIdentifier I_ServiceDocumentLongText SrvcDocLogTextIdentifier
TextObjectCategory I_ServiceDocumentLongText TextObjectCategory
SrvcDocLongTextMimeType I_ServiceDocumentLongText SrvcDocLongTextMimeType
BusSolnOrdItmLongText I_ServiceDocumentLongText ServiceDocumentLongText
ReferenceTextObjectCategory I_ServiceDocumentLongText ReferenceTextObjectCategory
ReferenceTextObjectType I_ServiceDocumentLongText ReferenceTextObjectType
ReferenceLongTextKey I_ServiceDocumentLongText ReferenceLongTextKey
ReferenceServiceObjectType I_ServiceDocumentLongText ReferenceServiceObjectType
ReferenceServiceDocument I_ServiceDocumentLongText ReferenceServiceDocument
ReferenceServiceDocumentItem I_ServiceDocumentLongText ReferenceServiceDocumentItem
SrvcDocLongTxtCreationDateTime I_ServiceDocumentLongText SrvcDocLongTxtCreationDateTime
SrvcDocLongTextCreatedByUser I_ServiceDocumentLongText SrvcDocLongTextCreatedByUser
SrvcDocLongTextChangedDateTime I_ServiceDocumentLongText SrvcDocLongTextChangedDateTime
SrvcDocLongTextChangedByUser I_ServiceDocumentLongText SrvcDocLongTextChangedByUser
_BusinessSolutionOrderTP _BusinessSolutionOrderTP
_BusinessSolutionOrderItemTP _BusinessSolutionOrderItemTP 
@AccessControl: {
  authorizationCheck:    #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  dataCategory: #TEXT,
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order Item Long Text - TP'

define view entity R_BusSolnOrdItemLongTextTP
  as select from I_ServiceDocumentLongText as ServiceItemText
    inner join   I_ServiceDocumentItem     as BusinessSolutionOrderItem on  ServiceItemText.ServiceDocument             = BusinessSolutionOrderItem.ServiceDocument
                                                                        and ServiceItemText.ServiceDocumentItem         = BusinessSolutionOrderItem.ServiceDocumentItem
                                                                        and ServiceItemText.TextObjectCategory          = 'CRM_ORDERI'
                                                                        and BusinessSolutionOrderItem.ServiceObjectType = 'BUS2000172'

  association        to parent R_BusinessSolutionOrderItemTP as _BusinessSolutionOrderItemTP on  $projection.BusinessSolutionOrder     = _BusinessSolutionOrderItemTP.BusinessSolutionOrder
                                                                                             and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItemTP.BusinessSolutionOrderItem

  association [1..1] to R_BusinessSolutionOrderTP            as _BusinessSolutionOrderTP     on  $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder
{

  key BusinessSolutionOrderItem.ServiceDocument     as BusinessSolutionOrder,
  key BusinessSolutionOrderItem.ServiceDocumentItem as BusinessSolutionOrderItem,
  key ServiceItemText.TextObjectType,
      @Semantics.language:true
  key ServiceItemText.Language,
      ServiceItemText.SrvcDocLogTextIdentifier,

      //   ServiceItemText.ServiceDocumentLongTextUUID,

      ServiceItemText.TextObjectCategory,

      ServiceItemText.SrvcDocLongTextMimeType,
      @Semantics.text:true
      ServiceItemText.ServiceDocumentLongText       as BusSolnOrdItmLongText,
      ServiceItemText.ReferenceTextObjectCategory,
      ServiceItemText.ReferenceTextObjectType,
      ServiceItemText.ReferenceLongTextKey,
      ServiceItemText.ReferenceServiceObjectType,
      ServiceItemText.ReferenceServiceDocument,
      ServiceItemText.ReferenceServiceDocumentItem,

      ServiceItemText.SrvcDocLongTxtCreationDateTime,
      ServiceItemText.SrvcDocLongTextCreatedByUser,
      ServiceItemText.SrvcDocLongTextChangedDateTime,
      ServiceItemText.SrvcDocLongTextChangedByUser,

      /* Associations */
      _BusinessSolutionOrderTP,
      _BusinessSolutionOrderItemTP
}
where
  ServiceItemText.ServiceObjectType = 'BUS2000172'

Learn More