P_RU_LinkedCommsnTradeInvoice0

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PRULNKCTINV0'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_RU_LinkedCommsnTradeInvoice0
  as select from I_RU_InvoiceJournalDocLink as DocLink

    inner join   I_JournalEntry             as AccDoc_in on  AccDoc_in.CompanyCode        = DocLink.RU_IncomingInvoiceCompanyCode
                                                         and AccDoc_in.AccountingDocument = DocLink.RU_IncomingInvoiceNumber
                                                         and AccDoc_in.FiscalYear         = DocLink.RU_IncomingInvoiceFiscalYear

  association [0..1] to P_RU_InvoiceTotalAmount as _InvTotAm_in on  _InvTotAm_in.CompanyCode          =  DocLink.RU_IncomingInvoiceCompanyCode
                                                                and _InvTotAm_in.AccountingDocument   =  DocLink.RU_IncomingInvoiceNumber
                                                                and _InvTotAm_in.FiscalYear           =  DocLink.RU_IncomingInvoiceFiscalYear
                                                                and DocLink.IncomingCorrectionInvoice =  ''

                                                                or  _InvTotAm_in.CompanyCode          =  DocLink.RU_IncomingInvoiceCompanyCode
                                                                and _InvTotAm_in.AccountingDocument   =  DocLink.IncomingCorrectionInvoice
                                                                and _InvTotAm_in.FiscalYear           =  DocLink.IncomingCorrectionInvoiceYear
                                                                and DocLink.IncomingCorrectionInvoice <> ''

{
  key DocLink.InternalTableKeyField,

      DocLink.CompanyCode,
      DocLink.Invoice,
      DocLink.InvoiceYear,
      DocLink.CorrectionInvoice,
      DocLink.CorrectionInvoiceYear,
      DocLink.RevisionNumber,
      DocLink.RevisionInvoice,
      DocLink.RevisionInvoiceYear,
      DocLink.OriginalInvoiceRevisionNumber,
      case
        when DocLink.RevisionInvoice   <> '' then DocLink.RevisionInvoice
        when DocLink.CorrectionInvoice <> '' then DocLink.CorrectionInvoice
        else DocLink.Invoice
      end                                                                                   as AccountingDocument,
      case
        when DocLink.RevisionInvoiceYear   <> '0000' then DocLink.RevisionInvoiceYear
        when DocLink.CorrectionInvoiceYear <> '0000' then DocLink.CorrectionInvoiceYear
        else DocLink.InvoiceYear
      end                                                                                   as FiscalYear,

      DocLink.RU_IncomingInvoiceCompanyCode,
      DocLink.RU_IncomingInvoiceNumber,
      DocLink.RU_IncomingInvoiceFiscalYear,
      DocLink.IncomingCorrectionInvoice,
      DocLink.IncomingCorrectionInvoiceYear,
      DocLink.IncomingRevisionNumber,
      DocLink.IncomingRevisionInvoice,
      DocLink.IncomingRevisionInvoiceYear,
      DocLink.IncgOriglInvoiceRevisionNumber,
      case
        when DocLink.IncomingRevisionInvoice   <> '' then DocLink.IncomingRevisionInvoice
        when DocLink.IncomingCorrectionInvoice <> '' then DocLink.IncomingCorrectionInvoice
        else DocLink.RU_IncomingInvoiceNumber
      end                                                                                   as IncgInvoiceAccountingDocument,
      case
        when DocLink.IncomingRevisionInvoiceYear   <> '0000' then DocLink.IncomingRevisionInvoiceYear
        when DocLink.IncomingCorrectionInvoiceYear <> '0000' then DocLink.IncomingCorrectionInvoiceYear
        else DocLink.RU_IncomingInvoiceFiscalYear
      end                                                                                   as IncgInvoiceAcctgDocFiscalYear,

      cast(case
        when DocLink.CommsnTradeInvoiceLinkedAmount = 0
          then _InvTotAm_in.AmountInTransactionCurrency
        else abs( DocLink.CommsnTradeInvoiceLinkedAmount )
      end                                                       as firu_invj_linked_amount) as CommsnTradeInvoiceLinkedAmount,
      DocLink.CommsnTradeInvcLinkedVATAmount                                                as CommsnTradeInvcLinkedVATAmount,

      _InvTotAm_in.TaxAmount                                                                as BsetTaxAmount,
      _InvTotAm_in.AmountInTransactionCurrency                                              as BsetGrossAmountInTransCrcy,

      case
        when DocLink.Currency = ''
          then AccDoc_in.TransactionCurrency
        else DocLink.Currency
      end                                                                                   as CommsnTradeInvoiceLinkingCrcy
}