P_ValuationRunAccountLineItem

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PVALRUNITEM'

@AccessControl.authorizationCheck: #NOT_ALLOWED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #XXL, dataClass: #MIXED }

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_ValuationRunAccountLineItem
  with parameters
    p_fiscal_year_period : fiscalyearperiod

  as select from           I_GLAccountLineItem        as acdoca

    left outer to one join P_BPCreditRiskClass        as _CustomerRiskClass on acdoca.Customer = _CustomerRiskClass.Customer

    left outer to one join R_FinClsgMDChgBPSpclGLAcct as _specialglaccount  on acdoca.CompanyCode   = _specialglaccount.CompanyCode
                                                                            and(
                                                                              acdoca.SpecialGLCode  = _specialglaccount.SpecialGLCode
                                                                            )
                                                                            and(
                                                                              (
                                                                                acdoca.Customer     is not initial
                                                                                and acdoca.Customer = _specialglaccount.Customer
                                                                              )
                                                                              or(
                                                                                acdoca.Supplier     is not initial
                                                                                and acdoca.Supplier = _specialglaccount.Supplier
                                                                              )
                                                                            )

{
      // Debit items are invoices, credit items are payments

  key acdoca.CompanyCode,
      // For non-open item we require current ledger fiscal year

  key acdoca.LedgerFiscalYear                                                                                                    as FiscalYear,
  key acdoca.AccountingDocument,
  key acdoca.LedgerGLLineItem,
  key acdoca.Ledger,

      acdoca.SourceLedger,

      acdoca.AccountingDocumentItem,

      cast(
            case  when acdoca.FiscalYearPeriod = :p_fiscal_year_period
            then 'VALUATION_CURRENT'
            when acdoca.FiscalYearPeriod < :p_fiscal_year_period
            then 'VALUATION_PREVIOUS' end                  as fins_cls_val_line_type)                                            as line_type,

      acdoca._PostingKey.DebitCreditCode,
      acdoca.ClearingAccountingDocument,
      acdoca.ClearingDocFiscalYear,
      acdoca.ClearingDate,
      acdoca.NetDueDate,
      acdoca.ChartOfAccounts,
      acdoca.GLAccount,
      acdoca.CreationDateTime,
      acdoca.SubLedgerAcctLineItemType,
      acdoca.PostingDate,
      acdoca.PostingDate                                                                                                         as OriginalPostingDate,
      acdoca.AccountingDocumentCategory,
      acdoca.LedgerFiscalYear,
      acdoca.ReferenceDocumentType,
      acdoca.FiscalYearPeriod,
      acdoca.BusinessTransactionCategory,
      acdoca.IsOpenItemManaged,
      acdoca.IsReversal,
      acdoca.IsReversed,

      acdoca.BalanceTransactionCurrency,
      acdoca.CompanyCodeCurrency,
      acdoca.GlobalCurrency,
      acdoca.FreeDefinedCurrency1,
      acdoca.FreeDefinedCurrency2,
      acdoca.FreeDefinedCurrency3,
      acdoca.FreeDefinedCurrency4,
      acdoca.FreeDefinedCurrency5,
      acdoca.FreeDefinedCurrency6,
      acdoca.FreeDefinedCurrency7,
      acdoca.FreeDefinedCurrency8,

      acdoca.AmountInBalanceTransacCrcy,
      acdoca.AmountInCompanyCodeCurrency,
      acdoca.AmountInGlobalCurrency,
      acdoca.AmountInFreeDefinedCurrency1,
      acdoca.AmountInFreeDefinedCurrency2,
      acdoca.AmountInFreeDefinedCurrency3,
      acdoca.AmountInFreeDefinedCurrency4,
      acdoca.AmountInFreeDefinedCurrency5,
      acdoca.AmountInFreeDefinedCurrency6,
      acdoca.AmountInFreeDefinedCurrency7,
      acdoca.AmountInFreeDefinedCurrency8,
      ' '                                                                                                                        as ISCLEAREDATKEYDATE,
      acdoca.GLAccountType,
      acdoca.FinancialAccountType, // corresponding wl field name ACCOUNT_TYPE

      acdoca.AssignmentReference,
      acdoca.GLRecordType,

      case when acdoca.Customer is not initial
      then coalesce(acdoca._Customer.CustomerCorporateGroup, ' ')
      else
      coalesce(acdoca._Supplier.SupplierCorporateGroup, ' ') end                                                                 as CUSTOMER_SUPPLIER_GROUP_KEY,

      acdoca.FiscalPeriod,
      acdoca.OffsettingAccount,
      acdoca.WBSElement,
      acdoca.TaxCode,
      acdoca.TaxCountry,
      cast(case acdoca.GLAccountType when 'C' then acdoca.HouseBank else '' end  as farp_hbkid)                                  as HouseBank,
      cast(case acdoca.GLAccountType when 'C' then acdoca.HouseBankAccount else '' end as fac_hktid)                             as HouseBankAccount,
      acdoca.CostCtrActivityType,
      acdoca.WBSElementInternalID,
      acdoca.FinancialTransactionType,
      acdoca.JointVenture,
      acdoca.JointVentureEquityGroup,
      acdoca.JointVentureEquityType,
      acdoca.PartnerVenture,
      acdoca.JointVenturePartner,
      acdoca.JointVentureCostRecoveryCode,
      acdoca.ProjectNetwork,
      acdoca.RelatedNetworkActivity,
      acdoca.OrderID,
      acdoca.BusinessProcess,
      acdoca.SalesDocument                                                                                                       as SalesOrder,
      acdoca.SalesDocumentItem                                                                                                   as SalesOrderItem,
      acdoca.CostObject,
      acdoca.CostCenter,
      acdoca.ProfitCenter,
      acdoca.FunctionalArea,
      acdoca.BusinessArea,
      acdoca.ControllingArea,
      acdoca.Segment,
      acdoca.PartnerCostCenter,
      acdoca.PartnerProfitCenter,
      acdoca.PartnerFunctionalArea,
      acdoca.PartnerBusinessArea,
      acdoca.PartnerCompany,
      acdoca.PartnerSegment,
      acdoca.Supplier,
      acdoca.Customer,
      acdoca.FinancialValuationObjectType,
      acdoca.FinancialValuationObject,
      acdoca.FinancialValuationSubobject,
      acdoca.REBusinessEntity,
      acdoca.RealEstateBuilding,
      acdoca.RealEstateProperty,
      acdoca.Fund,
      acdoca.BudgetPeriod,
      acdoca.GrantID,
      acdoca.PubSecBudgetAccount,
      acdoca.CashLedgerAccount,
      acdoca.SponsoredProgram,
      acdoca.SponsoredClass,
      acdoca.Plant,
      acdoca.Product,
      acdoca.ShipToParty,
      acdoca.PartnerFund,
      acdoca.PartnerGrant,
      acdoca.CashLedgerCompanyCode,
      acdoca.FundsCenter,
      acdoca.PartnerEquityGroup,
      acdoca.FundedProgram,
      acdoca.PartnerBudgetPeriod,
      acdoca.PubSecBudgetAccountCoCode,
      acdoca.ServiceDocument,
      acdoca.ServiceDocumentItem,
      acdoca.ServiceDocumentType,
      acdoca.GeneralLedgerAgingScope,
      acdoca.GeneralLedgerAgingIncrement,
      acdoca.AccrualObjectType,
      acdoca.AccrualObject,
      acdoca.AccrualSubobject,
      acdoca.AccrualItemType,
      acdoca.AccrualReferenceObject,
      acdoca.AccrualObjectLogicalSystem,
      acdoca.Material,

      cast(
      case when acdoca.RelatedNetworkActivity is not initial
      then concat(concat(acdoca.OrderCategory, '/'), acdoca.AccountAssignment)
      else '' end        as cls_run_nplnr_vorgn_helper)                                                                          as relatednetworkactivityinternal,

      acdoca.PrdcssrJournalEntryCompanyCode,
      acdoca.PrdcssrJournalEntryFiscalYear,
      acdoca.PredecessorJournalEntry,
      acdoca.PredecessorJournalEntryItem,

      cast(coalesce(coalesce(_Customer._CustomerToBusinessPartner._BusinessPartner.BusinessPartner,
                    _Supplier._SupplierToBusinessPartner._BusinessPartner.BusinessPartner), '')   as bu_partner preserving type) as BusinessPartner,

      cast(coalesce(_CustomerRiskClass._CreditManagement.CreditRiskClass, '') as ukm_risk_class)                                 as CreditRiskClass,


      cast(
      case when acdoca.SpecialGLCode is initial or (acdoca.SpecialGLCode != _specialglaccount.SpecialGLCode)
      then
      coalesce(coalesce(acdoca._SupplierCompany.ReconciliationAccount, acdoca._CustomerCompany.ReconciliationAccount), '')
      else
      _specialglaccount.GLAccount
      end as akont)                                                                                                              as MASTERDATARECNCLNACCT,

      coalesce(coalesce(acdoca._SupplierCompany.ReconciliationAccount, acdoca._CustomerCompany.ReconciliationAccount), '')       as TAGGEDACCOUNT,


      cast(
      coalesce(coalesce(acdoca._Supplier._SupplierToBusinessPartner._BusinessPartner._BPFinancialServicesExt.TradingPartner,
      acdoca._Customer._CustomerToBusinessPartner._BusinessPartner._BPFinancialServicesExt.TradingPartner),
      '')       as rassc)                                                                                                        as MASTERDATAPARTNERCOMPANY,

      acdoca.SpecialGLCode                                                                                                       as SpecialGLCode

}

where
  (
       acdoca.Supplier                                    is initial
    or acdoca._SupplierCompany.IsBusinessPurposeCompleted = ''
  )
  and(
       acdoca.Customer                                    is initial
    or acdoca._CustomerCompany.IsBusinessPurposeCompleted = ''
  )