P_RblsItmForKeyDtePerd2_WSJ

@AbapCatalog.sqlViewName: 'PRBLSKDATDUE2WSJ'
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_RblsItmForKeyDtePerd2_WSJ
  with parameters
    P_KeyDate : sydate,
    P_PeriodType               : fis_period_type

    as select from P_RblsItmForKeyDteRepPeriod( P_KeyDate: :P_KeyDate,
                                        P_PeriodType: :P_PeriodType ) as Period
    inner join  P_RblsItmForKeyDtePerd2A_WSJ as Receivables on Period.CompanyCode = Receivables.CompanyCode

{
  key Receivables.CompanyCode,
  key Receivables.AccountingDocument,
  key Receivables.AccountingDocumentItem,
  key Receivables.FiscalYear,

      Receivables.InvoiceReference,
      Receivables.InvoiceItemReference,
      Receivables.InvoiceReferenceFiscalYear,
      Receivables.ClearingDate,
      Receivables.PostingDate,
      Receivables.DocumentDate,
      Receivables.FinancialAccountType,
      Receivables.DebitCreditCode,
      Receivables.Customer,
      Receivables.FollowOnDocumentType,
      Receivables.SpecialGLCode,
      Receivables.GLAccount,
      Receivables.DisplayCurrency,
      Receivables.CompanyCodeCurrency,
      Receivables.AmountInCompanyCodeCurrency,
      Receivables.RefInvcDocumentDate,
      Receivables.RefInvcInvoiceReference,
      Receivables.RefInvcNetDueDate,
      Receivables.NetDueDate,

      Period.ReportingPeriodStartDate,
      Period.ReportingPeriodEndDate

}
where
(
  //  Overdue items

  ( Receivables.NetDueDate  <  Period.ReportingPeriodStartDate
    and ( Receivables.ClearingDate = '00000000' or Receivables.ClearingDate >= Period.ReportingPeriodStartDate ) )
//  Due this period

  or
  ( Receivables.NetDueDate  >= Period.ReportingPeriodStartDate
    and Receivables.NetDueDate  <= Period.ReportingPeriodEndDate
    and Receivables.PostingDate < Period.ReportingPeriodStartDate )
  or
//  New Invoices

  (     Receivables.PostingDate >= Period.ReportingPeriodStartDate
    and Receivables.PostingDate <= Period.ReportingPeriodEndDate
    and Receivables.NetDueDate  >= Period.ReportingPeriodStartDate
    and Receivables.NetDueDate  <= Period.ReportingPeriodEndDate
    and Receivables.PostingDate <= $parameters.P_KeyDate
    )
  )