P_SOFAProcFlow30

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSOFAPROCF30'

define view P_SOFAProcFlow30 
 as select from   P_SOFAProcFlow20        as Level2
 inner join       I_SDDocumentProcessFlow as Level3
on 
     Level2.Level2Document         = Level3.PrecedingDocument
and  Level2.Level2DocumentCategory = Level3.PrecedingDocumentCategory
and  Level2.Level2DocumentItem     = Level3.PrecedingDocumentItem
and ( Level3.SubsequentDocumentCategory = 'O' or   --> Credit Memo 
      Level3.SubsequentDocumentCategory = 'P' or   --> Debit  Memo 
      Level3.SubsequentDocumentCategory = 'K' or   --> Credit Memo Request
      Level3.SubsequentDocumentCategory = 'L' )    --> Debit  Memo Request

left outer to one join 
I_BillingDocument as BillingDocument
  on Level3.SubsequentDocument         = BillingDocument.BillingDocument  and
     Level3.SubsequentDocumentCategory = BillingDocument.SDDocumentCategory                   
{
   //SalesOrder

   key SalesDocument,
   key Level2.SDDocumentCategory,
   
   key Level2Document,
   key Level2DocumentItem,
   key Level2DocumentCategory,
   key Level1DocumentCategory,
   
   key Level3.SubsequentDocument         as Level3Document,
   key Level3.SubsequentDocumentItem     as Level3DocumentItem,
   key Level3.SubsequentDocumentCategory as Level3DocumentCategory,
   
   Level2.SalesDocumentType,

    //Organization

   Level2.SalesOrganization,
   Level2.DistributionChannel,
   Level2.OrganizationDivision,   
   
   Level2.OverallSDProcessStatus,
   Level2.OverallTotalDeliveryStatus,
   Level2.OverallOrdReltdBillgStatus,
   
   //Misc

    Level2.RequestedDeliveryDate,
    --OverallSDProcessStatus,
    Level2.SalesDocumentDate,
    Level2.SalesGroup,
    Level2.SalesOffice,
    Level2.SoldToParty,
    Level2.PurchaseOrderByCustomer,
   
                
   case 
     when
      BillingDocument.BillingDocumentIsCancelled = 'X'
     then 'X' 
     else ''
    end as BillingDocumentIsCancelled   
 }