P_Ra_Line_Items_Posting_Rules

@AbapCatalog.sqlViewName: 'PRA_LITM_PRULE'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@VDM.private:true //= @VDM.private

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Apply posting rules to line items'


@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

//used by view P_Ra_Fold_Line_Item_Post_Rules

//Selects from from coepb, P_Ra_Objects, tka01, t001, tkkap, kkag_constant and tkkab


define view P_Ra_Line_Items_Posting_Rules as 

select 
  b.kokrs as kokrs,
  b.bukrs as bukrs,
  b.werks as werks,
  b.prctr as prctr,
  b.posid as posid,
  b.pspid as pspid,
  b.aufnr as aufnr,
  b.posnr_co as posnr_co,
  b.vbeln as vbeln,
  b.posnr_va as posnr_va,
  b.abgsl as abgsl,
  a.objnr as objnr,
  a.versn as versn,
  f.rflg3 as rflg3,
  a.kstar as kstar,
  cast ( a.abkat as abkat_no_conv preserving type )as abkat,
  a.awkus as awkus,
  a.zlnid as zlnid,
  a.gjahr as gjahr,
  a.perio as perio,
  a.belnr as belnr,
  a.buzei as buzei,
  a.wkgbtr as wkgbtr,
  cast(d.waers as fins_currk) as kwaer,
  a.wogbtr as wogbtr,
  cast(e.waers as fins_currh) as bwaer,
  a.wdgbtr as wdgbtr,
  a.dwaer as dwaer,
  a.wvgbtr as wvgbtr,
  a.vwaer as vwaer,
  a.wfgbtr as wfgbtr,
  a.fwaer as fwaer,
  case when c.sakso <> ' ' then c.sakso 
       when c1.sakso <> ' ' then c1.sakso 
       when c2.sakso <> ' ' then c2.sakso
       when c3.sakso <> ' ' then c3.sakso 
       when c4.sakso <> ' ' then c4.sakso 
       when c5.sakso <> ' ' then c5.sakso  
       else ' ' end as sakso,
  case when c.sakha <> ' ' then c.sakha 
       when c1.sakha <> ' ' then c1.sakha 
       when c2.sakha <> ' ' then c2.sakha
       when c3.sakha <> ' ' then c3.sakha 
       when c4.sakha <> ' ' then c4.sakha 
       when c5.sakha <> ' ' then c5.sakha  
       else ' ' end as sakha,
  g.lfdsn       
  from coepb as a 
  inner join P_Ra_Objects as b on b.objnr = a.objnr
  inner join tka01 as d on d.kokrs = b.kokrs
  inner join t001 as e on e.bukrs = b.bukrs
  inner join tkkap as f on f.kokrs = b.kokrs and f.versa = a.versn
  left outer join kkag_constant as g on g.verwendung = 'B'
  left outer join tkkab as c on c.kokrs = b.kokrs and c.bukrs = b.bukrs and c.versa = a.versn and c.abkat = a.abkat and c.awkus = a.awkus and c.kstar = a.kstar and c.lfdsn = g.lfdsn 
  left outer join tkkab as c1 on c1.kokrs = b.kokrs and c1.bukrs = b.bukrs and c1.versa = a.versn and c1.abkat = a.abkat and c1.awkus = ' ' and c1.kstar = a.kstar and c1.lfdsn = g.lfdsn
  left outer join tkkab as c2 on c1.kokrs = b.kokrs and c2.bukrs = b.bukrs and c2.versa = a.versn and c2.abkat = '00' and c2.awkus = a.awkus and c2.kstar = a.kstar and c2.lfdsn = g.lfdsn    
  left outer join tkkab as c3 on c3.kokrs = b.kokrs and c3.bukrs = b.bukrs and c3.versa = a.versn and c3.abkat = '00' and c3.awkus = ' ' and c3.kstar = a.kstar and c3.lfdsn = g.lfdsn
  left outer join tkkab as c4 on c4.kokrs = b.kokrs and c4.bukrs = b.bukrs and c4.versa = a.versn and c4.abkat = a.abkat and c4.awkus = a.awkus and c4.kstar = ' ' and c4.lfdsn = g.lfdsn
  left outer join tkkab as c5 on c5.kokrs = b.kokrs and c5.bukrs = b.bukrs and c5.versa = a.versn and c5.abkat = a.abkat and c5.awkus = ' ' and c5.kstar = ' ' and c5.lfdsn = g.lfdsn        
  where c.sakso <> ' ' or c1.sakso <> ' ' or c2.sakso <> ' ' or c3.sakso <> ' ' or c4.sakso <> ' ' or c5.sakso <> ' ' or
        c.sakha <> ' ' or c1.sakha <> ' ' or c2.sakha <> ' ' or c3.sakha <> ' ' or c4.sakha <> ' ' or c5.sakha <> ' '  
            
;