P_WBRP_ValueHelp

@AbapCatalog.sqlViewName: 'PWBRPVH'
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
//@AbapCatalog.preserveKey:true

// Value Help for Settlement Management Docs Items

define view P_WBRP_ValueHelp

  as select from wbrp
    inner join   P_WBRK_Begru_Values on wbrp.wbeln = P_WBRK_Begru_Values.wbeln

  association [0..1] to P_WLF_CDS_LFA1_BG as _PriorSupplier on $projection.kolif = _PriorSupplier.vendor_account
  association [0..1] to P_WLF_CDS_KNA1_BG as _Customer      on $projection.customer = _Customer.customer_account

{
  key wbrp.wbeln                                 as wbeln,
  key wbrp.posnr                                 as posnr,
      wbrp.matnr                                 as matnr,
      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'wfkme'
      wbrp.menge                                 as menge,
      @Semantics.unitOfMeasure: true
      wbrp.wfkme                                 as wfkme,
      wbrp.kolif                                 as kolif,
      P_WBRK_Begru_Values.lnrzb                  as lnrzb,
      P_WBRK_Begru_Values.kunrg                  as kunrg,
      P_WBRK_Begru_Values.ekorg                  as ekorg,
      P_WBRK_Begru_Values.ekgrp                  as ekgrp,
      P_WBRK_Begru_Values.vkorg                  as vkorg,
      P_WBRK_Begru_Values.vtweg                  as vtweg,
      P_WBRK_Begru_Values.spart                  as spart,
      P_WBRK_Begru_Values.bukrs                  as bukrs,
      P_WBRK_Begru_Values.lifre                  as lifre,
      P_WBRK_Begru_Values.kunre                  as kunre,
      P_WBRK_Begru_Values.lfart                  as lfart,
      P_WBRK_Begru_Values.bukrs_deb              as bukrs_deb,
      P_WBRK_Begru_Values.authorization_category as authorization_category,
      P_WBRK_Begru_Values.lifre_begru            as lifre_begru,
      P_WBRK_Begru_Values.lifnr_fi_begru         as lifnr_fi_begru,
      P_WBRK_Begru_Values.lnrzb_begru            as lnrzb_begru,
      P_WBRK_Begru_Values.kunre_begru            as kunre_begru,
      P_WBRK_Begru_Values.kunrg_begru            as kunrg_begru,
      _PriorSupplier.vendor_begru                as kolif_begru,
      wbrp.customer                              as customer,
      _Customer.customer_begru                   as customer_begru

}