P_SOFAProcFlow12

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSOFAPROCF12'

define view P_SOFAProcFlow12
as select distinct from  P_SOFAProcFlow00          as SalesDocument  --> Level 0
    inner join           P_SDDocumentPurchOrdProcFlow  as ProcFlow
     on SalesDocument.SalesDocument = ProcFlow.PrecedingDocument
{
  key  SalesDocument,
  key  SDDocumentCategory, 
  key  ProcFlow.SubsequentDocument as PurchaseOrder,
  
  SalesDocumentType,

  //Organization

  SalesOrganization,
  DistributionChannel,
  OrganizationDivision,

  OverallSDProcessStatus,
  OverallTotalDeliveryStatus, 
  OverallOrdReltdBillgStatus,
  
  //Misc

  RequestedDeliveryDate,
  --OverallSDProcessStatus,
  SalesDocumentDate,
  SalesGroup,
  SalesOffice,
  SoldToParty,
  PurchaseOrderByCustomer
  
}
where
      ProcFlow.PrecedingDocument != '000000' 
  and SalesDocument.SDDocumentCategory  = 'C' --> Order    
   or SalesDocument.SDDocumentCategory  = 'I' --> Order w/o charge     
   
union all select distinct from  P_SOFAProcFlow00          as SalesDocument  --> Level 0
    inner join           I_PurOrdAccountAssignment as POAccountAss 
     on SalesDocument.SalesDocument = POAccountAss.SalesOrder
     
    inner join            R_PurchaseOrderItem as PurchaseOrderItem
                          on POAccountAss.PurchaseOrder = PurchaseOrderItem.PurchaseOrder
                          and POAccountAss.PurchaseOrderItem = PurchaseOrderItem.PurchaseOrderItem
                          and PurchaseOrderItem.PurchasingDocumentItemOrigin != 'V'
{
  key  SalesDocument,
  key  SDDocumentCategory, 
  key  POAccountAss.PurchaseOrder,
  
  SalesDocumentType,

  //Organization

  SalesOrganization,
  DistributionChannel,
  OrganizationDivision,

  OverallSDProcessStatus,
  OverallTotalDeliveryStatus, 
  OverallOrdReltdBillgStatus,
  
  //Misc

  RequestedDeliveryDate,
  --OverallSDProcessStatus,
  SalesDocumentDate,
  SalesGroup,
  SalesOffice,
  SoldToParty,
  PurchaseOrderByCustomer
  
}
where
      POAccountAss.SalesOrderItem != '000000' 
  and SalesDocument.SDDocumentCategory  = 'C' --> Order    
   or SalesDocument.SDDocumentCategory  = 'I' --> Order w/o charge