P_SI_AddNonResidentDocument

@EndUserText.label: 'Merged additional documents added by RAP - SI BST'
@VDM.viewType: #COMPOSITE
//@Metadata.allowExtensions:true

//@Analytics: { dataCategory: #CUBE }

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
//@Analytics.internalName:#LOCAL

@Metadata.ignorePropagatedAnnotations: true
@VDM.private:true

define view entity P_SI_AddNonResidentDocument as select from  P_SI_GLLineItmBPAssignment as GLRawData
association [1..1] to  I_Country                   as intcn       on //GLRawData.SI_IntlInstitutionCode is initial

                                                                    GLRawData.Country      = intcn.Country and GLRawData.SI_IntlInstitutionCode is initial 
{
key GLRawData.CompanyCode,
key GLRawData.FiscalYear,
key GLRawData.AccountingDocument,
//in casse there are more BP in one document - should not happen but in might - also ensures that manually added document from union will not be dulpicated

max( GLRawData.Customer ) as Customer,
max( GLRawData.Supplier ) as Supplier,
//needs to have the same country in case of duplucate documents - chose to be max - might cause possible issue when adding document manually -> then the country needs to be changes for each item of the document in FIORI application in preprocessing of the report

max( coalesce( intcn.CountryThreeDigitISOCode, GLRawData.SI_IntlInstitutionCode ) ) as Country,
//if document is manually added and then the BP is maintained additionally, we would have a duplicate as there would be document coming from both parts of union. In this case we take the info from the maintained BP

min ( GLRawData.DocumentIsAdded ) as DocumentIsAdded
}
group by GLRawData.CompanyCode, GLRawData.FiscalYear, GLRawData.AccountingDocument