P_SlsContrItmAddlInhtdPartner

@AbapCatalog: {
  sqlViewName: 'PSLSCONITMINHPT',
  compiler.compareFilter: true,
  preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }
}

@VDM: {
  private: true,
  viewType: #COMPOSITE
}

@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_SlsContrItmAddlInhtdPartner
  as select from I_SalesDocumentItem         as _Item
  
  inner join I_SlsContrAddlCompletePartners  as _Partner on _Item.SalesDocument = _Partner.SDDocument
  
  left outer to one join I_SalesDocumentItemPartner as _ItemPartner on _Partner.SDDocument   = _ItemPartner.SalesDocument
                                                                    and _Item.SalesDocumentItem  = _ItemPartner.SalesDocumentItem
                                                                    and _Partner.PartnerFunction = _ItemPartner.PartnerFunction
  association [0..1] to I_ContactPerson      as _ContactPerson on $projection.ContactPerson = _ContactPerson.ContactPerson
{
  key _Partner.SDDocument                                as SalesDocument,
  
  key _Item.SalesDocumentItem,
  
  key _Partner.PartnerFunction,
  
  key _Partner.SDDocPartnerSequenceNumber,
  
      _Partner.Customer,
      
      cast('' as lifnr )                                 as Supplier,
      
      cast( '0000000000' as parnr )                      as ContactPerson,
      
      _Partner.ReferenceBusinessPartner,
      
      _Partner.Personnel,
      
      _Partner.AddressID,
      
      _Partner.AddressPersonID,
      
      _Partner.AddressObjectType,
      
      _Partner.SDDocPartnerAddressRefType,
      
      _Partner.BPAddrDeterminationTransaction,
      
      _Partner.BPRefAddressIDForDocSpcfcAddr,
      
      cast( ' ' as stceg  )                              as VATRegistration,
      
      cast( ' ' as ablad )                               as UnloadingPointName,
      
      _Partner._DfltAddrRprstn,
      
      _Partner._BusinessPartnerAddress,
      
      _Partner._BPRefAddressForDocSpcfcAddr,
      
      _Partner._PartnerFunction,
      
      _ContactPerson
} where _ItemPartner.PartnerFunction is null