P_SubstanceNameText

@EndUserText.label: 'Substance Names with Listed Substance Names'

@AbapCatalog:
{
  sqlViewName: 'PSUBNAMTXT',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_SubstanceNameText
  --Select data from substance
  as select from I_Substance as Substance

{

      --UUID of substance
      @Consumption.semanticObject: 'CompanySubstance'
  key Substance.SubstanceUUID,

      ResponsibleUnit,

      --UUID of listed substance
      Substance.ListedSubstanceUUID,

      --Internal Name of substance (language-independent)
      Substance.SubstanceInternalName,

      --Specification
      --CAS Number
      cast( Substance.Specification as ehfnd_internal_nr_nc ) as Specification,

      --CAS Number
      Substance._ListedSubstance.CASNumber,

      --EC Number
      Substance._ListedSubstance.ECNumber,

      --ListedSubstanceDefaultName
      Substance._ListedSubstance.ListedSubstance              as ListedSubstance,

      //1. specific substance name

      //2. listed substance name

      //3. internal name

      cast (
              coalesce( coalesce( Substance._SubstanceText[1:Language = $session.system_language].SubstanceName,
                                  Substance._ListedSubstance.ListedSubstanceDefaultName ),
                        Substance.SubstanceInternalName )
           as ehfnd_sub_substance_name_ltd )                  as SubstanceName

}