P_WorkCenterCapacityCalc

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
define view entity P_WorkCenterCapacityCalc
  as select from P_WorkCenterCapacityBase
{
  key CapacityInternalID,
      cast('00000000' as dats)                               as ValidityStartDate,
      cast('99991231' as dats)                               as ValidityEndDate,
      Capacity,
      CapacityCategoryCode,
      CapacityActiveVersion,
      CapacityIsFinite,
      CapacityIsPooled,
      CapacityHasIndivCapacities,
      CapacityIsExcldFrmLongTermPlng,
      CapacityNumberOfCapacities,
      CapacityResponsiblePlanner,
      CapacityPlanUtilizationPercent,
      CapacityBreakDuration,
      CapIsUsedInMultiOperations,
      ReferencedCapacityInternalID,
      CapOverloadThresholdInPercent,
      Plant,
      FactoryCalendar,
      AuthorizationGroup,
      ShiftGroup,
      CapacityStartTime,
      CapacityEndTime,
      CapacityQuantityUnit,
      CapacityBaseQtyUnit,
      CapacityLastChangeDateTime,
      OperatingDurationWithoutBreak,

      case when OperatingDurationWithoutBreak <= CapacityBreakDuration
      -- if the break is longer or equal to the opening hours, we have 0 capacity
            then 0
      -- Calculate the capacity, based on Capacity Start Date, End Date ,  Break down Duration, number of Capacities and plan utilization percent
            else cast((OperatingDurationWithoutBreak - CapacityBreakDuration) as abap.fltp) * cast(CapacityNumberOfCapacities as abap.fltp) * cast(CapacityPlanUtilizationPercent as abap.fltp )/ cast(100 as abap.fltp)
          end                                                as OverallCapacity,

      case when OperatingDurationWithoutBreak <= CapacityBreakDuration
      -- if the break is longer or equal to the opening hours, we have 0 capacity
        then 0
      -- Calculate the Single capacity based on Capacity StartTime, EndTime and Break Duration.
      -- Single capacity also has to take in to account of the utilization percentage defined
      --        else OperatingDurationWithoutBreak - CapacityBreakDuration
        else cast((OperatingDurationWithoutBreak - CapacityBreakDuration) as abap.fltp) * cast(CapacityPlanUtilizationPercent as abap.fltp )/ cast(100 as abap.fltp)
      end                                                    as SingleCapacity,

      /* Associations */
      //P_WorkCenterCapacityBase

      _Capacity,
      _CapacityBaseQtyUnit,
      _CapacityCategory,
      _CapacityQuantityUnit,
      _CapacityResponsiblePlanner,
      _FactoryCalendar,
      _Plant,
      _ShiftGrouping,
      _Text



}