P_SD_Sor_Cust_Identification

DDL: P_SD_SOR_CUST_IDENTIFICATION Type: view_entity COMPOSITE Package: RAP_SD_SLS_AUTOEXTRN

Custemer Identification for SOR

P_SD_Sor_Cust_Identification is a Composite CDS View that provides data about "Custemer Identification for SOR" in SAP S/4HANA. It reads from 2 data sources (I_BusinessPartnerCustomer, I_Customer) and exposes 42 fields with key field Customer. It has 4 associations to related views. Part of development package RAP_SD_SLS_AUTOEXTRN.

2 data source(s) 42 fields

Data Sources (2)

SourceAliasJoin Type
I_BusinessPartnerCustomer BusinessPartnerCustomer inner
I_Customer Customer from

Associations (4)

CardinalityTargetAliasCondition
[0..*] I_BusinessPartnerDefaultAddr _DefaultAddress BusinessPartnerCustomer.BusinessPartner = _DefaultAddress.BusinessPartner
[0..*] I_BusinessPartnerBank _BusinessPartnerBank _BusinessPartnerBank.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
[0..*] I_Businesspartnertaxnumber _Businesspartnertaxnumber _Businesspartnertaxnumber.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
[0..*] I_BusinessPartnerAddress _BusinessPartnerAddress _BusinessPartnerAddress.BusinessPartner = BusinessPartnerCustomer.BusinessPartner

Annotations (9)

NameValueLevelField
EndUserText.label Custemer Identification for SOR view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
VDM.private true view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view

Fields (42)

KeyFieldSource TableSource FieldDescription
KEY Customer I_Customer Customer
BusinessPartner I_BusinessPartnerCustomer BusinessPartner
CompanyCode
SalesOrganization
DistributionChannel
Division
DeletionIndicator I_Customer DeletionIndicator
AddressID I_Customer AddressID
BusinessPartnerAddressID _DefaultAddress BusinessPartnerAddressID
AddressPersonID
IndependentAddressID
IBAN _BusinessPartnerBank IBAN
BankAccount _BusinessPartnerBank BankAccount
BPTaxNumber _Businesspartnertaxnumber BPTaxNumber
BPTaxLongNumber _Businesspartnertaxnumber BPTaxLongNumber
BPEmailAddress
AddressIndependentEmail
CreatedByUser
CustomerName I_Customer CustomerName
OrganizationBPName1 I_Customer OrganizationBPName1
AddressNumber _BusinessPartnerAddress AddressNumber
Country _BusinessPartnerAddress Country
CityName _BusinessPartnerAddress CityName
Region _BusinessPartnerAddress Region
District _BusinessPartnerAddress District
StreetName _BusinessPartnerAddress StreetName
HouseNumber _BusinessPartnerAddress HouseNumber
PostalCode _BusinessPartnerAddress PostalCode
AuthorizationGroup I_Customer AuthorizationGroup
CustomerAccountGroup I_Customer CustomerAccountGroup
IsBusinessPurposeCompleted I_Customer IsBusinessPurposeCompleted
DataControllerSet I_Customer DataControllerSet
DataController1 I_Customer DataController1
DataController2 I_Customer DataController2
DataController3 I_Customer DataController3
DataController4 I_Customer DataController4
DataController5 I_Customer DataController5
DataController6 I_Customer DataController6
DataController7 I_Customer DataController7
DataController8 I_Customer DataController8
DataController9 I_Customer DataController9
DataController10 I_Customer DataController10 
@EndUserText.label: 'Custemer Identification for SOR'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType:#COMPOSITE
@VDM.private:true
@AccessControl.personalData.blocking:#BLOCKED_DATA_EXCLUDED
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity P_SD_Sor_Cust_Identification 
  as select from I_Customer                          as Customer
    inner join   I_BusinessPartnerCustomer           as BusinessPartnerCustomer   on Customer.Customer = BusinessPartnerCustomer.Customer
  association [0..*] to I_BusinessPartnerDefaultAddr as _DefaultAddress           on BusinessPartnerCustomer.BusinessPartner = _DefaultAddress.BusinessPartner
  association [0..*] to I_BusinessPartnerBank        as _BusinessPartnerBank      on _BusinessPartnerBank.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
  association [0..*] to I_Businesspartnertaxnumber   as _Businesspartnertaxnumber on _Businesspartnertaxnumber.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
  association [0..*] to I_BusinessPartnerAddress     as _BusinessPartnerAddress   on _BusinessPartnerAddress.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
{
  key Customer.Customer                                                              as Customer,
      BusinessPartnerCustomer.BusinessPartner                                        as BusinessPartner,
      Customer._CustomerCompany.CompanyCode                                          as CompanyCode,
      Customer._CustomerSalesArea.SalesOrganization                                  as SalesOrganization,
      Customer._CustomerSalesArea.DistributionChannel                                as DistributionChannel,
      Customer._CustomerSalesArea.Division                                           as Division,
      Customer.DeletionIndicator                                                     as DeletionIndicator,
      
      Customer.AddressID                                                             as AddressID,
      _DefaultAddress.BusinessPartnerAddressID                                       as BusinessPartnerAddressID,
      _DefaultAddress._AddressDefaultRepresentation.AddressPersonID                  as AddressPersonID,
      BusinessPartnerCustomer._BusinessPartner.IndependentAddressID                  as IndependentAddressID,
      
      _BusinessPartnerBank.IBAN                                                      as IBAN,
      _BusinessPartnerBank.BankAccount                                               as BankAccount,
      _Businesspartnertaxnumber.BPTaxNumber                                          as BPTaxNumber,
      _Businesspartnertaxnumber.BPTaxLongNumber                                      as BPTaxLongNumber,
      
      _DefaultAddress._AddressDefaultRepresentation._EmailAddress.EmailAddress       as BPEmailAddress,
      BusinessPartnerCustomer._BusinessPartner._AddressIndependentEmail.EmailAddress as AddressIndependentEmail,
      
      //Addition Info

      BusinessPartnerCustomer._BusinessPartner.CreatedByUser                         as CreatedByUser,
      Customer.CustomerName                                                          as CustomerName,
      Customer.OrganizationBPName1                                                   as OrganizationBPName1,
      
      _BusinessPartnerAddress.AddressNumber,
      _BusinessPartnerAddress.Country,
      _BusinessPartnerAddress.CityName,
      _BusinessPartnerAddress.Region,
      _BusinessPartnerAddress.District,
      _BusinessPartnerAddress.StreetName,
      _BusinessPartnerAddress.HouseNumber,
      _BusinessPartnerAddress.PostalCode,
      
      //ACC Control

      Customer.AuthorizationGroup,
      Customer.CustomerAccountGroup,
      Customer.IsBusinessPurposeCompleted,
      Customer.DataControllerSet,
      Customer.DataController1,
      Customer.DataController2,
      Customer.DataController3,
      Customer.DataController4,
      Customer.DataController5,
      Customer.DataController6,
      Customer.DataController7,
      Customer.DataController8,
      Customer.DataController9,
      Customer.DataController10
      
} where Customer.DeletionIndicator is initial and Customer.IsBusinessPurposeCompleted is initial

Learn More