P_RealTimeMFGOrdInspPostdDistr

@AbapCatalog.sqlViewName: 'PRTMOINSPPSTDSTR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
//@EndUserText.label: 'Private view of Event based Posted Variance in Inspector'

@AbapCatalog.preserveKey:true

define view P_RealTimeMFGOrdInspPostdDistr
  with parameters
    P_FiscalPeriodStartDate : budat,
    P_FiscalPeriodEndDate   : budat
  as select from I_GLAccountLineItemRawData   as _item
    inner join   I_Ledger as _ledger on  _ledger.Ledger     = _item.SourceLedger
    //and _ledger.IsLeadingLedger = 'X' //support only leading leader in CE2005

                                     and _ledger.LedgerType = '' //standard ledger only

{
  key OrderID,
  key SourceLedger                   as Ledger,

      sum(AmountInCompanyCodeCurrency)                as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)                as AmountInGlobalCurrency,
      sum(AmountInFreeDefinedCurrency1)                as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2)                as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3)                as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4)                as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5)                as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6)                as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7)                as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8)                as AmountInFreeDefinedCurrency8,

      max(PostingDate)              as PostingDate,

      /////////////////////////////////////////////////////////////////////////////////////

      // Period Amount Fields

      /////////////////////////////////////////////////////////////////////////////////////

      sum(case
                  when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                      AmountInCompanyCodeCurrency
                  else 0 end) as PeriodAmountInCompanyCodeCrcy,
      sum(case
      when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
          AmountInGlobalCurrency
          else 0 end)         as PeriodAmountInGlobalCurrency,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency1
            else 0 end)       as PeriodAmountInFreeDfndCrcy1,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency2
            else 0 end)       as PeriodAmountInFreeDfndCrcy2,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency3
            else 0 end)       as PeriodAmountInFreeDfndCrcy3,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency4
            else 0 end)       as PeriodAmountInFreeDfndCrcy4,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency5
            else 0 end)       as PeriodAmountInFreeDfndCrcy5,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency6
            else 0 end)       as PeriodAmountInFreeDfndCrcy6,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency7
            else 0 end)       as PeriodAmountInFreeDfndCrcy7,
      sum(case
            when (PostingDate >= $parameters.P_FiscalPeriodStartDate and PostingDate <= $parameters.P_FiscalPeriodEndDate) then
                AmountInFreeDefinedCurrency8
            else 0 end)       as PeriodAmountInFreeDfndCrcy8

}
where
      BusinessTransactionCategory   =  'EBDP'
  and ( PartnerAccountAssignment = 'KS' or PartnerAccountAssignment = 'PR')
  and PostingDate    <= $parameters.P_FiscalPeriodEndDate
  and ReferenceDocumentType    =  'EBWI'
group by
  OrderID,
  SourceLedger