P_SK_CADocumentSourceBase

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'CA Document Source Base'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{ serviceQuality: #A, sizeCategory: #XL, dataClass: #TRANSACTIONAL }
@VDM.viewType: #COMPOSITE
@VDM.private:true

define view entity P_SK_CADocumentSourceBase

  as select from I_CADocument

  association [0..1] to I_CAInvcgDocPosting as _CAInvcDocPosting on  $projection.CADocumentNumber                    = _CAInvcDocPosting.CADocumentNumber
                                                                 and _CAInvcDocPosting.CAInvcgIsPostedInCurrentInvcg = 'X'
{
  key CADocumentNumber,
      CAReconciliationKey,
      CADocumentType,
      CADocumentOriginCode,
      CreatedByUser,
      CreationDate,
      CreationTime,
      TransactionCurrency,
      DocumentDate,
      CAPostingDate as PostingDate,
      CAReferenceDocument,
      ReferenceDocumentType,
      OriginalReferenceDocument,
      CAReversedDocumentNumber,
      CAReversalDocumentNumber,
      LogicalSystem,
      TaxReportingDate,

      _CAInvcDocPosting.CAInvoicingDocument as CAInvoicingDocument,
      CAInvcgRefPostingDocType              as CAReferenceDocumentType,


      cast(case when _CAInvcDocPosting.CAInvoicingDocument <> '' or ReferenceDocumentType = 'VBRK'
      then 'IN'
      else
      case CADocumentOriginCode
      when '05' then 'PA'
      when '06' then 'PA'
      when '19' then 'PA'
      when '1A' then 'PA'
      when '1B' then 'PA'
      else 'WD'
      end
      end   as char5)                                as CASourceDocumentCategory,

      cast(case when _CAInvcDocPosting.CAInvoicingDocument <> '' then '04'
       else case when ReferenceDocumentType = 'VBRK' then '03'
       else '01'
       end
       end
        as char3)                     as CASourceDocumentType,


      cast(case when _CAInvcDocPosting.CAInvoicingDocument <> '' then _CAInvcDocPosting.CAInvoicingDocument
      else case when ReferenceDocumentType = 'VBRK' then left(OriginalReferenceDocument, 10 )
      else CADocumentNumber
      end
      end as fkkid_docnr)                   as CASourceDocument
}