R_BillingDocumentRequestItemTP

@AccessControl: { authorizationCheck: #MANDATORY, personalData.blocking: #('TRANSACTIONAL_DATA'), privilegedAssociations: [ '_CreatedByUser' ] }

@EndUserText.label: 'Billing Document Request Item - TP'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #C, sizeCategory: #XL }
@ObjectModel.semanticKey: ['BillingDocumentRequest','BillingDocumentRequestItem']
  
define view entity R_BillingDocumentRequestItemTP 
  as select from I_BillingDocumentRequestItem
  association to parent R_BillingDocumentRequestTP          as _BillingDocumentRequest on $projection.BillingDocumentRequest = _BillingDocumentRequest.BillingDocumentRequest 
  
  composition [0..*] of R_BillgDocRequestItemPartnerTP      as _ItemPartner
  composition [0..*] of R_BillgDocRequestItemTextTP         as _ItemText
  
  association [0..1] to I_Batch                             as _Batch                  on  $projection.Plant   = _Batch.Plant
                                                                                       and $projection.Product = _Batch.Material
                                                                                       and $projection.Batch   = _Batch.Batch 
   //Extensibility

  association [0..1] to E_BillingDocumentItem               as _Extension              on  $projection.BillingDocumentRequest     = _Extension.BillingDocument
                                                                                       and $projection.BillingDocumentRequestItem = _Extension.BillingDocumentItem
  association [0..1] to I_WBSElementByExternalID            as _WBSElementExternalID   on  $projection.wbselementexternalid = _WBSElementExternalID.WBSElementExternalID                                                                                                                                                                         
{
      key BillingDocumentRequest,
      key BillingDocumentRequestItem,
      SalesDocumentItemCategory,
      SalesDocumentItemType,
      ReturnItemProcessingType,
      CreatedByUser,
      CreationDate,
      CreationTime,
      ReferenceLogicalSystem,
      OrganizationDivision,
      Division,
      SalesOffice,
      Product,
      OriginallyRequestedMaterial,
      InternationalArticleNumber,
      PricingReferenceMaterial,
      @ObjectModel.foreignKey.association: '_Batch'
      Batch,
      ProductHierarchyNode,
      ProductGroup,
      AdditionalMaterialGroup1,
      AdditionalMaterialGroup2,
      AdditionalMaterialGroup3,
      AdditionalMaterialGroup4,
      AdditionalMaterialGroup5,
      MaterialCommissionGroup,
      Plant,
      StorageLocation,
      SoldProduct,
      BillingDocumentRequestItemText,
      ServicesRenderedDate,
      BillingQuantity,
      BillingQuantityUnit,
      BillingQuantityInBaseUnit,
      BaseUnit,
      MRPRequiredQuantityInBaseUnit,
      BillingToBaseQuantityDnmntr,
      BillingToBaseQuantityNmrtr,
      ItemGrossWeight,
      ItemNetWeight,
      ItemWeightUnit,
      ItemVolume,
      ItemVolumeUnit,
      NetAmount,
      TransactionCurrency,
      GrossAmount,
      PricingDate,
      PriceDetnExchangeRate,
      cast(abs( PriceDetnExchangeRate ) as kursk_abs)                                                as AbsltPriceDetnExchangeRate, //new

      cast(case when PriceDetnExchangeRate < 0 then 'X' else ' ' end  as kursk_quotatn_is_indirect)  as PriceDetnExchRateIsIndrctQtan, //new

      PricingScaleQuantityInBaseUnit,
      TaxAmount,
      CostAmount,
      Subtotal1Amount,
      Subtotal2Amount,
      Subtotal3Amount,
      Subtotal4Amount,
      Subtotal5Amount,
      Subtotal6Amount,
      StatisticalValueControl,
      CashDiscountIsDeductible,
      TimeSheetOvertimeCategory,
      DepartureCountry,
      TaxJurisdiction,
      ProductTaxClassification1,
      ProductTaxClassification2,
      ProductTaxClassification3,
      ProductTaxClassification4,
      ProductTaxClassification5,
      ProductTaxClassification6,
      ProductTaxClassification7,
      ProductTaxClassification8,
      ProductTaxClassification9,
      ZeroVATRsn,
      BillgDocReqBillgSts,
      BusinessArea,
      ProfitCenter,
      BillingPeriodOfPerfStartDate,
      BillingPeriodOfPerfEndDate,
      OrderID,
      WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_WBSElementExternalID'//new

      _WBSElementBasicData.WBSElementExternalID, //new

      ProviderContract,
      ProviderContractItem,
      ControllingArea,
      @ObjectModel.foreignKey.association: '_CostCenter'            
      CostCenter,
      OriginSDDocument,
      OriginSDDocumentItem,
      PriceDetnExchangeRateDate,
      MatlAccountAssignmentGroup,
      ReferenceDocument,
      ReferenceDocumentItem,
      ReferenceDocSDDocCategory,
      SalesDocument,
      SalesDocumentItem,
      SalesSDDocumentCategory,
      HigherLevelItem,
      BillgDocRequestItemInPartSgmt,
      SalesGroup,
      ItemIsRelevantForCredit,
      CreditRelatedPrice,
      ServiceDocumentType,
      ServiceDocument,
      ServiceDocumentItem,
      BusinessSolutionOrder,
      BusinessSolutionOrderItem,
      
      // The following two fields are only required for the DCL  

      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: null      
      BillingDocumentRequestType,
      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: null
      SalesOrganization,
      
      _ItemPartner,
      _ItemText,
                  
      _BillingDocumentRequest,
      _SalesDocumentItemCategory,
      _SalesDocumentItemType,
      _CreatedByUser,
      _ReferenceLogicalSystem,
      _OrganizationDivision,
      _Division,
      _SalesOffice,
      _Product,
      _OriginallyRequestedMaterial,
      _PricingReferenceMaterial,
      _Batch,
      _ProductHierarchyNode,
      _ProductGroup,
      _AdditionalMaterialGroup1,
      _AdditionalMaterialGroup2,
      _AdditionalMaterialGroup3,
      _AdditionalMaterialGroup4,
      _AdditionalMaterialGroup5,
      _MaterialCommissionGroup,
      _Plant,
      _StorageLocation,
      _SoldProduct,
      _BillingQuantityUnit,
      _BaseUnit,
      _ItemWeightUnit,
      _ItemVolumeUnit,
      _TransactionCurrency,
      _StatisticalValueControl,
      _TimeSheetOvertimeCat,
      _DepartureCountry,
      _BusinessArea,
      _ProfitCenter,
      _WBSElementBasicData,
      _ControllingArea,
      _CostCenter_2 as _CostCenter,
      _ReferenceDocSDDocCategory,
      _SalesDocument,
      _SalesDocumentItem,
      _SalesSDDocumentCategory,
      _HigherLevelItem,
      _BillgDocReqBillgSts,
      _SalesGroup,
      _MatlAccountAssignmentGroup,
      _ServiceDocumentType,
      _ProviderContract,
      _ProviderContractItem,
      _WBSElementExternalID
//      _ProductText,

//      _BusinessAreaText,

//      _PricingReferenceMaterialText,

//      _OriginallyRequestedMatlText


}